dmlarray.pas

Oracle Data Access Components Source Code ODAC v.6.70.0.45

unit DMLArray;

interface

uses
{$IFDEF LINUX}
  SysUtils, Types, Classes, QGraphics, QControls, QForms, QDialogs, QStdCtrls,
  QDBCtrls, QComCtrls, QExtCtrls, QGrids, QDBGrids, QButtons, OdacClx,
{$ELSE}
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, ExtCtrls, Grids, DBGrids, StdCtrls, ToolWin, ComCtrls, Buttons,
  OdacVcl,
{$ENDIF}
{$IFDEF FPC}
  LResources,
{$ENDIF}
  DB, {$IFNDEF FPC}MemDS{$ELSE}MemDataSet{$ENDIF},
  DBAccess, Ora, OdacDemoFrame, OdacDemoForm;

type
  TDMLArrayFrame = class(TOdacDemoFrame)
    ToolBar: TPanel;
    sqGet: TOraSQL;
    Memo: TMemo;
    sqPut: TOraSQL;
    gdDept: TDBGrid;
    dsDept: TDataSource;
    quDept: TOraQuery;
    Splitter1: TSplitter;
    Memo1: TMemo;
    Panel1: TPanel;
    Label1: TLabel;
    Label2: TLabel;
    Panel2: TPanel;
    DBNavigator: TDBNavigator;
    btPut: TSpeedButton;
    btGet: TSpeedButton;
    btClose: TSpeedButton;
    btOpen: TSpeedButton;
    procedure btGetClick(Sender: TObject);
    procedure btPutClick(Sender: TObject);
    procedure btOpenClick(Sender: TObject);
    procedure btCloseClick(Sender: TObject);
  private
    { Private declarations }
  public
    procedure SetDebug(Value: boolean); override;
    procedure Initialize; override;
  end;

implementation
{$IFNDEF VER130}
uses
  Variants;
{$ENDIF}

{$IFNDEF FPC}
{$IFDEF CLR}
{$R *.nfm}
{$ENDIF}
{$IFDEF WIN32}
{$R *.dfm}
{$ENDIF}
{$IFDEF LINUX}
{$R *.xfm}
{$ENDIF}
{$ENDIF}

procedure TDMLArrayFrame.btGetClick(Sender: TObject);
var
  i: integer;
  RecCount: integer;
begin
  RecCount := sqGet.Session.ExecSQL(
    'begin SELECT Count(*) INTO :Result FROM Scott.Dept; end;', [0]);

  sqGet.ArrayLength := RecCount; // set length of parameters

  for i := 1 to RecCount do begin
    sqGet.ParamByName('RowNum').ItemAsInteger[i]:= i;
  end;

  sqGet.Execute(RecCount);

  Memo.Lines.Clear;
  Memo1.Lines.Clear;
  for i := 1 to RecCount do begin
    Memo1.Lines.Add(sqGet.ParamByName('DeptNo').ItemAsString[i]);
    Memo.Lines.Add(sqGet.ParamByName('DName').ItemAsString[i]);
  end;
end;

procedure TDMLArrayFrame.btPutClick(Sender: TObject);
var
  i: integer;
  DeptNoArr: variant;
  DNameArr: variant;
  RecCount: integer;
begin
  RecCount := sqPut.Session.ExecSQL(
    'begin SELECT Count(*) INTO :Result FROM Scott.Dept; end;', [0]);

{sqPut.ArrayLength}

// Setting array parameters
//   Way 1 - DeptNo
//   Way 2 - DName
  DeptNoArr := VarArrayCreate([1, RecCount], varVariant); // explict creating array

  sqPut.ParamByName('DName').Length:= RecCount;
  DNameArr := sqPut.ParamByName('DName').Value;

  for i := 1 to RecCount do begin
    DeptNoArr[i] := Memo1.Lines[i - 1];
    DNameArr[i] := Memo.Lines[i - 1];
  // Way 3:
  // sqPut.ParamByName('DeptNo').ItemAsString[i]:= Memo1.Lines[i - 1];
  // sqPut.ParamByName('DName').ItemAsString[i]:= Memo.Lines[i - 1];

  end;
  sqPut.ParamByName('DeptNo').Value := DeptNoArr;
  sqPut.ParamByName('DName').Value := DNameArr;

  sqPut.Execute(RecCount);

  if quDept.Active then
    quDept.Refresh
  else
    quDept.Open;
end;

procedure TDMLArrayFrame.btOpenClick(Sender: TObject);
begin
  quDept.Open;
end;

procedure TDMLArrayFrame.btCloseClick(Sender: TObject);
begin
  quDept.Close;
end;

procedure TDMLArrayFrame.SetDebug(Value: boolean);
begin
  sqGet.Debug := Value;
  sqPut.Debug := Value;
  quDept.Debug := Value;
end;

procedure TDMLArrayFrame.Initialize;
begin
  inherited;

  sqGet.Connection := Connection;
  sqPut.Connection := Connection;
  quDept.Connection := Connection;

  OdacForm.StatusBar.Panels[2].Text := 'Use GetNames button to retrive all names by DML array operation and PutNames button to set it';
end;

initialization
{$IFDEF FPC}
{$I DMLArray.lrs}
{$ENDIF}

end.