step_master_read

来自「StaMps最新测试版」· 代码 · 共 89 行

#!/bin/tcsh -f

set masterdate = `echo $cwd | gawk 'BEGIN {FS="/"} {print $NF}'`
set CURRDIR = `echo $cwd` 
set WORKDIR = ".." 
set INSARDIR = "../../INSAR_$masterdate"

if (! -e $WORKDIR/master_readfiles.dorisin) then
    cp $DORIS_SCR/master_readfiles.dorisin $WORKDIR
endif
if (! -e $WORKDIR/readfiles.dorisin) then
    cp $DORIS_SCR/readfiles.dorisin $WORKDIR
endif
if (! -e $WORKDIR/cropfiles.dorisin) then
    cp $DORIS_SCR/cropfiles.dorisin $WORKDIR
endif

set first_l = `grep first_l master_crop.in | gawk '{print $NF}'`
set last_l = `grep last_l master_crop.in | gawk '{print $NF}'`
set first_p = `grep first_p master_crop.in | gawk '{print $NF}'`
set last_p = `grep last_p master_crop.in | gawk '{print $NF}'`

@ first_l = $first_l - 1
@ last_l = $last_l - 1
@ first_p = $first_p - 1
@ last_p = $last_p - 1

sed -n '1,/M_CROP_OUT/p' $WORKDIR/master_readfiles.dorisin > tmp_master_readfiles.$$
echo "M_DBOW  $first_l $last_l $first_p $last_p // line low/hi pixel low/hi" >> tmp_master_readfiles.$$
echo "STOP" >> tmp_master_readfiles.$$
mv tmp_master_readfiles.$$ $WORKDIR/master_readfiles.dorisin

@ first_l = $first_l - 1000
@ last_l = $last_l + 1000
@ first_p = $first_p - 100
@ last_p = $last_p + 100
if ($first_l < 1) then
    set first_l = 1
endif
if ($first_p < 1) then
    set first_p = 1
endif

sed -n '1,/S_CROP_OUT/p' $WORKDIR/cropfiles.dorisin > tmp_cropfiles.$$
echo "S_DBOW  $first_l $last_l $first_p $last_p // line low/hi pixel low/hi" >> tmp_cropfiles.$$
echo "STOP" >> tmp_cropfiles.$$
mv tmp_cropfiles.$$ $WORKDIR/cropfiles.dorisin

rm -f master.res
doris $WORKDIR/master_readfiles.dorisin > step_master_read.log

set first = `grep 'First_pixel ' master.res | gawk 'END {print $4}'`
set last = `grep 'Last_pixel '  master.res | gawk 'END {print $4}'`
@ width = ($last - $first) + 1
set master_slc = $masterdate"_crop.slc"
#set mcrop = `\ls *crop.slc`
set mcrop = "master.slc"

echo 's#'$mcrop'#'$cwd'/'$master_slc'#' > tmp_sed.in
sed -f tmp_sed.in master.res > tmp_master.res
echo 's#SLC/'$masterdate'#INSAR_'$masterdate'#'  > tmp_sed.in
sed -f tmp_sed.in tmp_master.res > master.res
rm -f tmp_sed.in

mv master.slc $master_slc

cd $WORKDIR
\ls -d [1,2]* | sed "/$masterdate/ d" > make_slcs.list
cd $CURRDIR


if (! -e $INSARDIR) then
    mkdir $INSARDIR  
endif

#foreach masterres(`find $INSARDIR -name master.res`)
#    cp -f master.res $masterres
#end
cp -f master.res $INSARDIR
mv $master_slc $INSARDIR

if (! -e $INSARDIR/dem.dorisin) then
    cp $DORIS_SCR/dem.dorisin $INSARDIR
endif

if (! -e $INSARDIR/geocode.dorisin) then
    cp $DORIS_SCR/geocode.dorisin $INSARDIR
endif