powereasy.job.asp

个人网站比较简短

<%
'**************************************************************
' Software name: PowerEasy SiteWeaver
' Web: http://www.powereasy.net
' Copyright (C) 2005－2008 佛山市动易网络科技有限公司 版权所有
'**************************************************************

Class Job

Private strListStr_Font

Public Sub Init()
    ChannelShortName = "职位"

    If XmlDoc.Load(Server.MapPath(InstallDir & "Language/Gb2312_Channel_" & ChannelID & ".xml")) = False Then XmlDoc.Load (Server.MapPath(InstallDir & "Language/Gb2312.xml"))

    strListStr_Font = XmlText_Class("JobList/UpdateTimeColor_New", "color=""red""")

    
    strNavPath = XmlText("BaseText", "Nav", "您现在的位置：") & "&nbsp;<a class='LinkPath' href='" & SiteUrl & "'>" & SiteName & "</a>"
    strPageTitle = SiteTitle
    
    Call GetChannel(ChannelID)
    HtmlDir = strInstallDir & ChannelDir
    If Trim(ChannelName) <> "" And ShowChannelName <> False Then
        If UseCreateHTML > 0 Then
            strNavPath = strNavPath & "&nbsp;" & strNavLink & "&nbsp;<a class='LinkPath' href='" & ChannelUrl & "/Index" & FileExt_Index & "'>" & ChannelName & "</a>"
        Else
            strNavPath = strNavPath & "&nbsp;" & strNavLink & "&nbsp;<a class='LinkPath' href='" & ChannelUrl & "/Index.asp'>" & ChannelName & "</a>"
        End If
        strPageTitle = strPageTitle & " >> " & ChannelName
    End If
    
End Sub


Private Sub ReleaseDate_OptionJS()
    Call Init
    Dim ReleaseDateJS, ReleaseDate_FileName
    Dim strReleaseDate
    strReleaseDate = "<select name='SearchDateNum'>"
    strReleaseDate = strReleaseDate & "<option value=''>-- 请选择发布日期--</option>"
    strReleaseDate = strReleaseDate & "<option value='0'>一天内</option>"
    strReleaseDate = strReleaseDate & "<option value='1'>近两天</option>"
    strReleaseDate = strReleaseDate & "<option value='2'>近三天</option>"
    strReleaseDate = strReleaseDate & "<option value='6'>近一周</option>"
    strReleaseDate = strReleaseDate & "<option value='13'>近两周</option>"
    strReleaseDate = strReleaseDate & "<option value='29'>近一个月</option>"
    strReleaseDate = strReleaseDate & "<option value='59'>近两个月</option>"
    strReleaseDate = strReleaseDate & "<option value='89'>近三个月</option>"
    strReleaseDate = strReleaseDate & "</select>"
    strReleaseDate = "document.write(""" & strReleaseDate & """);"
    ReleaseDate_FileName = strInstallDir & "Job/JS/ReleaseDate_Option.js"
    Call WriteToFile(ReleaseDate_FileName, strReleaseDate)
End Sub


'函数名：GetPositionList
'作  用：显示职位名称等信息
'参  数：
'1        PositionNum ---职位数，若大于0，则只查询前几个职位
'2        IsUrgent ------------是否是紧急招聘，True为只显示紧急招聘职位，False为显示所有招聘职位
'3        DateNum ----日期范围，如果大于0，则只显示最近几天内更新的职位
'4        OrderType ----排序方式，1----按职位ID降序，2----按职位ID升序，3----按更新时间降序，4----按更新时间升序
'5        ShowType -----显示方式，1为紧急招聘，2为最新招聘，3为分页显示招聘信息列表
'6        TitleLen  ----职位名称最多字符数，一个汉字=两个英文字符，若为0，则显示完整职位名
'7        WorkPlaceNameLen-----工作地点最多字符数，一个汉字=两个英文字符，若为0，则显示完整职位名
'8        SubCompanyNameLen----用人单位最多字符数，一个汉字=两个英文字符，若为0，则显示完整职位名
'9        PShowPoints-----职位名称设置最多字符数时是否显示省略号，True---显示， False---不显示
'10       WShowPoints-----工作地点名称设置最多字符数时是否显示省略号，True---显示， False---不显示
'11       SShowPoints-----用人单位名称设置最多字符数时是否显示省略号，True---显示， False---不显示
'12       ShowDateType ------显示更新日期的样式，0为不显示，1为显示年月日，2为只显示月日，3为以“月-日”方式显示月日。
'13       ShowPositionID -----------是否显示职位ID，0为不显示， 1为显示
'14       ShowPositionName -----------是否显示职位名称， 0为不显示， 1为显示
'15       ShowWorkPlaceName -----------是否显示工作地点， 0为不显示， 1为显示
'16       ShowSubCompanyName -----------是否显示用人单位， 0为不显示， 1为显示
'17       ShowPositionNum -----------是否显示招聘人数， 0为不显示， 1为显示
'18       ShowPositionStatus -----------是否职位状态， 0为不显示， 1为显示
'19       ShowValidDate -----------是否显示有效期， 0为不显示， 1为显示
'20       ShowUrgentSign -----------是否显示紧急招聘标志，True为显示，False为不显示
'21       ShowNewSign -------是否显示新招聘标志，True为显示，False为不显示
'22       UsePage ----------是否分页显示，True为分页显示，False为不分页显示
'23       OpenType -----申请职位打开方式，0为在原窗口打开，1为在新窗口打开
'=================================================

Private Function GetPositionList(PositionNum, IsUrgent, DateNum, OrderType, ShowType, TitleLen, WorkPlaceNameLen, SubCompanyNameLen, PShowPoints, WShowPoints, SShowPoints, ShowDateType, ShowPositionID, ShowPositionName, ShowWorkPlaceName, ShowSubCompanyName, ShowPositionNum, ShowPositionStatus, ShowValidDate, ShowUrgentSign, ShowNewSign, UsePage, OpenType)

    Dim sqlPosition, rsPositionList, iCount, strPositionList, TitleStrstrLink, TitleStr, strLink
    Dim iTop, iElite, iCommon, iHot, iNew, iTitle1, iTitle2
    iCount = 0

    If TitleLen < 0 Or TitleLen > 200 Then
        TitleLen = 50
    End If
    
    If PositionNum > 0 Then
        sqlPosition = "select top " & PositionNum & " "
    Else
        sqlPosition = "select "
    End If
    sqlPosition = sqlPosition & "P.PositionID,P.PositionName,W.WorkPlaceName,P.ReleaseDate,P.PositionNum,P.ValidDate,P.PositionStatus,P.SubCompanyName from PE_Position P left join PE_WorkPlace W on P.WorkPlaceID=W.WorkPlaceID"
    
    If IsUrgent = True Then
        sqlPosition = sqlPosition & " where P.Urgent=0"
        If DateNum > 0 Then
            sqlPosition = sqlPosition & " and DateDiff(" & PE_DatePart_D & ",P.ReleaseDate," & PE_Now & ")<" & DateNum & " and P.PositionStatus=0"
        Else
            sqlPosition = sqlPosition & " and P.PositionStatus=0"
        End If
    Else
        If DateNum > 0 Then
            sqlPosition = sqlPosition & " where DateDiff(" & PE_DatePart_D & ",P.ReleaseDate," & PE_Now & ")<" & DateNum & " and P.PositionStatus=0"
        Else
            sqlPosition = sqlPosition & " where P.PositionStatus=0"
        End If
    End If
    sqlPosition = sqlPosition & " order by "
    Select Case PE_CLng(OrderType)
    Case 1
        sqlPosition = sqlPosition & "P.PositionID desc"
    Case 2
        sqlPosition = sqlPosition & "P.PositionID asc"
    Case 3
        sqlPosition = sqlPosition & "P.ReleaseDate desc,P.PositionID desc"
    Case 4
        sqlPosition = sqlPosition & "P.ReleaseDate asc,P.PositionID desc"
    Case Else
        sqlPosition = sqlPosition & "P.PositionID desc"
    End Select
    Set rsPositionList = Server.CreateObject("ADODB.Recordset")
    rsPositionList.Open sqlPosition, Conn, 1, 1
    If rsPositionList.BOF And rsPositionList.EOF Then
        If UsePage = True Then totalPut = 0
        If IsUrgent = True Then
            strPositionList = "<li>" & XmlText_Class("PositionList/t1", "没有") & XmlText_Class("PositionList/t1", "紧急") & "招聘信息</li>"
        Else
            If DateNum > 0 Then
                strPositionList = "<li>" & XmlText_Class("PositionList/t1", "没有") & XmlText_Class("PositionList/t1", "最近") & DateNum & "天招聘信息</li>"
            Else
                strPositionList = "<li>" & XmlText_Class("PositionList/t1", "没有") & XmlText_Class("PositionList/t1", "任何") & "招聘信息</li>"
            End If
        End If
        rsPositionList.Close
        Set rsPositionList = Nothing
        GetPositionList = strPositionList
        Exit Function
    End If
    If UsePage = True Then
        totalPut = rsPositionList.RecordCount
        If CurrentPage < 1 Then
            CurrentPage = 1
        End If
        If (CurrentPage - 1) * MaxPerPage > totalPut Then
            If (totalPut Mod MaxPerPage) = 0 Then
                CurrentPage = totalPut \ MaxPerPage
            Else
                CurrentPage = totalPut \ MaxPerPage + 1
            End If
        End If
        If CurrentPage > 1 Then
            If (CurrentPage - 1) * MaxPerPage < totalPut Then
                rsPositionList.Move (CurrentPage - 1) * MaxPerPage
            Else
                CurrentPage = 1
            End If
        End If
    End If
    Dim iPositionIDLen, iPositionNameLen, iWorkPlaceNameLen, iSubCompanyNameLen, iPositionNumLen, iPositionStatusLen, iValidDateLen, iReleaseDateLen
    iPositionIDLen = R_XmlText_Class("ShowPosition/PositionIDLen", "60")
    iPositionNameLen = R_XmlText_Class("ShowPosition/PositionNameLen", "80")
    iWorkPlaceNameLen = R_XmlText_Class("ShowPosition/WorkPlaceNameLen", "80")
    iSubCompanyNameLen = R_XmlText_Class("ShowPosition/SubCompanyNameLen", "120")
    iPositionNumLen = R_XmlText_Class("ShowPosition/PositionNumLen", "60")
    iPositionStatusLen = R_XmlText_Class("ShowPosition/PositionStatusLen", "60")
    iValidDateLen = R_XmlText_Class("ShowPosition/ValidDateLen", "60")
    iReleaseDateLen = R_XmlText_Class("ShowPosition/ReleaseDateLen", "80")
    

    If ShowType = 3 Then
        strPositionList = "<table width='100%' cellpadding='0' cellspacing='0'>"
        strPositionList = strPositionList & "<tr'>"
        If ShowPositionID > 0 Then
            strPositionList = strPositionList & "<td width='" & iPositionIDLen & "' align='center'>" & R_XmlText_Class("ShowPosition/PositionID", "编号") & "</td>"
        End If
        If ShowPositionName > 0 Then
            strPositionList = strPositionList & "<td width='" & iPositionNameLen & "' align='center'>" & R_XmlText_Class("ShowPosition/PositionName", "职位名称") & "</td>"
        End If
        If ShowWorkPlaceName > 0 Then
            strPositionList = strPositionList & "<td width='" & iWorkPlaceNameLen & "' align='center'>" & R_XmlText_Class("ShowPosition/WorkPlaceName", "工作地点") & "</td>"
        End If
        If ShowSubCompanyName > 0 Then
            strPositionList = strPositionList & "<td width='" & iSubCompanyNameLen & "' align='center'>" & R_XmlText_Class("ShowPosition/SubCompanyName", "用人单位") & "</td>"
        End If
        If ShowPositionNum > 0 Then
            strPositionList = strPositionList & "<td width='" & iPositionNumLen & "' align='center'>" & R_XmlText_Class("ShowPosition/PositionNum", "招聘人数") & "</td>"
        End If
        If ShowPositionStatus > 0 Then
            strPositionList = strPositionList & "<td width='" & iPositionStatusLen & "' align='center'>" & R_XmlText_Class("ShowPosition/PositionStatus", "职位状态") & "</td>"
        End If
        If ShowValidDate > 0 Then
            strPositionList = strPositionList & "<td width='" & iValidDateLen & "' align='center'>" & R_XmlText_Class("ShowPosition/ValidDate", "有效期") & "</td>"
        End If
        If ShowDateType > 0 Then
            strPositionList = strPositionList & "<td width='" & iReleaseDateLen & "' align='center'>" & R_XmlText_Class("ShowPosition/ReleaseDate", "发布日期") & "</td>"
        End If
        strPositionList = strPositionList & "</tr>"
    Else
        strPositionList = ""
    End If
        
    Do While Not rsPositionList.EOF
        
        If TitleLen > 0 Then
            TitleStr = GetSubStr(rsPositionList("PositionName"), TitleLen, PShowPoints)
        Else
            TitleStr = rsPositionList("PositionName")
        End If
        
        strLink = "<a href='SupplyInfo.asp?PositionID=" & rsPositionList("PositionID") & "'"
        If OpenType = 0 Then
            strLink = strLink & " target='_self'>"
        Else
            strLink = strLink & " target='_blank'>"
        End If
        strLink = strLink & TitleStr & "</a>"

        If ShowType = 1 Then
            strPositionList = strPositionList & "&nbsp;" & strLink
            If ShowWorkPlaceName > 0 Then
                If WorkPlaceNameLen > 0 Then
                    strPositionList = strPositionList & "&nbsp;" & GetSubStr(rsPositionList("WorkPlaceName"), WorkPlaceNameLen, WShowPoints)
                Else
                    strPositionList = strPositionList & "&nbsp;" & rsPositionList("WorkPlaceName")
                End If
            End If
            If ShowSubCompanyName > 0 Then
                If SubCompanyNameLen > 0 Then
                    strPositionList = strPositionList & "&nbsp;" & GetSubStr(rsPositionList("SubCompanyName"), SubCompanyNameLen, SShowPoints)
                Else
                    strPositionList = strPositionList & "&nbsp;" & rsPositionList("SubCompanyName")
                End If
            End If
            If ShowPositionNum > 0 Then
                strPositionList = strPositionList & "&nbsp;" & rsPositionList("PositionNum")
            End If
            If ShowPositionStatus > 0 Then
                strPositionList = strPositionList & "&nbsp;" & GetPositionStatus(rsPositionList("PositionStatus"), rsPositionList("ReleaseDate"), rsPositionList("ValidDate"))
            End If
            If ShowValidDate > 0 Then
                strPositionList = strPositionList & "&nbsp;" & rsPositionList("ValidDate")
            End If
            If ShowUrgentSign = True Then
                strPositionList = strPositionList & "<img src='" & strInstallDir & "images/Urgent.gif' >"
            End If
            If ShowDateType > 0 Then
                strPositionList = strPositionList & "&nbsp;("