currenciesform.pas

功能全面的商业财会系统源码,清晰,很有参考价值.扩展性强.

unit CurrenciesForm;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  DBCtrls, Grids, DBGrids, DB, DBTables, Menus, ExtCtrls, StdCtrls, Buttons, BDE;

type
  TfrmCurrencies = class(TForm)
    Panel1: TPanel;
    MainMenu1: TMainMenu;
    tblCurrency: TTable;
    dsCurrency: TDataSource;
    DBGrid1: TDBGrid;
    mnuFile: TMenuItem;
    mnuView: TMenuItem;
    mnuHelp: TMenuItem;
    mnuRefresh: TMenuItem;
    mnuCurrenciesHelp: TMenuItem;
    mnuPrint: TMenuItem;
    N2: TMenuItem;
    mnuExit: TMenuItem;
    Bevel1: TBevel;
    btnNew: TSpeedButton;
    btnEdit: TSpeedButton;
    btnDelete: TSpeedButton;
    mnuRecords: TMenuItem;
    mnuNew: TMenuItem;
    mnuEdit: TMenuItem;
    mnuDelete: TMenuItem;
    tblCurrencyCurrencyID: TAutoIncField;
    tblCurrencyCurrencyName: TStringField;
    tblCurrencyExchangeRate: TFloatField;
    PopupMenu1: TPopupMenu;
    popNew: TMenuItem;
    popEdit: TMenuItem;
    popDelete: TMenuItem;
    procedure mnuRefreshClick(Sender: TObject);
    procedure tblCurrencyBeforeDelete(DataSet: TDataSet);
    procedure FormCreate(Sender: TObject);
    procedure Panel1DblClick(Sender: TObject);
    procedure DBGrid1KeyPress(Sender: TObject; var Key: Char);
    procedure FormShow(Sender: TObject);
    procedure mnuNewClick(Sender: TObject);
    procedure mnuEditClick(Sender: TObject);
    procedure mnuDeleteClick(Sender: TObject);
    procedure mnuExitClick(Sender: TObject);
    procedure FormResize(Sender: TObject);
    procedure mnuPrintClick(Sender: TObject);
    procedure mnuCurrenciesHelpClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  frmCurrencies: TfrmCurrencies;

implementation

uses BS1Form, CurrencyForm, CurrenciesReport, LookUpsData;

var
  intClientHeight, intClientWidth: Integer;
  OldWindowState: TWindowState;

{$R *.DFM}

procedure TfrmCurrencies.mnuRefreshClick(Sender: TObject);
begin
  tblCurrency.refresh;
end;

procedure TfrmCurrencies.tblCurrencyBeforeDelete(DataSet: TDataSet);
begin
  if MessageDlg('Delete ' + '''' + tblCurrencyCurrencyName.AsString + '''' + '?',mtConfirmation,mbOKCancel,0) <> mrOK then raise(EAbort.create(''));  //Silent Exception: "abort;" replaced by "raise etc" since abort conflicts with BDE (required by DbiSaveChanges).

  dmLookUps.tblBank.Active := true;
  if dmLookUps.tblBank.Locate('CurrencyID', tblCurrencyCurrencyID.value, []) = true then raise(Exception.Create('Unable to delete ' + '''' + tblCurrencyCurrencyName.AsString + '''' + '...' + #13 + 'Bank(s) exist for this currency'));

  dmLookUps.tblVendor.Active := true;
  if dmLookUps.tblVendor.Locate('CurrencyID', tblCurrencyCurrencyID.value, []) = true then raise(Exception.Create('Unable to delete ' + '''' + tblCurrencyCurrencyName.AsString + '''' + '...' + #13 + 'Vendor(s) exist for this currency'));
  
  dmLookUps.tblCustomer.Active := true;
  if dmLookUps.tblCustomer.Locate('CurrencyID', tblCurrencyCurrencyID.value, []) = true then raise(Exception.Create('Unable to delete ' + '''' + tblCurrencyCurrencyName.AsString + '''' + '...' + #13 + 'Customer(s) exist for this currency'));
end;

procedure TfrmCurrencies.FormCreate(Sender: TObject);
var
  x: integer;
begin
  tblCurrency.DatabaseName := strDatabaseName;
  tblCurrency.Active := true;

  if FontFactor <> 1 then begin   //If using large fonts, resize grid columns.
    intClientWidth := Trunc(20*FontFactor) + DBGrid1.Columns.Count - 1;   //Scrollbar + grid lines.
    for x := 0 to DBGrid1.Columns.Count - 1 do begin
      DBGrid1.Columns[x].width := Trunc(DBGrid1.Columns[x].width*FontFactor);
      intClientWidth := intClientWidth + DBGrid1.Columns[x].width;
    end;
    ClientWidth := intClientWidth;
  end;
  intClientHeight := ClientHeight;   //Store form size.
  intClientWidth := ClientWidth;
end;

procedure TfrmCurrencies.Panel1DblClick(Sender: TObject);
begin
  ClientHeight := intClientHeight;   //Resize form.
  ClientWidth := intClientWidth;
end;

procedure TfrmCurrencies.DBGrid1KeyPress(Sender: TObject; var Key: Char);
begin
  if key = #13 then begin
    mnuEditClick(Sender);
    Key := #0;   //Cancel Enter key.
  end;
end;

procedure TfrmCurrencies.FormShow(Sender: TObject);
begin
  DBGrid1.setfocus;
  tblCurrency.First;   //Reset grid to start at 1st record.
end;

procedure TfrmCurrencies.mnuNewClick(Sender: TObject);
begin
  screen.cursor := crHourglass;
  application.createform (TfrmCurrency,frmCurrency);
  frmCurrency.tblCurrency.Insert;
  frmCurrency.Show;
  screen.cursor := crDefault;
end;

procedure TfrmCurrencies.mnuEditClick(Sender: TObject);
begin
  screen.cursor := crHourglass;
  application.createform (TfrmCurrency,frmCurrency);
  frmCurrency.tblCurrency.Locate('CurrencyID', tblCurrencyCurrencyID.value, []);
  frmCurrency.Show;
  screen.cursor := crDefault;
end;

procedure TfrmCurrencies.mnuDeleteClick(Sender: TObject);
begin
  tblCurrency.delete;
  DbiSaveChanges(tblCurrency.handle);
end;

procedure TfrmCurrencies.mnuExitClick(Sender: TObject);
begin
  Close;
end;

procedure TfrmCurrencies.FormResize(Sender: TObject);
var
  Bookmark: TBookmark;
begin
  if (WindowState <> OldWindowState)   //Prevent grid resize bugs.
  and (WindowState <> wsMinimized)
  and (OldWindowState <> wsMinimized)
  then begin
    screen.cursor := crHourglass;
    Bookmark := tblCurrency.GetBookmark;
    tblCurrency.First;
    tblCurrency.refresh;
    try tblCurrency.GotoBookmark(Bookmark); except; end;
    tblCurrency.FreeBookmark(BookMark);
    screen.cursor := crDefault;
  end;
  OldWindowState := WindowState;
end;

procedure TfrmCurrencies.mnuPrintClick(Sender: TObject);
begin
  screen.cursor := crHourglass;
  application.createform (TrptCurrencies,rptCurrencies);
  screen.cursor := crDefault;
  rptCurrencies.QuickReport.Preview;
end;

procedure TfrmCurrencies.mnuCurrenciesHelpClick(Sender: TObject);
begin
  Application.HelpContext(430);
end;

end.