approve.asp

本同学录系统演示地址: http://class.19870123.cn/ 下载后请在Web.Config里更改设置,如数据库路径等 如果要换sql数据库,请将app_code里的MyPage

<!-- #include file="../ConnDB.asp" -->
<!-- #include file="../class/Person.asp" -->
<!-- #include file="../class/SysConf.asp" -->
<!-- #include file="../class/Bulletin.asp" -->
<%
  On error resume next
  Dim uid
  uid = Request("uid")
  set objPerson = new Person
  objPerson.GetPersonInfo(uid)	' 读取申请人的信息
  objPerson.Approve(uid)	    ' 将Status设置为1，批准指定同学的加入申请

  set objBulletin = new Bulletin
  objBulletin.Title = objPerson.Name & " 加入班级"
  objBulletin.Content = "代表全体同学对 " & objPerson.Name & " 的加入表示热烈欢迎！"
  set obj = new Person
  obj.GetPersonInfo(Session("UserName"))
  objBulletin.Poster = obj.Name
  objBulletin.Posttime = Now
  objBulletin.insert
  
  ' 发送邮件
  Dim JMail, contentId
  Set JMail = Server.CreateObject("JMail.Message") 
  JMail.Charset = "gb2312" ' 邮件字符集，默认为"US-ASCII"
  JMail.ISOEncodeHeaders = False ' 是否进行ISO编码，默认为True
  JMail.ContentType="text/html"
  ' 发送者信息（可用变量方式赋值）
  set objSys = new SysConf
  JMail.From = objSys.GetSysConfInfo("Email") '发送者地址
  JMail.FromName = "网上同学录" ' 发送者姓名
  JMail.Subject = "你已经通过网上同学录的审批，欢迎加入我们！" ' 邮件主题

  JMail.MailServerUserName = objSys.GetSysConfInfo("EmailUser") ' 身份验证的用户名
  JMail.MailServerPassword = objSys.GetSysConfInfo("EmailPwd") ' 身份验证的密码

  ' 设置优先级，范围从1到5，越大的优先级越高，3为普通
  JMail.Priority = 3
  JMail.AddHeader "Originating-IP", Request.ServerVariables("REMOTE_ADDR")

  ' 加入一个收件人【变量email：收件人地址】可以同一语句重复加入多个
  JMail.AddRecipient(objPerson.Email)
  ' 邮件主体（文本部分）
  JMail.Body = "亲爱的同学：你的加入申请已经被批准。<BR>用户名为：" _
		& objPerson.UserId & "密码为：" & objPerson.UserPwd _
		& "<BR>请访问<a href=" & objSys.GetSysConfInfo("Website") _
		& " target=_blank>此网址</a>"
  ' 发送【调用格式：objJMail.Send([username:password@]SMTPServerAddress[:Port])】
  JMail.Send(objSys.GetSysConfInfo("SmtpServer"))

  ' 关闭并清除对象
  JMail.Close()
  Set JMail = Nothing
%>  
<script language="javascript">
  opener.location.reload();
  setTimeout("window.close()",800);
</script>