assembly.s

硬盘MP3播放器-MEGA128-VS1001K-USB-遥控-LCD-ICCAVR代码-硬盘-支持FAT32-单面PCB 第三部分

		.text

SPMCR = 0x68

; void write_page (unsigned int adr, unsigned char function);
; bits 8:15 adr addresses the page...(must setup RAMPZ beforehand!!!)
_write_page::
        XCALL __WAIT_SPMEN__
	MOV R31,R17        
        MOV R30,R16         ;move address to z pointer (R31=ZH R30=ZL)
        STS SPMCR,R18       ;argument 2 decides function
        SPM                 ;perform pagewrite
        RET

; void fill_temp_buffer (unsigned int data, unsigned int adr);
; bits 7:1 in adr addresses the word in the page... (2=first word, 4=second word etc..)
_fill_temp_buffer::

        XCALL __WAIT_SPMEN__
        MOV R31,R19        
        MOV R30,R18         ;move adress to z pointer (R31=ZH R30=ZL)
        MOV R1,R17
        MOV R0,R16          ;move data to reg 0 and 1      
        LDI R19,0x01
        STS SPMCR,R19
        SPM            ;Store program memory
        RET      

;unsigned int read_program_memory (unsigned int adr ,unsigned char cmd);
_read_program_memory::
        MOV R31,R17         ;R31=ZH R30=ZL
        MOV R30,R16         ;move adress to z pointer
        SBRC R18,0          ;read lockbits? (second argument=0x09)
        STS SPMCR,R18	    ;if so, place second argument in SPMEN register
        ELPM                ;read LSB
        MOV R16,R0         
        INC R30
        ELPM
        MOV R17,R0          ;read MSB (ignored when reading lockbits)
        RET
        
_enableRWW::
	XCALL __WAIT_SPMEN__
        LDI R27,0x11
        STS SPMCR,R27
        SPM
        RET              

__WAIT_SPMEN__:
        LDS     R27,SPMCR       ; load SPMCR to R27
        SBRC    R27,0          ; check SPMEN flag
        RJMP    __WAIT_SPMEN__ ; wait for SPMEN flag cleared        
        RET