admin_smspost.asp

个人网站比较简短

            End If
        End If
        rsUser.movenext
    Loop
    rsUser.Close
    Set rsUser = Nothing
    GetReciever_Member = strReciever
End Function

Function GetReciever_Contacter()
    Dim InceptType, GroupID, TrueName
    Dim sqlContacter, strReciever, strMobile
    strReciever = ""
    sqlContacter = "select TrueName,Mobile,PHS from PE_Contacter where (Mobile<>'' or PHS<>'')"
    InceptType = PE_CLng(Trim(Request("InceptType")))
    Select Case InceptType
    Case 0  '所有会员
        
    Case 1  '指定地区
        sqlContacter = sqlContacter & " and Country='" & ReplaceBadChar(Request("Country")) & "'"
        sqlContacter = sqlContacter & " and Province='" & ReplaceBadChar(Request("Province")) & "'"
        sqlContacter = sqlContacter & " and City='" & ReplaceBadChar(Request("City")) & "'"
    Case 2  '指定联系人
        TrueName = Replace(ReplaceBadChar(Request("TrueName")), ",", "','")
        sqlContacter = sqlContacter & " and TrueName in ('" & TrueName & "')"
    End Select
    sqlContacter = sqlContacter & " order by Mobile,PHS"
    Dim rsContacter, strMoblie
    Set rsContacter = server.CreateObject("adodb.recordset")
    rsContacter.open sqlContacter, Conn, 1, 1
    ReDim arrMobile(rsContacter.recordcount)
    Do While Not rsContacter.EOF
        strMobile = rsContacter("Mobile")
        If strMobile = "" Then strMobile = rsContacter("PHS")
        strMobile = GetValidNumber(strMobile)
        If strMobile <> "" Then
            If FoundMobile(strMobile, RecieverCount) = False Then
                arrMobile(RecieverCount) = strMobile
                If strReciever <> "" Then
                    strReciever = strReciever & vbCrLf
                End If
                strReciever = strReciever & strMobile & "," & rsContacter("TrueName")
                RecieverCount = RecieverCount + 1
            End If
        End If
        rsContacter.movenext
    Loop
    rsContacter.Close
    Set rsContacter = Nothing
    GetReciever_Contacter = strReciever
End Function

Function GetReciever_Consignee()
    Dim InceptType, GroupID, OrderFormID
    Dim sqlOrder, strReciever, strMobile
    strReciever = ""
    sqlOrder = "select OrderFormNum,ContacterName,Mobile,Phone from PE_OrderForm where (Mobile<>'' or Phone<>'')"
    InceptType = PE_CLng(Trim(Request("InceptType")))
    Select Case InceptType
    Case 0  '所有订单
        
    Case 1  '查询条件
        Dim BeginID, EndID, BeginDate, EndDate, MinMoney, MaxMoney, OrderStatus, PayStatus, DeliverStatus, OrderFormNum, ClientName, UserName, AgentName, ContacterName, Address, Phone, Mobile, Remark, ProductName
        BeginID = PE_CLng(Trim(Request("BeginID")))
        EndID = PE_CLng(Trim(Request("EndID")))
        BeginDate = Trim(Request("BeginDate"))
        EndDate = Trim(Request("EndDate"))
        MinMoney = PE_CDbl(Trim(Request("MinMoney")))
        MaxMoney = PE_CDbl(Trim(Request("MaxMoney")))
        OrderStatus = PE_CLng(Trim(Request("OrderStatus")))
        PayStatus = PE_CLng(Trim(Request("PayStatus")))
        DeliverStatus = PE_CLng(Trim(Request("DeliverStatus")))
        OrderFormNum = ReplaceBadChar(Trim(Request("OrderFormNum")))
        ClientName = ReplaceBadChar(Trim(Request("ClientName")))
        UserName = ReplaceBadChar(Trim(Request("UserName")))
        AgentName = ReplaceBadChar(Trim(Request("AgentName")))
        ContacterName = ReplaceBadChar(Trim(Request("ContacterName")))
        Address = ReplaceBadChar(Trim(Request("Address")))
        Phone = ReplaceBadChar(Trim(Request("Phone")))
        Mobile = ReplaceBadChar(Trim(Request("Mobile")))
        Remark = ReplaceBadChar(Trim(Request("Remark")))
        ProductName = ReplaceBadChar(Trim(Request("ProductName")))

        If BeginID > 0 Then
            sqlOrder = sqlOrder & " And OrderFormID>=" & BeginID
        End If
        If EndID > 0 Then
            sqlOrder = sqlOrder & " And OrderFormID<=" & EndID
        End If

        If BeginDate <> "" Then
            BeginDate = PE_CDate(BeginDate)
            If SystemDatabaseType = "SQL" Then
                sqlOrder = sqlOrder & " And InputTime>='" & BeginDate & "'"
            Else
                sqlOrder = sqlOrder & " And InputTime>=#" & BeginDate & "#"
            End If
        End If
        If EndDate <> "" Then
            EndDate = PE_CDate(EndDate)
            If SystemDatabaseType = "SQL" Then
                sqlOrder = sqlOrder & " And InputTime<='" & EndDate & "'"
            Else
                sqlOrder = sqlOrder & " And InputTime<=#" & EndDate & "#"
            End If
        End If
        If MinMoney > 0 Then
            sqlOrder = sqlOrder & " And MoneyTotal>=" & MinMoney
        End If
        If MaxMoney > 0 Then
            sqlOrder = sqlOrder & " And MoneyTotal<=" & MaxMoney
        End If
        If OrderStatus >= 0 Then
            sqlOrder = sqlOrder & " And Status=" & OrderStatus
        End If
        If PayStatus >= 0 Then
            Select Case PayStatus
            Case 0
                sqlOrder = sqlOrder & " And MoneyTotal>0 And MoneyReceipt=0"
            Case 1
                sqlOrder = sqlOrder & " And MoneyTotal>MoneyReceipt And MoneyReceipt>0"
            Case 2
                sqlOrder = sqlOrder & " And MoneyTotal<=MoneyReceipt"
            End Select
        End If
        If DeliverStatus >= 0 Then
            sqlOrder = sqlOrder & " And DeliverStatus=" & DeliverStatus
        End If
        If OrderFormNum <> "" Then
            sqlOrder = sqlOrder & " And OrderFormNum like '%" & OrderFormNum & "%'"
        End If
        If ClientName <> "" Then
            sqlOrder = "select O.OrderFormNum,O.ContacterName,O.Mobile,O.Phone from PE_OrderForm O left join PE_Client C on O.ClientID=C.ClientID where (O.Mobile<>'' or O.Phone<>'')"
            sqlOrder = sqlOrder & " And C.ClientName like '%" & ClientName & "%'"
        End If
        If UserName <> "" Then
            sqlOrder = sqlOrder & " And UserName like '%" & UserName & "%'"
        End If
        If AgentName <> "" Then
            sqlOrder = sqlOrder & " And AgentName='" & AgentName & "'"
        End If
        If ContacterName <> "" Then
            sqlOrder = sqlOrder & " And ContacterName like '%" & ContacterName & "%'"
        End If
        If Address <> "" Then
            sqlOrder = sqlOrder & " And Address like '%" & Address & "%'"
        End If
        If Phone <> "" Then
            sqlOrder = sqlOrder & " And Phone like '%" & Phone & "%'"
        End If
        If Mobile <> "" Then
            sqlOrder = sqlOrder & " And Mobile like '%" & Mobile & "%'"
        End If
        If Remark <> "" Then
            sqlOrder = sqlOrder & " And Remark like '%" & Remark & "%'"
        End If
        If ProductName <> "" Then
            sqlOrder = "select O.OrderFormNum,O.ContacterName,O.Mobile,O.Phone from PE_Product P inner join (Pe_OrderFormItem I inner join (PE_OrderForm O left join PE_Client C On O.ClientID = C.ClientID) on I.OrderFormID = O.OrderFormID) on P.ProductID = I.ProductID where (O.Mobile<>'' or O.Phone<>'')"
            sqlOrder = sqlOrder & " And P.ProductName like '%" & ProductName & "%'"
        End If

    Case 2  '指定订单ID
        OrderFormID = Trim(Request("OrderFormID"))
        If IsValidID(OrderFormID) = False Then
            OrderFormID = ""
        End If

        If OrderFormID = "" Then OrderFormID = "0"
        sqlOrder = sqlOrder & " and OrderFormID in (" & OrderFormID & ")"
    End Select
    sqlOrder = sqlOrder & " order by Mobile,Phone"
    Dim rsOrder, strMoblie
    Set rsOrder = server.CreateObject("adodb.recordset")
    rsOrder.open sqlOrder, Conn, 1, 1
    ReDim arrMobile(rsOrder.recordcount)
    Do While Not rsOrder.EOF
        strMobile = rsOrder("Mobile")
        If strMobile = "" Then strMobile = rsOrder("Phone")
        strMobile = GetValidNumber(strMobile)
        If strMobile <> "" Then
            If FoundMobile(strMobile, RecieverCount) = False Then
                arrMobile(RecieverCount) = strMobile
                If strReciever <> "" Then
                    strReciever = strReciever & vbCrLf
                End If
                strReciever = strReciever & strMobile & "," & rsOrder("ContacterName") & "," & rsOrder("OrderFormNum")
                RecieverCount = RecieverCount + 1
            End If
        End If
        rsOrder.movenext
    Loop
    rsOrder.Close
    Set rsOrder = Nothing
    GetReciever_Consignee = strReciever
End Function
%>