person.asp

本同学录系统演示地址: http://class.19870123.cn/ 下载后请在Web.Config里更改设置,如数据库路径等 如果要换sql数据库,请将app_code里的MyPage

<% 
'本类用于保存对表Person的数据库访问操作
'表的每个字段对应类的一个成员变量
class Person
  public UserId			' 用户名
  public UserPwd		' 密码
  public Name			' 姓名
  public Sex			' 性别
  public Address		' 地址
  public Postcode		' 邮编
  public Email			' 电子邮件
  public Telephone		' 电话
  public Mobile			' 手机
  public Company		' 单位
  public Birthday		' 生日
  public Status			' 当前状态
  public UserType		' 用户类型
  public rs				' 用于返回结果集

  '获取个人信息
  public sub GetPersonInfo(uid)
	'创建Recordset对象，处理查询结果集
	Set rs=Server.CreateObject("ADODB.Recordset")
	'设置rs的ActiveConnection属性，绑定到连接
	Set rs.ActiveConnection = Conn
	'设置游标类型
	rs.CursorType = 3
	'设置查询的SELECT语句
 	sql = "SELECT * FROM Person WHERE UserId='" + uid + "'"
	'打开记录集
	rs.Open sql
	'读取个人数据
	if rs.EOF Then  
	  UserId = ""
	else
	  UserId = uid	
	  UserPwd = rs("UserPwd")
	  Name = rs("Name")
	  Sex = rs("Sex")
	  Address = rs("Address")
	  Postcode = rs("Postcode")
	  Email = rs("Email")
	  Telephone = rs("Telephone")
	  Mobile = rs("Mobile")
	  Company = rs("Company")
	  Birthday = rs("Birthday")
	  Status = rs("Status")
	  UserType = rs("UserType")
	end if
	rs.Close
  end sub

  '获取所有个人信息，返回结果集
  public sub GetPersonlist()
		'创建Recordset对象，处理查询结果集
		Set rs=Server.CreateObject("ADODB.Recordset")
		'设置rs的ActiveConnection属性，绑定到连接
		Set rs.ActiveConnection = Conn
		'设置游标类型
		rs.CursorType = 3
		'设置查询的SELECT语句
	 	sql = "SELECT * FROM Person"
		'打开记录集
		rs.Open sql
  end sub

  '获取最近一周的生日信息，返回结果集
  public sub GetRecentBirthlist()
		'创建Recordset对象，处理查询结果集
		Set rs=Server.CreateObject("ADODB.Recordset")
		'设置rs的ActiveConnection属性，绑定到连接
		Set rs.ActiveConnection = Conn
		'设置游标类型
		rs.CursorType = 3
		'设置查询的SELECT语句
	 	sql = "SELECT Name, Birthday, DateDiff(day, getdate(), DateAdd(Year, " _
			& " year(getdate())-year(Birthday), Birthday)) " _
			& " FROM Person WHERE IsDate(Birthday)=1 And DateDiff(day, getdate(), DateAdd(Year, " _
			& " year(getdate())-year(Birthday), Birthday))<=7 ORDER BY Birthday DESC"

		'打开记录集
		rs.Open sql
  end sub

  ' 判断指定用户名是否存在
  public function HavePerson(uid)
	dim exist
	'创建Recordset对象，处理查询结果集
	Set rs=Server.CreateObject("ADODB.Recordset")
	'设置rs的ActiveConnection属性，绑定到连接
	Set rs.ActiveConnection = Conn
	'设置游标类型
	rs.CursorType = 3
	'设置查询的SELECT语句
 	sql = "SELECT * FROM Person WHERE UserId='" + uid + "'"
	'打开记录集
	rs.Open sql
	'如果记录集为空，则插入数据；否则修改数据
	if rs.EOF then  	
	  exist = false
	else
	  exist = true
	end if

	rs.Close
	HavePerson = exist
  end function

  '添加个人信息
  public sub insert()
    sql = "INSERT INTO Person VALUES ('" + UserId + "','" + UserPwd _
		  + "','" + Name + "'," + CStr(Sex) + ",'" + Address + "','" + Postcode _
		  + "','" + Email + "','" + Telephone + "','" + Mobile _
		  + "','" + Company + "','" + Birthday + "'," + CStr(Status) + "," + CStr(UserType) + ")"
	'执行SQL语句
	Conn.Execute(sql)
  end sub

  '修改个人信息
  public sub update(uid)
    sql = "UPDATE Person SET Name='" + Name _
		  + "', Sex=" + CStr(Sex) + ", Address='" + Address + "', Postcode='" _
		  + Postcode + "', Email='" + Email + "', Telephone='" + Telephone _
		  + "', Mobile='" + Mobile + "', Company='" + Company + "', Birthday='" _
		  + Birthday + "' WHERE UserId='" + uid + "'"
	'执行SQL语句
	Conn.Execute(sql)
  end sub

  public sub setpwd(uid)
	sql = "UPDATE Person SET UserPwd='" + UserPwd + "' WHERE UserId='" + uid + "'"
	Conn.Execute(sql)
  end sub

  ' 将Status设置为1，批准指定同学的加入申请
  public sub approve(uid)
    sql = "UPDATE Person SET Status=1 WHERE UserId='" & uid & "'"
	Conn.Execute(sql)
  end sub

  '删除个人信息
  public sub delete(uid)
	sql = "DELETE FROM Person WHERE UserId='" & uid & "'"
	Conn.Execute(sql)
  end sub
end class
%>