taxform.pas

功能全面的商业财会系统源码,清晰,很有参考价值.扩展性强.

unit TaxForm;

interface

uses Windows, Messages, SysUtils, Classes, Graphics, Forms, Dialogs, Controls, StdCtrls,
  Buttons, ComCtrls, ExtCtrls, Mask, DBCtrls, DB, DBTables, Menus, DBLookup, BDE;

type
  TfrmTax = class(TForm)
    Panel1: TPanel;
    PageControl1: TPageControl;
    dsTax: TDataSource;
    Panel3: TPanel;
    Panel2: TPanel;
    TabSheet1: TTabSheet;
    Label1: TLabel;
    editTaxName: TDBEdit;
    Panel4: TPanel;
    btnOK: TButton;
    btnCancel: TButton;
    Label2: TLabel;
    editRate: TDBEdit;
    Label3: TLabel;
    Label4: TLabel;
    editTaxCode: TDBEdit;
    Label5: TLabel;
    editTaxDescription: TDBEdit;
    Label10: TLabel;
    editTaxGLAccount: TDBEdit;
    cboTaxGLAccount: TDBLookupComboBox;
    btnTaxGLAccount: TSpeedButton;
    tblTax: TTable;
    tblTaxTaxID: TAutoIncField;
    tblTaxTaxName: TStringField;
    tblTaxRate: TFloatField;
    tblTaxTaxCode: TStringField;
    tblTaxTaxDescription: TStringField;
    tblTaxTaxGLAccount: TStringField;
    qryLastID: TQuery;
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure dsTaxDataChange(Sender: TObject; Field: TField);
    procedure FormShow(Sender: TObject);
    procedure Panel2DblClick(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormKeyPress(Sender: TObject; var Key: Char);
    procedure dsTaxUpdateData(Sender: TObject);
    procedure btnOKClick(Sender: TObject);
    procedure btnCancelClick(Sender: TObject);
    procedure cboTaxGLAccountKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure btnTaxGLAccountClick(Sender: TObject);
    procedure tblTaxTaxGLAccountValidate(Sender: TField);
    procedure tblTaxBeforePost(DataSet: TDataSet);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  frmTax: TfrmTax;

implementation

uses BS1Form, TaxesForm, GLAccountsForm, GLAccountsFilterForm, LookUpsData;

var
  intClientHeight, intClientWidth: Integer;

{$R *.DFM}

procedure TfrmTax.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if tblTax.State in [dsInsert, dsEdit] then btnOKClick(sender);
  Action := caFree;
end;

procedure TfrmTax.dsTaxDataChange(Sender: TObject;
  Field: TField);
begin
  if (tblTaxTaxID.AsVariant = null) and (tblTaxTaxName.Value = '') then self.Caption := 'New Tax'
  else self.Caption := tblTaxTaxName.value;
end;

procedure TfrmTax.FormShow(Sender: TObject);
begin
  PageControl1.ActivePage := Tabsheet1;
  editTaxName.setfocus;
end;

procedure TfrmTax.Panel2DblClick(Sender: TObject);
begin
  ClientHeight := intClientHeight;   //Resize form.
  ClientWidth := intClientWidth;
end;

procedure TfrmTax.FormCreate(Sender: TObject);
begin
  tblTax.DatabaseName := strDatabaseName;
  qryLastID.DatabaseName := strDatabaseName;
  //tblGLAccnt.DatabaseName := strDatabaseName;
  //tblGLAccnt.Active := true;   //Data Module used instead.
  tblTax.Active := true;

  if FontFactor <> 1 then begin   //If using large fonts, resize form.
    ClientHeight := Trunc(ClientHeight*FontFactor);
    ClientWidth := Trunc(ClientWidth*FontFactor);
    PageControl1.TabWidth := Trunc(PageControl1.TabWidth*FontFactor);
  end;  
  intClientHeight := ClientHeight;   //Store form size.
  intClientWidth := ClientWidth;
end;

procedure TfrmTax.FormKeyPress(Sender: TObject; var Key: Char);
begin
  if key = #13 then begin   //Enter key: advance to next control.
    if (ActiveControl.ClassType <> TDBMemo) and (ActiveControl.ClassType <> TDBLookupCombobox) then begin
      Key := #0;
      Perform(WM_NEXTDLGCTL, 0, 0);
    end else if (ActiveControl.ClassType = TDBLookupComboBox) and (TDBLookupComboBox(ActiveControl).ListVisible = false) then begin
      Key := #0;
      Perform(WM_NEXTDLGCTL, 0, 0);
    end;
  end;
end;

procedure TfrmTax.dsTaxUpdateData(Sender: TObject);
begin
  if tblTaxTaxName.AsString = '' then begin
    with editTaxName do begin Show; SetFocus; end;
    raise(exception.create('Field ' + '''Tax Name''' + ' must have a value'));
  end;

  if tblTaxTaxCode.AsString = '' then begin
    with editTaxCode do begin Show; SetFocus; end;
    raise(exception.create('Field ' + '''Code''' + ' must have a value'));
  end;

  if tblTaxTaxDescription.AsString = '' then begin
    with editTaxDescription do begin Show; SetFocus; end;
    raise(exception.create('Field ' + '''Description''' + ' must have a value'));
  end;

  if tblTaxRate.AsFloat = 0 then begin
    with editRate do begin Show; SetFocus; end;
    raise(exception.create('Field ' + '''Rate''' + ' must have a value'));
  end;

  if tblTaxTaxGLAccount.AsString = '' then begin
    with editTaxGLAccount do begin Show; SetFocus; end;
    raise(exception.create('Field ' + '''GL Account''' + ' must have a value'));
  end;
end;

procedure TfrmTax.btnOKClick(Sender: TObject);
begin
  if tblTax.State in [dsInsert, dsEdit] then begin
    try tblTax.post; DbiSaveChanges(tblTax.handle);
    except
      on E: EDBEngineError do
        if E.Errors[E.ErrorCount - 1].ErrorCode = 9729 then begin   //Key violation (key already exists).
          with editTaxName do begin Show; SetFocus; end;
          raise(exception.create('Tax already exists'));
        end else raise;
    end;
    try
      frmTaxes.tblTax.refresh;
      frmTaxes.tblTax.Locate('TaxID', tblTaxTaxID.AsInteger, []);
      frmTaxes.DBGrid1.Setfocus;
    except; end;
  end;
  Close;
end;

procedure TfrmTax.btnCancelClick(Sender: TObject);
begin
  tblTax.cancel;
  Close;
end;

procedure TfrmTax.cboTaxGLAccountKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  if key = VK_Delete then begin
    tblTax.Edit;
    tblTaxTaxGLAccount.AsVariant := null;
  end;
end;

procedure TfrmTax.btnTaxGLAccountClick(Sender: TObject);
var
  aComponent: TComponent;
begin
  screen.cursor := crHourglass;
  aComponent := Application.FindComponent('frmGLAccounts');
  if not Assigned (aComponent) then frmGLAccounts := TfrmGLAccounts.Create(Application);

  aComponent := Application.FindComponent('frmGLAccountsFilter');
  if Assigned (aComponent) then try frmGLAccountsFilter.btnResetClick(sender); except; end;
  frmGLAccounts.mnuFilter.Checked := false;
  frmGLAccounts.qryGLAccnt.Filtered := false;
  frmGLAccounts.tblGLAccnt.Filtered := false;

  if frmGLAccounts.WindowState = wsMinimized then frmGLAccounts.WindowState := wsNormal;
  if frmGLAccounts.visible = true then frmGLAccounts.FormShow(sender)
  else frmGLAccounts.Show;
  if not frmGLAccounts.qryGLAccnt.Locate('GLAccount', tblTaxTaxGLAccount.value, []) then frmGLAccounts.qryGLAccnt.First;
  screen.cursor := crDefault;
end;

procedure TfrmTax.tblTaxTaxGLAccountValidate(Sender: TField);
begin
  if (editTaxGLAccount.text <> '') and (dmLookUps.tblGLAccnt.Locate('GLAccount', editTaxGLAccount.Text, []) <> true) then raise(Exception.Create('GL Account ' + '''' + editTaxGLAccount.Text + '''' + ' not found'));
end;

procedure TfrmTax.tblTaxBeforePost(DataSet: TDataSet);
begin
  if tblTax.state = dsInsert then begin
    qryLastID.close;
    qryLastID.open;
    with qryLastID.Fields[0] do
      if IsNull then tblTaxTaxID.value := 1
      else tblTaxTaxID.value := AsInteger + 1;
  end;
end;

end.