admin_bank.asp

个人网站比较简短

    Response.Write "      <td height='50' colspan='2'><input name='BankID' type='hidden' id='BankID' value='" & BankID & "'>" & vbCrLf
    Response.Write "      <input name='Action' type='hidden' id='Action' value='SaveModify'>" & vbCrLf
    Response.Write "          <input type='submit' name='Submit' value='保存银行帐户'></td>" & vbCrLf
    Response.Write "    </tr>" & vbCrLf
    Response.Write "  </table>" & vbCrLf
    Response.Write "</form>" & vbCrLf
    Response.Write "" & vbCrLf
    Set rsBank = Nothing
End Sub

Sub SaveBank()
    Dim BankID, BankShortName, BankName, Accounts, CardNum, HolderName, BankIntro, BankPic, IsDefault, OrderID
    Dim rsBank, sqlBank
    BankID = Trim(Request("BankID"))
    BankShortName = ReplaceBadChar(Trim(Request("BankShortName")))
    BankName = Trim(Request("BankName"))
    Accounts = Trim(Request("Accounts"))
    CardNum = Trim(Request("CardNum"))
    HolderName = Trim(Request("HolderName"))
    BankIntro = Trim(Request("BankIntro"))
    BankPic = Trim(Request("BankPic"))
    IsDefault = Trim(Request("IsDefault"))
    If Action = "SaveAdd" And BankShortName = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定帐户名称</li>"
    End If
    If BankName = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定开户行</li>"
    End If
    If HolderName = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定户名</li>"
    End If
    If Accounts = "" And CardNum = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>至少要输入帐号和卡号的其中一个</li>"
    End If
    If IsDefault = "Yes" Then
        IsDefault = True
        Conn.Execute ("update PE_Bank set IsDefault=" & PE_False & "")
    Else
        IsDefault = False
    End If
    
    If Action = "SaveAdd" Then
        sqlBank = "select top 1 * from PE_Bank"
        Dim trs, mrs
        Set trs = Conn.Execute("select BankID from PE_Bank where BankShortName='" & BankShortName & "'")
        If Not (trs.BOF And trs.EOF) Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>指定的帐户名称已经存在！</li>"
        Else
            Set mrs = Conn.Execute("select max(BankID) from PE_Bank")
            If IsNull(mrs(0)) Then
                BankID = 1
            Else
                BankID = mrs(0) + 1
            End If
            Set mrs = Nothing
            Set mrs = Conn.Execute("select max(OrderID) from PE_Bank")
            If IsNull(mrs(0)) Then
                OrderID = 1
            Else
                OrderID = mrs(0) + 1
            End If
            Set mrs = Nothing
        End If
        Set trs = Nothing
    Else
        If BankID = "" Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请指定BankID！</li>"
        Else
            BankID = PE_CLng(BankID)
        End If
        sqlBank = "select * from PE_Bank where BankID=" & BankID
    End If
    
    If FoundErr = True Then Exit Sub
    
    Set rsBank = Server.CreateObject("adodb.recordset")
    rsBank.Open sqlBank, Conn, 1, 3
    If Action = "SaveAdd" Then
        rsBank.AddNew
        rsBank("BankID") = BankID
        rsBank("OrderID") = OrderID
        rsBank("IsDisabled") = False
        rsBank("BankShortName") = BankShortName
    End If
    
    rsBank("BankName") = BankName
    rsBank("Accounts") = Accounts
    rsBank("CardNum") = CardNum
    rsBank("HolderName") = HolderName
    rsBank("BankIntro") = BankIntro
    rsBank("BankPic") = BankPic
    rsBank("IsDefault") = IsDefault
    rsBank.Update
    rsBank.Close
    Set rsBank = Nothing
    Call WriteEntry(2, AdminName, "保存银行帐户信息成功：" & BankName)
    Call CloseConn
    Response.Redirect "Admin_Bank.asp"
End Sub

Sub Del()
    Dim BankID
    BankID = Trim(Request("BankID"))
    If BankID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定银行帐户ID</li>"
        Exit Sub
    Else
        BankID = PE_CLng(BankID)
    End If
    
    Dim rsBank, trs
    Set rsBank = Server.CreateObject("adodb.recordset")
    rsBank.Open "select * from PE_Bank where BankID=" & BankID & "", Conn, 1, 3
    If rsBank.BOF And rsBank.EOF Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>找不到指定的银行帐户"
    Else
        If rsBank("IsDefault") = True Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>不能删除默认的银行帐户</li>"
        End If
        Set trs = Conn.Execute("select top 1 ItemID from PE_BankrollItem where Bank='" & rsBank("BankShortName") & "'")
        If Not (trs.BOF And trs.EOF) Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>此银行帐户已经有资金明细记录，所以不能删除！但你可以禁用此银行帐户，以达到前台不显示此银行帐户的目的。</li>"
        End If
        Set trs = Nothing
        If FoundErr = False Then
            rsBank.Delete
            rsBank.Update
        End If
    End If
    rsBank.Close
    Set rsBank = Nothing
    Call WriteEntry(2, AdminName, "删除银行帐户成功，ID：" & BankID)

    Call CloseConn
    If FoundErr = False Then
        Response.Redirect "Admin_Bank.asp"
    End If
End Sub

Sub DisableBank()
    Dim BankID
    BankID = Trim(Request("BankID"))
    If BankID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定银行帐户ID</li>"
    Else
        BankID = PE_CLng(BankID)
    End If
    If FoundErr = True Then Exit Sub
    Dim trs
    Set trs = Conn.Execute("select IsDefault from PE_Bank where BankID=" & BankID & "")
    If trs.BOF And trs.EOF Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>找不到指定的银行帐户</li>"
    Else
        If trs(0) = True Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>不能禁用默认的银行帐户</li>"
        End If
    End If
    Set trs = Nothing
    If FoundErr = True Then Exit Sub
    
    Select Case Action
    Case "Disable"
        Conn.Execute ("update PE_Bank set IsDisabled=" & PE_True & " where BankID=" & BankID & "")
    Case "Enable"
        Conn.Execute ("update PE_Bank set IsDisabled=" & PE_False & " where BankID=" & BankID & "")
    End Select

    Call CloseConn
    Response.Redirect "Admin_Bank.asp"
End Sub

Sub Order()
    Dim BankID, OrderID
    BankID = Trim(Request("BankID"))
    OrderID = Trim(Request("OrderID"))
    If BankID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定银行帐户ID</li>"
    Else
        BankID = PE_CLng(BankID)
    End If
    If OrderID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定OrderID</li>"
    Else
        OrderID = PE_CLng(OrderID)
    End If
    If FoundErr = True Then Exit Sub
    Conn.Execute ("update PE_Bank set OrderID=" & OrderID & " where BankID=" & BankID & "")
    Call CloseConn
    Response.Redirect "Admin_Bank.asp"
End Sub

Sub SetDefault()
    Dim BankID
    BankID = Trim(Request("BankID"))
    If BankID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定BankID</li>"
        Exit Sub
    Else
        BankID = PE_CLng(BankID)
    End If
    Conn.Execute ("update PE_Bank set IsDefault=" & PE_False & "")
    Conn.Execute ("update PE_Bank set IsDefault=" & PE_True & " where  BankID=" & BankID)
    Call CloseConn
    Response.Redirect "Admin_Bank.asp"
End Sub
%>