configure.in

ppciaxclient softphone

dnl Process this file with autoconf to produce a configure script. -*-m4-*-

AC_INIT(libspeex/nb_celp.c)

SPEEX_MAJOR_VERSION=1
SPEEX_MINOR_VERSION=0
SPEEX_MICRO_VERSION=5
SPEEX_EXTRA_VERSION=
SPEEX_VERSION=$SPEEX_MAJOR_VERSION.$SPEEX_MINOR_VERSION.$SPEEX_MICRO_VERSION$SPEEX_EXTRA_VERSION

SPEEX_LT_CURRENT=4
SPEEX_LT_REVISION=0
SPEEX_LT_AGE=3

AC_SUBST(SPEEX_LT_CURRENT)
AC_SUBST(SPEEX_LT_REVISION)
AC_SUBST(SPEEX_LT_AGE)

# For automake.
VERSION=$SPEEX_VERSION
PACKAGE=speex

AC_SUBST(SPEEX_VERSION)

AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
AM_MAINTAINER_MODE

AC_CANONICAL_HOST
AM_PROG_LIBTOOL

AC_C_BIGENDIAN
AC_CHECK_HEADERS(sys/soundcard.h sys/audioio.h)

AC_ARG_ENABLE(ogg,
      [  --enable-ogg=[yes/no]    Turn on or off the use of ogg
libraries [default=yes]],
      [case "${enableval}" in
        yes) useogg=true ;;
        no)  useogg=false ;;
        *) AC_MSG_ERROR(bad value ${enableval} for --enable-ogg) ;;
      esac],[useogg=true])

if test x$useogg = xtrue; then
AC_PATH_LIBOGG
fi

if test "$have_libogg" = yes; then
   src=src
else
   src=
fi
AC_SUBST(src)

AC_CHECK_LIB(m, sin)
AC_CHECK_LIB(gnugetopt, getopt_long)

AC_DEFINE_UNQUOTED(SPEEX_VERSION, "${SPEEX_VERSION}")
AC_DEFINE_UNQUOTED(SPEEX_MAJOR_VERSION, ${SPEEX_MAJOR_VERSION})
AC_DEFINE_UNQUOTED(SPEEX_MINOR_VERSION, ${SPEEX_MINOR_VERSION})
AC_DEFINE_UNQUOTED(SPEEX_MICRO_VERSION, ${SPEEX_MICRO_VERSION})
AC_DEFINE_UNQUOTED(SPEEX_EXTRA_VERSION, "${SPEEX_EXTRA_VERSION}")


AC_ARG_ENABLE(sse, [  --enable-sse             enable SSE support], [if test "$enableval" = yes; then AC_DEFINE(_USE_SSE) fi])

dnl Output the makefiles and version.h.

AC_OUTPUT([Makefile libspeex/Makefile src/Makefile doc/Makefile Speex.spec
           include/Makefile include/speex/Makefile speex.pc
           win32/Makefile win32/libspeex/Makefile win32/speexenc/Makefile
           win32/speexdec/Makefile ])

if test "x$src" = "x"; then 
echo "You don't seem to have the development package for libogg (libogg-devel) installed. Only the Speex library (libspeex) will be built (no encoder/decoder executable)"
echo "You can download libogg from http://www.vorbis.com/download.psp"
fi

echo "Type \"make; make install\" to compile and install Speex";