frmstock.frm

一个简单的用vb制作的公司贸易管理系统

VERSION 5.00
Object = "{5E9E78A0-531B-11CF-91F6-C2863C385E30}#1.0#0"; "MSFLXGRD.OCX"
Begin VB.Form frmStock 
   Caption         =   "进货信息列表"
   ClientHeight    =   3885
   ClientLeft      =   45
   ClientTop       =   345
   ClientWidth     =   7785
   LinkTopic       =   "Form1"
   MDIChild        =   -1  'True
   ScaleHeight     =   3885
   ScaleWidth      =   7785
   WindowState     =   2  'Maximized
   Begin VB.CommandButton Command1 
      Caption         =   "关闭"
      Height          =   375
      Left            =   6480
      TabIndex        =   2
      Top             =   120
      Width           =   1215
   End
   Begin MSFlexGridLib.MSFlexGrid msgList 
      Height          =   3132
      Left            =   120
      TabIndex        =   0
      Top             =   600
      Width           =   7452
      _ExtentX        =   13150
      _ExtentY        =   5530
      _Version        =   393216
      Cols            =   4
      FixedCols       =   3
      AllowUserResizing=   1
   End
   Begin VB.Label lblTitle 
      Caption         =   "进  货  信  息  列  表"
      BeginProperty Font 
         Name            =   "宋体"
         Size            =   12
         Charset         =   134
         Weight          =   700
         Underline       =   0   'False
         Italic          =   0   'False
         Strikethrough   =   0   'False
      EndProperty
      ForeColor       =   &H8000000D&
      Height          =   252
      Left            =   120
      TabIndex        =   1
      Top             =   120
      Width           =   3012
   End
End
Attribute VB_Name = "frmStock"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit
Public txtsql As String
Dim mrc As ADODB.Recordset
Dim MsgText As String

Private Sub Command1_Click()
    Unload Me
End Sub

Private Sub Form_Load()

    ShowTitle
    ShowData
    flagSedit = True
End Sub

Private Sub Form_Resize()
    If Me.WindowState <> vbMinimized And fMainForm.WindowState <> vbMinimized Then
        '边界处理
        If Me.ScaleHeight < 10 * lblTitle.Height Then

            Exit Sub
        End If
        If Me.ScaleWidth < lblTitle.Width + lblTitle.Width / 2 Then

            Exit Sub
        End If
        '控制控件的位置

        lblTitle.Top = lblTitle.Height
        lblTitle.Left = (Me.Width - lblTitle.Width) / 2

        msgList.Top = lblTitle.Top + lblTitle.Height + lblTitle.Height / 2
        msgList.Width = Me.ScaleWidth - 200
        msgList.Left = Me.ScaleLeft + 100
        msgList.Height = Me.ScaleHeight - msgList.Top - 200
        Command1.Left = Me.Width - Command1.Width - 300
    End If
End Sub

Public Sub FormClose()
    Unload Me
End Sub
Private Sub Form_Unload(Cancel As Integer)
    flagSedit = False
    gintSmode = 0
End Sub
Private Sub ShowData()

    Dim j As Integer
    Dim i As Integer

    Set mrc = ExecuteSQL(txtsql, MsgText)
    With msgList
        .Rows = 1

        Do While Not mrc.EOF
            .Rows = .Rows + 1
            For i = 1 To mrc.Fields.Count
                Select Case mrc.Fields(i - 1).Type
                  Case adDBDate
                    .TextMatrix(.Rows - 1, i) = Format(mrc.Fields(i - 1) & "", "yyyy-mm-dd")
                  Case Else
                    .TextMatrix(.Rows - 1, i) = mrc.Fields(i - 1) & ""
                End Select
            Next i
            mrc.MoveNext
        Loop

    End With
    mrc.Close

End Sub

'显示Grid表头
Private Sub ShowTitle()
    Dim i As Integer

    With msgList
        .Cols = 12
        .TextMatrix(0, 1) = ""
        .TextMatrix(0, 2) = ""
        .TextMatrix(0, 3) = "供应商名称"
        .TextMatrix(0, 4) = ""
        .TextMatrix(0, 5) = "商品名称"
        .TextMatrix(0, 6) = "商品规格"
        .TextMatrix(0, 7) = "商品单位"
        .TextMatrix(0, 8) = "商品数量"
        .TextMatrix(0, 9) = "商品单价"
        .TextMatrix(0, 10) = "进货日期"
        .TextMatrix(0, 11) = "备注信息"

        '固定表头
        .FixedRows = 1

        '设置各列的对齐方式
        For i = 0 To 11
            .ColAlignment(i) = 0
        Next i

        '表头项居中
        .FillStyle = flexFillRepeat
        .Col = 0
        .Row = 0
        .RowSel = 1
        .ColSel = .Cols - 1
        .CellAlignment = 4

        '设置单元大小
        .ColWidth(0) = 1000
        .ColWidth(1) = 0
        .ColWidth(2) = 0
        .ColWidth(3) = 3000
        .ColWidth(4) = 0
        .ColWidth(5) = 1000
        .ColWidth(6) = 1000
        .ColWidth(7) = 1000
        .ColWidth(8) = 1000
        .ColWidth(9) = 1000
        .ColWidth(10) = 1000
        .ColWidth(11) = 1000

        .Row = 1

    End With
End Sub

Private Sub msgList_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
    '右键弹出
    If Button = 2 And Shift = 0 Then
        PopupMenu fMainForm.menuStock
    End If

End Sub