user_exchange_code.asp

个人网站比较简短

                        Response.Write "<td>"
                        If rsCard("CardType") = 0 Then
                            Response.Write "本站充值卡"
                        Else
                            Response.Write "<font color='blue'>其他公司卡</font>"
                        End If
                        Response.Write "</td>"
                        Response.Write "<td>" & rsCard("CardNum") & "</td>"
                        Response.Write "<td>" & Base64decode(rsCard("Password")) & "</td>"
                        Response.Write "<td>" & rsCard("Money") & "</td>"
                        Response.Write "<td>" & GetValidNum(rsCard("ValidNum"), rsCard("ValidUnit")) & arrCardUnit(rsCard("ValidUnit")) & "</td>"
                        Response.Write "<td>" & rsCard("EndDate") & "</td></tr>"
                        i = i + 1
                    End If
                    rsCard.MoveNext
                Loop
                If i = 0 Then
                    Response.Write "<tr class='tdbg' align='center'><td>" & rsOrderItem("Productname") & "</td><td colspan='10' height='50' align='center'>您购买的所有充值卡都已经使用。</td></tr>"
                End If
            End If
            Set rsCard = Nothing
            rsOrderItem.MoveNext
        Loop
        Response.Write "</table><br><br>"
    End If
    Set rsOrderItem = Nothing
    Response.Write "</td></tr>"
    Response.Write "<tr class='tdbg'><td><font color='red'>注意：</font><br>这里只显示了还未使用的充值卡的卡号及密码。为了安全起见，请您尽快使用！<br><br>如果您购买的是本站的充值卡，可以直接点击“充值卡充值”链接进行充值。<br>如果您购买的是其他公司的卡，请尽快去相关公司或网站的充值入口进行充值。</td></tr>"
    Response.Write "</table>"
End Sub

Sub SaveExchange()
    If UserSetting(18) = 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>不允许进行自助兑换" & PointName & "！</li>"
        Exit Sub
    End If

    Dim rsUser, sqlUser
    Dim ChangeType, ChangeMoney, ChangeExp, GetPoint
    ChangeType = Abs(PE_CLng(Trim(Request("ChangeType"))))
    ChangeMoney = Abs(PE_CDbl(Trim(Request("ChangeMoney"))))
    ChangeExp = Abs(PE_CLng(Trim(Request("ChangeExp"))))

    If ChangeType = 1 Then '使用货币
        If ChangeMoney = 0 Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请输入要兑换的资金数！</li>"
        Else
            If ChangeMoney > Balance Then
                FoundErr = True
                ErrMsg = ErrMsg & "<li>输入的资金数大于您的资金余额！</li>"
            Else
                If Fix(ChangeMoney / MoneyExchangePoint) < 1 Then
                    FoundErr = True
                    ErrMsg = ErrMsg & "<li>输入的资金数不足以兑换 1 " & PointUnit & PointName & "！</li>"
                End If
            End If
        End If
    Else  '使用积分
        If ChangeExp = 0 Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请输入要减去的积分数！</li>"
        Else
            If ChangeExp > UserExp Then
                FoundErr = True
                ErrMsg = ErrMsg & "<li>输入的积分数大于您的可用积分！</li>"
            Else
                If Fix(ChangeExp / UserExpExchangePoint) < 1 Then
                    FoundErr = True
                    ErrMsg = ErrMsg & "<li>输入的积分数不足以兑换 1 " & PointUnit & PointName & "！</li>"
                End If
            End If
        End If
    End If

    If FoundErr = True Then
        Exit Sub
    End If

    Set rsUser = Server.CreateObject("Adodb.RecordSet")
    sqlUser = "select * from PE_User where UserID=" & UserID
    rsUser.Open sqlUser, Conn, 1, 3

    If ChangeType = 1 Then
        GetPoint = Fix(ChangeMoney / MoneyExchangePoint)
        rsUser("Balance") = rsUser("Balance") - ChangeMoney
        rsUser("UserPoint") = rsUser("UserPoint") + GetPoint
        Call AddBankrollItem("System", UserName, ClientID, ChangeMoney, 4, "", 0, 2, 0, 0, "用于兑换 " & GetPoint & " " & PointUnit & PointName, Now())
        Call AddConsumeLog("System", 0, UserName, 0, GetPoint, 1, "将 " & ChangeMoney & " 元资金兑换成 " & GetPoint & " " & PointUnit & PointName)
        Call WriteSuccessMsg("成功将 " & ChangeMoney & " 元资金兑换成 " & GetPoint & " " & PointUnit & PointName & " ！", ComeUrl)
    Else
        GetPoint = Fix(ChangeExp / UserExpExchangePoint)
        rsUser("UserExp") = rsUser("UserExp") - ChangeExp
        rsUser("UserPoint") = rsUser("UserPoint") + GetPoint
        Call AddConsumeLog("System", 0, UserName, 0, GetPoint, 1, "将 " & ChangeExp & " 分积分兑换成 " & GetPoint & " " & PointUnit & PointName)
        Call WriteSuccessMsg("成功将 " & ChangeExp & " 分积分兑换成 " & GetPoint & " " & PointUnit & PointName & " ！", ComeUrl)
    End If

    rsUser.Update
    rsUser.Close
    Set rsUser = Nothing
End Sub

Sub SaveValid()
    If UserSetting(19) = 0 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>不允许进行自助兑换有效期！</li>"
        Exit Sub
    End If

    Dim rsUser, sqlUser
    Dim ChangeType, ChangeMoney, ChangeExp, GetValidDay
    ChangeType = Abs(PE_CLng(Trim(Request("ChangeType"))))
    ChangeMoney = Abs(PE_CDbl(Trim(Request("ChangeMoney"))))
    ChangeExp = Abs(PE_CLng(Trim(Request("ChangeExp"))))

    If ChangeType = 1 Then '使用货币
        If ChangeMoney = 0 Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请输入要兑换的资金数！</li>"
        Else
            If ChangeMoney > Balance Then
                FoundErr = True
                ErrMsg = ErrMsg & "<li>输入的资金数大于您的资金余额！</li>"
            Else
                If Fix(ChangeMoney / MoneyExchangeValidDay) < 1 Then
                    FoundErr = True
                    ErrMsg = ErrMsg & "<li>输入的资金数不足以兑换 1 天有效期！</li>"
                End If
            End If
        End If
    Else  '使用积分
        If ChangeExp = 0 Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请输入要减去的积分数！</li>"
        Else
            If ChangeExp > UserExp Then
                FoundErr = True
                ErrMsg = ErrMsg & "<li>输入的积分数大于您的可用积分！</li>"
            Else
                If Fix(ChangeExp / UserExpExchangeValidDay) < 1 Then
                    FoundErr = True
                    ErrMsg = ErrMsg & "<li>输入的积分数不足以兑换 1 天有效期！</li>"
                End If
            End If
        End If
    End If

    If FoundErr = True Then
        Exit Sub
    End If
    
    Set rsUser = Server.CreateObject("Adodb.RecordSet")
    sqlUser = "select * from PE_User where UserID=" & UserID
    rsUser.Open sqlUser, Conn, 1, 3

    If rsUser("ValidNum") = -1 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>您的有效期为“无限期”，无需兑换有效期。"
    Else
        If ChangeType = 1 Then
            GetValidDay = Fix(ChangeMoney / MoneyExchangeValidDay)
            rsUser("Balance") = rsUser("Balance") - ChangeMoney
            Call AddBankrollItem("System", UserName, ClientID, ChangeMoney, 4, "", 0, 2, 0, 0, "用于兑换 " & GetValidDay & " 天有效期", Now())
        Else
            GetValidDay = Fix(ChangeExp / UserExpExchangeValidDay)
            rsUser("UserExp") = rsUser("UserExp") - ChangeExp
        End If

        If ValidDays > 0 Then
            If rsUser("ValidUnit") = 1 Then
                rsUser("ValidNum") = rsUser("ValidNum") + GetValidDay
                rsUser.Update
            Else
                rsUser("ValidNum") = ValidNumToValidDays(rsUser("ValidNum"), rsUser("ValidUnit"), rsUser("BeginTime")) + GetValidDay
                rsUser("ValidUnit") = 1
                rsUser.Update
                Call AddRechargeLog("System", UserName, 0, 0, 0, "兑换有效期时更改有效期计费单位")
            End If
        Else
            rsUser("BeginTime") = Now()
            rsUser("ValidNum") = GetValidDay
            rsUser("ValidUnit") = 1
            rsUser.Update
            Call AddRechargeLog("System", UserName, 0, 0, 0, "兑换有效期时将原来过期的有效期重新计算")
        End If

        If ChangeType = 1 Then
            Call AddRechargeLog("System", UserName, GetValidDay, 1, 1, "将 " & ChangeMoney & " 元资金兑换成 " & GetValidDay & " 天有效期")
            Call WriteSuccessMsg("成功将 " & ChangeMoney & " 元资金兑换成 " & GetValidDay & " 天有效期！", ComeUrl)
        Else
            Call AddRechargeLog("System", UserName, GetValidDay, 1, 1, "将 " & ChangeExp & " 分积分兑换成 " & GetValidDay & " 天有效期")
            Call WriteSuccessMsg("成功将 " & ChangeExp & " 分积分兑换成 " & GetValidDay & " 天有效期！", ComeUrl)
        End If
    End If
    rsUser.Close
    Set rsUser = Nothing
End Sub


Sub SaveRecharge()
    Dim CardNum, Password
    Dim rsCard
    CardNum = ReplaceBadChar(Trim(Request("CardNum")))
    Password = ReplaceBadChar(Trim(Request("Password")))
    If CardNum = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请输入充值卡卡号！</li>"
    End If
    If Password = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请输入充值卡密码！</li>"
    Else
        Password = Base64encode(Password)
    End If
    If FoundErr = True Then Exit Sub
    
    Set rsCard = Server.CreateObject("Adodb.Recordset")
    rsCard.Open "select * from PE_Card where CardNum='" & CardNum & "' and Password='" & Password & "'", Conn, 1, 3
    If rsCard.BOF And rsCard.EOF Then
        FoundErr = True