sdram.lcf

Coldfire MCF5282 DBug bootloader

#/*
# * File:		sdram.lcf
# * Purpose:	Linker file for the M5282EVB
# *
# * Notes:		dBUG running in SDRAM
# *
# */

MEMORY
{
	sdram		(RWX) : ORIGIN = 0x00000000,	LENGTH = 0x01000000
	vector_ram	(RWX) : ORIGIN = 0x00000000,	LENGTH = 0x00000400
	dbug		(RWX) : ORIGIN = 0x00000400,	LENGTH = 0x0003FC00
	user_space	(RWX) : ORIGIN = 0x00040000,	LENGTH = 0x00FC0000
	sram		(RWX) : ORIGIN = 0x20000000,	LENGTH = 0x00010000
	ext_sram	(RWX) : ORIGIN = 0x30000000,	LENGTH = 0x00080000
	ipsbar		(RWX) : ORIGIN = 0x40000000,	LENGTH = 0x40000000
	flash		(RWX) : ORIGIN = 0xF0000000,	LENGTH = 0x00080000
	ext_flash 	(RWX) : ORIGIN = 0xFFE00000,	LENGTH = 0x00200000	
	params		(RWX) : ORIGIN = 0xFFE04000,	LENGTH = 0x00002000

	text		(RWX) : ORIGIN = 0x00000000,	LENGTH = 0
	data		(RWX) : ORIGIN = AFTER(text),	LENGTH = 0
}

SECTIONS
{
	.sdram		: {} > sdram		
	.vector_ram	: {} > vector_ram
	.dbug		: {} > dbug		
	.user_space	: {} > user_space
	.sram		: {} > sram		
	.ext_sram	: {} > ext_sram
	.ipsbar		: {} > ipsbar		
	.flash		: {} > flash		
	.ext_flash	: {} > ext_flash 
	.params		: {} > params		

	.text :
	{
		vectors.s (.text)
		. 				= ALIGN(0x4);
		*(.text)
		. 				= ALIGN(0x4);
		*(.rodata)	
	} > text

	.data :
	{
		. 				= ALIGN(0x4);
		___DATA_ROM 	= .;
		___DATA_RAM 	= .;
		*(.sdata)
		*(.data)
		. 				= ALIGN(0x4);
		*(.relocate_code)
		. 				= ALIGN(0x4);
		*(.relocate_const)
		. 				= ALIGN(0x4);
		*(.relocate_data)
		___DATA_END 	= .;
		___BSS_START 	= .;
		*(.sbss)
		*(.bss)
		___BSS_END 		= .;
		___HEAP_START	= .;
		.				= . + 4;
		___HEAP_END		= .;
		___PARAMS_START	= .;
		.				= . + 0x48;
		___PARAMS_END	= .;
		___SP_END		= .;
		.				= . + 0xC00;
		___SP_INIT		= .;
	} > data

	___IPSBAR			= ADDR(.ipsbar);
	___VECTOR_RAM		= ADDR(.vector_ram);

	___SDRAM			= ADDR(.sdram);
	___SDRAM_SIZE		= 0x01000000;

	___SRAM				= ADDR(.sram);
	___SRAM_SIZE		= 0x00010000;

	___EXT_SRAM			= ADDR(.ext_sram);
	___EXT_SRAM_SIZE	= 0x00080000;

	___FLASH			= ADDR(.flash);
	___FLASH_SIZE		= 0x00080000;

	___EXT_FLASH		= ADDR(.ext_flash);
	___EXT_FLASH_SIZE	= 0x00200000;

	___PARAMS			= ADDR(.params);
	___PARAMS_SIZE		= ___PARAMS_END - ___PARAMS_START;
	
	___DBUG_ADDRESS		= ADDR(.sdram);
	___DBUG_SIZE		= 0x00040000;
	___DBUG_CODE_START	= ADDR(.dbug);
	___DBUG_CODE_SIZE	= 0x0003FC00;
	
	___USER_SPACE		= ADDR(.user_space);
	___USER_SPACE_SIZE	= 0x00FC0000;
}