saveuser.asp

邮件发送系统 sql与vb实现的 能完成在线的邮件发送与管理

<%@ Language=VBScript %>
<!--#include file="conn.asp"-->
<%
	'检查用户是否已经经过登陆验证了
	if session("admin") = "" and session("flag") = "" Then
		'如果没有登陆，则输出出错信息
		'要求用户进行登陆
		response.write "   <br><br><br>"
		response.write "    <table align='center' width='300' border='1' cellpadding='0' cellspacing='0' bordercolor='#999999'>"
		response.write "      <tr bgcolor='#999999'> "
		response.write "        <td colspan='2' height='15'> "
		response.write "          <div align='center'><font color='#FFFFFF'>操作: 确认身份失败!</font></div>"
		response.write "        </td>"
		response.write "      </tr>"
		response.write "      <tr> "
		response.write "        <td colspan='2' height='23'> "
		response.write "          <div align='center'><br><br>"
		response.write "      非法登陆,您的操作已经被记录!!! <br><br>"
		response.write "        <a href='javascript:onclick=history.go(-1)'>返回</a>"        
		response.write "        <br><br></div></td>"
		response.write "      </tr>   </table>" 

		'终止响应
		response.end
	end If

	'只有超级管理员才能进行用户权限管理
	if session("flag")>1 then
		response.write "<br><p align=center>您没有操作的权限</p>"
		response.end
	end If
	
	'新密码
	newpin=LCase(Request("newpin"))

	'新帐号
	manager=LCase(Request("manager"))

	'管理员ID
	adminid=Request("adminid")
	   
	'提交按钮的值
	submit=Trim(Request("submit"))
	   
	'记录集对象
	set rs = server.createobject("adodb.recordset")
	'进行修改操作
	if submit="修改" then
		'获得原信息的记录      
		sql="select * from admin where id=" & adminid
		'打开记录集对象
		rs.open sql,conn,3,3

		'更新用户帐号信息
		rs("username")=manager
		'更新用户密码信息
		rs("password")=newpin

		'提交更新
		rs.update

		'关闭记录集，释放对象
		rs.close
		set rs=Nothing
		
		'关闭数据库连接，释放对象
		conn.Close
		set conn=Nothing
		
		'返回权限管理页面
		response.redirect "adminuser.asp"
	end if
		
	'进行删除操作
	if submit="删除" Then
		'删除原信息的记录
		sql="delete from Admin where id=" & adminid

		'执行删除操作
		conn.Execute sql

		'关闭数据库连接，释放对象
		conn.Close
		set conn=Nothing  
		
		'返回权限管理页面
		response.redirect "adminuser.asp"
	end if
%>