login.asp

请认真阅读您的文件包然后写出其具体功能(至少要20个字)。尽量不要让站长把时间都花费在为您修正说明上。压缩包解压时不能有密码。

<!--#include file="conn.asp"-->
<!--#include file="inc/md5.asp"-->
<!--#include file="inc/const.asp"-->
<%
select case request("action")
	case "chkLogin"
    	call chkLogin()
	case else
		call main()
end select

sub main()
	dim url
	url=request.serverVariables("HTTP_REFERER")
	
	call anysale.minHead("会员登录","","")
%>
<script type="text/javascript">
//表单提交检查
function checkLogin() {
	var flag1 = check('用户名',$('username').value,'usernameNote',0,0,2,20)
	var flag2 = check('密码',$('password').value,'passwordNote',0,3,6,20)
	var flag3 = checkCode('验证码',$('passcode').value,'passcodeNote')
	var rtflag = flag1 && flag2 && flag3;
	return rtflag;
}
</script>
<div style="clear:both;height:100px;">&nbsp;</div>

<div class="bodyer">
 <form name="loginForm" id="loginForm" method="post">
 <ul class="loginL">
  <li><a href="javascript:anysale();" onclick="window.open('<%=anysale.asInfo(1)%>');"><img src="images/loginLogo.gif" alt="logo" width="95" height="38" /></a></li>
  <li class="f14" style="height:28px;line-height:28px;">传递网络价值!</li>
  <li>&nbsp;</li>
  <li>客服热线：<%=anysale.asInfo(12)%></li>
  <li><a href="javascript:anysale();" onclick="window.open('help.asp');">使用帮助!</a></li>
  <li><a class="f14" href="javascript:anysale();" onclick="window.open('password.asp');">找回密码</a></li>
  <li>&nbsp;</li>
  <li>&nbsp;</li>
  <li><button onclick="window.open('register.asp');" class="button" onmouseover="this.className='buttonH'" onmouseout="this.className='button'">注 册</button></li>
  <li>非本站会员请先注册</li>
 </ul>
 <ul class="loginM"><li>&nbsp;</li></ul>
 <ul class="loginR">
  <li><h3>欢迎光临!</h3></li>
  <li>为确保安全，系统使用完毕后，请注销登录。</li>
  <li>&nbsp;</li>
  <li style="height:30px;"><h2 class="color">登录会员管理系统</h2></li>   
  <li style="height:28px;"><label for="username" class="left">用户名&nbsp;&nbsp;&nbsp;&nbsp;<input type="text" name="username" id="username" onblur="check('用户名',this.value,'usernameNote',0,0,2,20)" tabindex="1" maxlength="20" />&nbsp;&nbsp;</label> <span class="note"><span id="usernameNote"></span></span></li>
  <li style="height:28px;"><label for="password" class="left">密&nbsp;&nbsp;&nbsp;&nbsp;码&nbsp;&nbsp;&nbsp;&nbsp;<input type="password" name="password" id="password" onblur="check('密码',this.value,'passwordNote',0,3,6,20)" tabindex="2" maxlength="20" />&nbsp;&nbsp;</label> <span class="note"><span id="passwordNote"></span></span></li>
  <li style="height:28px;"><label for="passcode" class="left">验证码&nbsp;&nbsp;&nbsp;
   <input name="passcode" type="text" id="passcode" tabindex="3" onfocus="setCode('code','passcodeNote');" onblur="checkCode('验证码',this.value,'passcodeNote')" maxlength="4" /> 
   <span id="code"></span>&nbsp;</label><span class="note"><span id="passcodeNote"></span></span>  </li>
  <li style="height:28px;"><label for="cookieDate">Cookie&nbsp;&nbsp;
   <select name="cookieDate" id="cookieDate" style="width:130px;" tabindex="4" onblur="$('userSubmit').focus();">
    <option value="0">不保存</option>
	<option value="1">保存一天</option>
	<option value="2">保存一月</option>
	<option value="3">保存一年</option>
   </select>
   </label>
  </li>
  <li>&nbsp;</li>
  <li>
   <span style="margin:0 0 0 48px;"></span>
   <input type="button" name="button" value="确 定" id="userSubmit" onclick="if(checkLogin()){getPage('login.asp?action=chkLogin','login',0,'loginForm');winNew('正在登录','<div class=anysaleLoad><ul class=winNote><li class=iLoad>&nbsp;</li><li class=left><ul><li class=f14>正在登录，请稍后...</li></ul></li></ul></div>',0,400,94);};" class="button" onmouseover="this.className='buttonH'" onmouseout="this.className='button'" />
   <input type="hidden" name="url" value="<%=url%>" />
  </li>
 </ul>
 </form>
</div>

<div style="clear:both;height:80px;">&nbsp;</div>
<%
anysale.minFoot
end sub

sub chkLogin()
	dim username, password, password2
	dim rs,url,isAdmin
	username=trim(replace(request("username"),"'",""))
	password=md5(replace(request.form("password"),"'",""),16)
	password2=md5(replace(request.form("password"),"'",""),32)
	isAdmin=false
	
	if not anysale.checkPost then
		errNote=errNote+"<li>请不要从外部提交。</li>"
		iserr=true
	end if
	if username="" or password="" or request("passcode")="" then
		errNote=errNote+"<li>请输入您的用户名或密码及验证码。</li>"
		iserr=true
	end if
	if cstr(session("getcode"))<>lcase(cstr(trim(request("passcode")))) then
		errNote=errNote+"<li>您输入的确认码和系统产生的不一致，请重新输入。</li>"
		iserr=true
	end if
	session("getcode")=""
	
	if iserr then
		anysale.errWin(errNote)
		exit sub
	end if
	
	set rs=server.createObject("adodb.recordset")
	set rs=conn.execute("select * from as_user where username='"&username&"'")
	if rs.eof and rs.bof then
		anysale.errWin("<li>您输入的用户名和密码不正确或者您不是会员。</li>")
		exit sub
	else
		if trim(rs("password"))<>password and lcase(trim(rs("password")))<>password2 then
			anysale.errWin("<li>您输入的用户名和密码不正确或者您不是会员。</li>")
			exit sub
		else
			'改为32位密码
			if trim(rs("password"))=password then
				conn.execute("update as_user set [password]='"&password2&"' where username='"&username&"'")
			end if
		
			if rs("islock")=1 then
				anysale.errWin("<li>会员被锁定。请联系网站管理员。</li>")
				exit sub
			end if
			
			if rs("groups")=1 then isAdmin=true end if
		end if
		
		if iserr=true then
			exit sub
		else
			dim cookies_path_s,cookies_path_d,cookies_path,i,usercookies
			cookies_path_s=split(Request.ServerVariables("PATH_INFO"),"/")
			cookies_path_d=ubound(cookies_path_s)
			cookies_path="/"
			for i=1 to cookies_path_d-1
				if not (cookies_path_s(i)="upfile" or cookies_path_s(i)="admin") then cookies_path=cookies_path&cookies_path_s(i)&"/"
			next
			usercookies=request("cookieDate")
			if isnull(usercookies) or usercookies="" then usercookies=1
			select case usercookies
				case "0"
				response.cookies(anysale.cookiesName)("usercookies") = usercookies
				case 1
   				response.cookies(anysale.cookiesName).Expires=Date+1
				response.cookies(anysale.cookiesName)("usercookies") = usercookies
				case 2
				response.cookies(anysale.cookiesName).Expires=Date+31
				response.cookies(anysale.cookiesName)("usercookies") = usercookies
				case 3
				response.cookies(anysale.cookiesName).Expires=Date+365
				response.cookies(anysale.cookiesName)("usercookies") = usercookies
			end select
			response.cookies(anysale.cookiesName).path = cookies_path
			response.cookies(anysale.cookiesName)("username") = rs("username")
			response.cookies(anysale.cookiesName)("userid") = rs("userID")
		
			conn.execute("update as_user set loginTime="&anysaleNow&",loginIP='"&anysale.userTrueIP&"',logins=logins+1 where username='"&username&"'")
			call anysale.setMoney(cint(anysale.asMoney(1)),"username='"&username&"'")

		end if
	end if

	rs.close
	set rs=nothing
	
	if instr(lcase(request("url")),"register.asp")>0 or instr(lcase(request("url")),"login.asp")>0 or  trim(request("url"))="" then
		url="index.asp"
	else
		url=request("url")
	end if
	
	if cint(request.form("back"))=1 then	
	sucNote="<li>登录成功!</li>|||<button onclick=""winClose();"" class=""button"" onmouseover=""this.className='buttonH'"" onmouseout=""this.className='button'"">返回</button>"
	else
	sucNote="<li>登录成功，"&anysale.asInfo(0)&"欢迎您的到来!</li>|||<button onclick=""location.href='index.asp';winClose();"" class=""button"" onmouseover=""this.className='buttonH'"" onmouseout=""this.className='button'"">网站首页</button>"
	sucNote=sucNote+"&nbsp;&nbsp;<button onclick=""location.href='user.asp';winClose();"" class=""button"" onmouseover=""this.className='buttonH'"" onmouseout=""this.className='button'"">会员中心</button>"
	if isAdmin then
	sucNote=sucNote+"&nbsp;&nbsp;<button onclick=""location.href='adminLogin.asp';winClose();"" class=""button"" onmouseover=""this.className='buttonH'"" onmouseout=""this.className='button'"">后台管理</button>"
	end if
	sucNote=sucNote+"&nbsp;&nbsp;<button onclick=""location.href='"&url&"';winClose();"" class=""button"" onmouseover=""this.className='buttonH'"" onmouseout=""this.className='button'"">返 回</button>"
	end if
	anysale.sucWin(sucNote)
end sub

call closeConn()
%>