step_master_setup

来自「StaMps最新测试版」· 代码 · 共 64 行

#!/bin/tcsh -f

set masterdate = `echo $cwd | gawk 'BEGIN {FS="/"} {print $NF}'`
set CURRDIR = `echo $cwd` 
set WORKDIR = ".." 
set INSARDIR = "../../INSAR_$masterdate"

rm -f master.res
roipac2doris $masterdate
set first = `grep 'First_pixel ' master.res | gawk 'END {print $4}'`
set last = `grep 'Last_pixel '  master.res | gawk 'END {print $4}'`
@ width = ($last - $first) + 1

set first_l = `grep first_l master_crop.in | gawk '{print $NF}'`
set last_l = `grep last_l master_crop.in | gawk '{print $NF}'`
set first_p = `grep first_p master_crop.in | gawk '{print $NF}'`
set last_p = `grep last_p master_crop.in | gawk '{print $NF}'`

set master_slc = $masterdate"_crop.slc"
echo "cpxfiddle -qnormal -w$width -l$first_l -L$last_l -p$first_p -P$last_p -fcr4 -ofloat $masterdate.slc > $master_slc"
cpxfiddle -qnormal -w$width -l$first_l -L$last_l -p$first_p -P$last_p -fcr4 -ofloat $masterdate.slc > $master_slc

cd $WORKDIR
\ls -d [1,2]* | sed "/$masterdate/ d" > make_slcs.list
cd $CURRDIR

if (! -e $INSARDIR) then
    mkdir $INSARDIR
endif

cp *.slc.rsc $INSARDIR
cp master.res $INSARDIR
mv $master_slc $INSARDIR
cd $INSARDIR

@ first_l = $first_l - 1
@ last_l = $last_l - 1
@ first_p = $first_p - 1
@ last_p = $last_p - 1

sed -n '1,/*_Start_crop/p' master.res > tmp_master.$$
echo "*******************************************************************" >> tmp_master.$$
echo "Data_output_file: $cwd/$master_slc" >> tmp_master.$$
grep 'Data_output_format:' master.res >> tmp_master.$$
echo "First_line (w.r.t. original_image):  $first_l" >> tmp_master.$$
echo "Last_line (w.r.t. original_image):   $last_l" >> tmp_master.$$
echo "First_pixel (w.r.t. original_image): $first_p" >> tmp_master.$$
echo "Last_pixel (w.r.t. original_image):  $last_p" >> tmp_master.$$
echo "*******************************************************************" >> tmp_master.$$
echo "* End_crop:_NORMAL"  >> tmp_master.$$
echo "*******************************************************************" >> tmp_master.$$

mv -f tmp_master.$$  master.res

if (! -e dem.dorisin) then
    cp $DORIS_SCR/dem.dorisin .
endif

if (! -e geocode.dorisin) then
    cp $DORIS_SCR/geocode.dorisin .
endif

cd $CURRDIR