playcontrol.as

as3歌词解析实例,源文件

package com.ninemoon{
	import flash.display.*;
	import flash.events.*;

	import com.ninemoon.Main;
	import com.ninemoon.PlayList;

	public class PlayControl extends Sprite {

		private static  var _instance:PlayControl;
		private var _position:int;
		private var _length:int;

		public function PlayControl() {
			init();
		}
		public static function getInstance():PlayControl {
			if (PlayControl._instance==null) {
				PlayControl._instance=new PlayControl();
			}
			return PlayControl._instance;
		}
		public function init():void {
			redian_mc.alpha=0;
			redian_mc.addEventListener(MouseEvent.CLICK,seekOnClick);
			redian_mc.useHandCursor= true;

			play_btn.visible=false;
			stop_btn.visible=true;
			play_btn.removeEventListener(MouseEvent.CLICK,onPlayClick);
			stop_btn.addEventListener(MouseEvent.CLICK,onStopClick);
			restart_btn.addEventListener(MouseEvent.CLICK,onRestartClick);
		}
		private function onPlayClick(event:MouseEvent):void {
			//Main.sc=Main.sound.play(_position);
			PlayList.getInstance().playplay(_position);
			Main.timer.start();

			play_btn.visible=false;
			stop_btn.visible=true;
			play_btn.removeEventListener(MouseEvent.CLICK,onPlayClick);
			stop_btn.addEventListener(MouseEvent.CLICK,onStopClick);
			redian_mc.addEventListener(MouseEvent.CLICK,seekOnClick);
		}
		private function onStopClick(event:MouseEvent):void {
			_position=Main.sc.position;
			Main.sc.stop();
			Main.timer.stop();
			play_btn.visible=true;
			stop_btn.visible=false;
			play_btn.addEventListener(MouseEvent.CLICK,onPlayClick);
			stop_btn.removeEventListener(MouseEvent.CLICK,onStopClick);
			redian_mc.removeEventListener(MouseEvent.CLICK,seekOnClick);
		}
		private function onRestartClick(event:MouseEvent):void {
			Main.sc.stop();
			Main.timer.stop();
			_position=0;
			stop_btn.visible=false;
			play_btn.visible=true;
			stop_btn.removeEventListener(MouseEvent.CLICK,onStopClick);
			play_btn.addEventListener(MouseEvent.CLICK,onPlayClick);
		}
		private function seekOnClick(event:MouseEvent):void {
			var time:Number=((this.mouseX-8)/center_bg.width)*_length;
			 Main.sc.stop();
			 Main.sc=Main.sound.play(time);

			//PlayList.getInstance().playplay(time);
		}
		public function progressHandler():void {
			if (Main.sound!=null) {
				var loaded:int = Main.sound.bytesLoaded;
				var total:int = Main.sound.bytesTotal;

				_length = Main.sound.length;
				var position:int = Main.sc.position;

				if (total > 0) {

					var percentBuffered:Number = loaded / total;

					progress_bar.width=center_bg.width*percentBuffered;
					redian_mc.width=progress_bar.width;

					_length /= percentBuffered;

					var percentPlayed:Number = position/_length;
					percent_bar.width=center_bg.width*percentPlayed;
					pro_bar.x=8+percent_bar.width;
				}
			}
		}
	}
}