admin_card.asp

个人网站比较简短

    ProductID = PE_CLng(Trim(Request.Form("ProductID")))
    AddType = PE_CLng(Trim(Request.Form("AddType")))
    
    CardNum = ReplaceBadChar(Trim(Request.Form("CardNum")))
    Password = ReplaceBadChar(Trim(Request.Form("Password")))
    
    CardText = Trim(Request.Form("CardText"))
    strSplit = Trim(Request.Form("strSplit"))
    
    Money = PE_CDbl(Trim(Request.Form("Money")))
    ValidUnit = PE_CLng(Trim(Request.Form("ValidUnit")))
    If ValidUnit = 5 Then
        ValidNum = PE_CLng(Trim(Request.Form("GroupList")))
    Else
        ValidNum = PE_CLng(Trim(Request.Form("ValidNum")))
    End If
    EndDate = Trim(Request.Form("EndDate"))
    AgentName = Trim(Request.Form("AgentName"))
    If CardType = 1 And ProductID = 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>其他公司卡必须通过商城销售。请指定所属商品。</li>"
    End If
    If AddType = 0 Then
        If CardNum = "" Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请指定充值卡ID</li>"
        End If
        If Password = "" Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请指定充值卡密码</li>"
        End If
    Else
        If CardText = "" Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请输入批量添加的充值卡格式文本</li>"
        End If
        If strSplit = "" Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请指定分隔符</li>"
        End If
    End If
    If Money <= 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定充值卡的面值！</li>"
    End If
    If ValidNum <= 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定充值卡的点数！</li>"
    End If
    If IsDate(EndDate) = False Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定正确的充值截止日期！</li>"
    Else
        EndDate = CDate(EndDate)
        If EndDate <= Date Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>充值截止日期不能比当前日期还早</li>"
        End If
    End If
    If FoundErr = True Then Exit Sub
    
    If AddType = 0 Then
        Set rsCard = Server.CreateObject("Adodb.Recordset")
        rsCard.Open "select * from PE_Card where CardNum='" & CardNum & "' and ProductID=" & ProductID & "", Conn, 1, 3
        If Not (rsCard.Bof And rsCard.EOF) Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>输入的充值卡卡号已经存在！</li>"
        End If
        If FoundErr = True Then
            Set rsCard = Nothing
            Exit Sub
        End If
        rsCard.AddNew
        rsCard("CardType") = CardType
        rsCard("ProductID") = ProductID
        rsCard("CardNum") = CardNum
        rsCard("Password") = Base64encode(Password)
        rsCard("Money") = Money
        rsCard("ValidNum") = ValidNum
        rsCard("ValidUnit") = ValidUnit
        rsCard("EndDate") = EndDate
        rsCard("AgentName") = AgentName
        rsCard("UserName") = ""
        rsCard("CreateTime") = Now()
        rsCard("OrderFormItemID") = 0
        rsCard.Update
        rsCard.Close
        Set rsCard = Nothing
        If ProductID > 0 Then
            Conn.Execute ("update PE_Product set Stocks=Stocks+1 where ProductID=" & ProductID & "")
        End If
        Call CloseConn
        Response.Redirect "Admin_Card.asp"
    Else
        Dim arrCard, arrCard2, i, iCount
        arrCard = Split(CardText, vbCrLf)
        iCount = 0
        Set rsCard = Server.CreateObject("Adodb.Recordset")
        For i = 0 To UBound(arrCard)
            If Trim(arrCard(i)) <> "" Then
                If InStr(arrCard(i), strSplit) <> 0 Then
                    arrCard2 = Split(Trim(arrCard(i)), strSplit)
                    CardNum = ReplaceBadChar(Trim(arrCard2(0)))
                    If CardNum <> "" And Trim(arrCard2(1)) <> "" Then
                        rsCard.Open "select * from PE_Card where CardNum='" & CardNum & "' and ProductID=" & ProductID & "", Conn, 1, 3
                        If rsCard.Bof And rsCard.EOF Then
                            rsCard.AddNew
                            rsCard("CardType") = CardType
                            rsCard("ProductID") = ProductID
                            rsCard("CardNum") = CardNum
                            rsCard("Password") = Base64encode(Trim(arrCard2(1)))
                            rsCard("Money") = Money
                            rsCard("ValidNum") = ValidNum
                            rsCard("ValidUnit") = ValidUnit
                            rsCard("EndDate") = EndDate
                            rsCard("UserName") = ""
                            rsCard("CreateTime") = Now()
                            rsCard("OrderFormItemID") = 0
                            rsCard.Update
                            rsCard.Close
                            iCount = iCount + 1
                            Response.Write "<li>卡号为：" & CardNum & " 的充值卡成功添加到数据库中！</li>"
                        Else
                            Response.Write "<li>卡号为：" & CardNum & " 的充值卡已经存在！</li>"
                            rsCard.Close
                        End If
                    End If
                Else
                    Response.Write "<li>添加的第" & i + 1 & "条卡号信息有误"
                End If
            End If
            Response.Flush
        Next
        If ProductID > 0 Then
            Conn.Execute ("update PE_Product set Stocks=Stocks+" & iCount & " where ProductID=" & ProductID & "")
        End If
        Set rsCard = Nothing
    End If
End Sub

Sub SaveModify()
    Dim CardID, rsCard
    Dim Password, Money, ValidNum, ValidUnit, EndDate
    Password = ReplaceBadChar(Trim(Request.Form("Password")))
    Money = PE_CDbl(Trim(Request.Form("Money")))
    ValidUnit = PE_CLng(Trim(Request.Form("ValidUnit")))
    If ValidUnit = 5 Then
        ValidNum = PE_CLng(Trim(Request.Form("GroupList")))
    Else
        ValidNum = PE_CLng(Trim(Request.Form("ValidNum")))
    End If
    EndDate = Trim(Request.Form("EndDate"))
    CardID = PE_CLng(Trim(Request("CardID")))
    If CardID = 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定充值卡ID</li>"
    End If
    If Money <= 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定充值卡的面值！</li>"
    End If
    If Password = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定充值卡的密码！</li>"
    End If
    If ValidNum <= 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定充值卡的点数！</li>"
    End If
    If IsDate(EndDate) = False Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定正确的充值截止日期！</li>"
    Else
        EndDate = CDate(EndDate)
        If EndDate <= Date Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>充值截止日期不能比当前日期还早</li>"
        End If
    End If
    If FoundErr = True Then Exit Sub

    Set rsCard = Server.CreateObject("Adodb.Recordset")
    rsCard.Open "select * from PE_Card where CardID=" & CardID & "", Conn, 1, 3
    If rsCard.Bof And rsCard.EOF Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>找不到指定的充值卡！</li>"
    Else
        If rsCard("UserName") <> "" Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>此充值卡已经被使用，不能再修改！</li>"
        End If
        If rsCard("OrderFormItemID") > 0 Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>此充值卡已经售出，不能再修改！</li>"
        End If
    End If
    If FoundErr = True Then
        Set rsCard = Nothing
        Exit Sub
    End If
    rsCard("Password") = Base64encode(Password)
    rsCard("Money") = Money
    rsCard("ValidNum") = ValidNum
    rsCard("ValidUnit") = ValidUnit
    rsCard("EndDate") = EndDate
    rsCard.Update
    rsCard.Close
    Set rsCard = Nothing
    Call CloseConn
    Response.Redirect "Admin_Card.asp"
End Sub

Sub DelCard()
    Dim CardID, rsCard
    CardID = Trim(Request("CardID"))
    If CardID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定要删除的充值卡ID</li>"
        Exit Sub
    Else
        If IsValidID(CardID) = False Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请指定正确的充值卡ID</li>"
            Exit Sub
        End If
    End If
    If InStr(CardID, ",") > 0 Then
        Set rsCard = Conn.Execute("select CardID,ProductID from PE_Card where CardID in (" & CardID & ") and UserName='' and OrderFormItemID=0")
        Do While Not rsCard.EOF
            If rsCard("ProductID") > 0 Then
                Conn.Execute ("update PE_Product set Stocks=Stocks-1 where ProductID=" & rsCard("ProductID") & "")
            End If
            rsCard.MoveNext
        Loop
        Set rsCard = Nothing
        
        Conn.Execute ("delete from PE_Card where CardID in (" & CardID & ") and UserName='' and OrderFormItemID=0")
    Else
        Set rsCard = Conn.Execute("select CardID,ProductID from PE_Card where CardID =" & CardID & " and UserName='' and OrderFormItemID=0")
        Do While Not rsCard.EOF
            If rsCard("ProductID") > 0 Then
                Conn.Execute ("update PE_Product set Stocks=Stocks-1 where ProductID=" & rsCard("ProductID") & "")
            End If
            rsCard.MoveNext
        Loop
        Set rsCard = Nothing
        Conn.Execute ("delete from PE_Card where CardID=" & CardID & " and UserName='' and OrderFormItemID=0")
    End If
    Call main
End Sub

Function GetProductName(iProductID)
    If iProductID = 0 Then
        GetProductName = "不通过商城销售"
    Else
        Dim rsProduct
        Set rsProduct = Conn.Execute("select ProductName from PE_Product where ProductID=" & iProductID & "")
        If rsProduct.Bof And rsProduct.EOF Then
            GetProductName = "找不到所属商品"
        Else
            GetProductName = rsProduct(0)
        End If
        Set rsProduct = Nothing
    End If
End Function

Function GetValidNum(intValidNum, intValidUnit)
    If intValidUnit = 5 Then
        Dim rsGroupList
        Set rsGroupList = Conn.Execute("Select GroupName from PE_UserGroup where GroupID = " & intValidNum)
        If Not (rsGroupList.EOF And rsGroupList.Bof) Then
            GetValidNum = rsGroupList("GroupName")
        Else
            GetValidNum = intValidNum
        End If
        rsGroupList.Close
        Set rsGroupList = Nothing
    Else
        GetValidNum = intValidNum
    End If
End Function
%>