storageinfo.pas

物流管理系统是一个典型的数据库应用程序

unit storageinfo;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, frame, StdCtrls, ExtCtrls, Grids, DBGrids, Buttons,
  DB;

type
  Tf_storageinfo = class(Tf_frame)
    Panel1: TPanel;
    Panel2: TPanel;
    Label1: TLabel;
    Label2: TLabel;
    Panel4: TPanel;
    Label3: TLabel;
    Label4: TLabel;
    Query: TBitBtn;
    Field: TComboBox;
    Add: TBitBtn;
    Update: TBitBtn;
    Cancel: TBitBtn;
    DBGrid1: TDBGrid;
    Delete: TBitBtn;
    Storagesource: TDataSource;
    Storagename: TEdit;
    Nameshort: TEdit;
    Value: TEdit;
    procedure StoragenameKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure AddClick(Sender: TObject);
    procedure CancelClick(Sender: TObject);
    procedure UpdateClick(Sender: TObject);
    procedure DeleteClick(Sender: TObject);
    procedure FormShow(Sender: TObject);
    procedure QueryClick(Sender: TObject);
    procedure DBGrid1DblClick(Sender: TObject);
  private
    { Private declarations }
    Function TextIsNull: Boolean; //判断仓库名称与简码是否为空
  public
    { Public declarations }
  end;

var
  f_storageinfo: Tf_storageinfo;

implementation
  uses data;
{$R *.dfm}

procedure Tf_storageinfo.StoragenameKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  inherited;
  if Key = vk_Return then
    FindNext(True);
end;
//处理添加按钮的单击事件
procedure Tf_storageinfo.AddClick(Sender: TObject);
begin
  inherited;
  if TextIsNull = False then  //判断编辑框文本是否为空
  begin
    With t_data.Query2 do //判断仓库名称是否重复
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_storageinfo where storagename = :name');
      Parameters.ParamByName('name').Value := Trim(Storagename.Text);
      Open;
    end;
    if t_data.Query2.RecordCount>0 then
    begin
      Application.MessageBox('该仓库名称已经存在,请重新输入.','提示',64);
      Storagename.SelectAll;
      Storagename.SetFocus;
      Exit;
    end;
    Try
      with t_data.Add1 do //向数据表中插入数据
      begin
        Close;
        SQL.Clear;
        SQL.Add('Insert into tb_storageinfo values(:name,:shortname)');
        Parameters.ParamByName('name').Value := Trim(StorageName.Text);
        Parameters.ParamByName('shortname').Value := Trim(Nameshort.Text);
        ExecSQL;
      end;
      Application.MessageBox('操作成功.','提示',64);
      Cancel.Click;
    Except
      On E: Exception do  //产生异常则抛出异常信息
        ShowMessage(E.Message);
    End;
  end
  else
  begin
    Application.MessageBox('仓库名称或简码不能为空.','提示',64);
  end;
end;
//自定义函数,判断编辑框是否为空
function Tf_storageinfo.TextIsNull: Boolean;
begin
  Result := False;
  if (Trim(Storagename.Text)='')or(Trim(Nameshort.Text)='') then
    Result := True;
end;
//处理取消按钮的单击事件代码
procedure Tf_storageinfo.CancelClick(Sender: TObject);
begin
  inherited;
  StorageName.Clear; //清空编辑框文本
  Nameshort.Clear;
  Field.ItemIndex := 0;
  With  t_data.Query1  do //刷新表格信息
  begin
    CLose;
    SQL.Clear;
    SQL.Add('Select * from tb_storageinfo');
    Open;
  end;
  if t_data.Query1.RecordCount>0 then
    StorageSource.DataSet := t_data.Query1
  else
  begin
    t_data.Query1.Close;
    StorageSource.DataSet := Nil;
  end;
end;
//处理修改按钮的单击事件代码
procedure Tf_storageinfo.UpdateClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //是否有修改的数据
  begin
    if TextIsNull = False then //数据是否为空
    begin
      //提示是否修改数据
      if Application.MessageBox(Pchar('确实要修改仓库名称为: '+t_data.Query1.FieldByName('storagename').AsString+' 的仓库信息吗?'),'提示',mb_YesNo)= ID_Yes then
      begin
        Try
          With t_data.update1 do
          begin
            CLose;
            SQL.Clear;
            SQL.Add('update tb_storageinfo set storagename = :name,nameshort = :short where storagename = :oldname');
            Parameters.ParamByName('name').Value := Trim(Storagename.Text);
            Parameters.ParamByName('short').Value := Trim(Nameshort.Text);
            Parameters.ParamByName('oldname').Value := Trim(t_data.Query1.FieldByName('storagename').AsString);
            ExecSQL;
          end;
          Application.MessageBox('修改成功.','提示',64);
          Cancel.Click;
        Except
          On E: Exception do
            ShowMessage(E.Message); //产生异常则抛出异常信息
        End;
      end;
    end
    else
      Application.MessageBox('仓库名称或简码不能为空.','提示',64);
  end
  else
    Application.MessageBox('当前没有可修改的数据.','提示',64);
end;
//处理删除按钮的单击事件
procedure Tf_storageinfo.DeleteClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //存在可删除的数据
  begin
    //提示是否删除数据
    if Application.MessageBox(Pchar('确实要删除库存名称为: ' + Trim(t_data.Query1.FieldByName('storagename').AsString)+' 的仓库信息吗?'),'提示',mb_YesNo)= ID_Yes then
    begin
      Try
        t_data.Query1.Delete;
        Cancel.Click;
      Except
        On E: Exception do
          ShowMessage(E.Message); //产生异常则抛出异常信息
      End;
    end
  end
  else
    Application.MessageBox('当前没有可删除的信息.','提示',64);
end;

procedure Tf_storageinfo.FormShow(Sender: TObject);
begin
  inherited;
  Cancel.Click;
end;
//处理查询按钮的单击事件
procedure Tf_storageinfo.QueryClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then  //如果有可查询的数据
  begin
    With t_data.Query1 do   //根据不同的查询条件执行相应的查询
    begin
      CLose;
      SQL.Clear;
      SQL.Add('select * from tb_storageinfo where ');
      if Field.ItemIndex = 0 then
      begin
        SQL.Add('storagename Like :Value');
        Parameters.ParamByName('Value').Value := '%'+Trim(Value.Text)+'%';
      end
      else
      begin
        SQL.Add('nameshort = :Value');
        Parameters.ParamByName('value').Value := Trim(Value.Text);
      end;
      Open;
    end;
    if t_data.Query1.RecordCount<1 then
    begin
      Cancel.Click;
      Application.MessageBox('没有找到符合条件的记录.','提示',64);
    end;
  end
  else
    Application.MessageBox('当前没有可查询的数据.','提示',64);
end;
//双击表格,将当前行数据显示在编辑框中
procedure Tf_storageinfo.DBGrid1DblClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
  begin
    Storagename.Text := Trim(t_data.Query1.FieldByName('Storagename').AsString);
    Nameshort.Text := Trim(t_data.Query1.FieldByName('nameshort').AsString);
  end;
end;

end.