📄 storeinfo.pas

📁 物流管理系统是一个典型的数据库应用程序
💻 PAS
字号:
unit storeinfo;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, frame, ExtCtrls, StdCtrls,Grids, DBGrids, DB,
  Buttons;

type
  Tf_storeinfo = class(Tf_frame)
    Panel1: TPanel;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    StoreSource: TDataSource;
    DBGrid1: TDBGrid;
    Label6: TLabel;
    Panel2: TPanel;
    Add: TBitBtn;
    Cancel: TBitBtn;
    Update: TBitBtn;
    Delete: TBitBtn;
    Label9: TLabel;
    Label10: TLabel;
    Label11: TLabel;
    Label7: TLabel;
    Field: TComboBox;
    Label8: TLabel;
    Query: TBitBtn;
    storename: TEdit;
    Nameshort: TEdit;
    Spec: TEdit;
    Defaultprice: TEdit;
    Barcode: TEdit;
    basicunit: TEdit;
    Value: TEdit;
    Stockunit: TEdit;
    Conversion: TEdit;
    procedure storenameKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure BarcodeKeyPress(Sender: TObject; var Key: Char);
    procedure CancelClick(Sender: TObject);
    procedure AddClick(Sender: TObject);
    procedure UpdateClick(Sender: TObject);
    procedure DeleteClick(Sender: TObject);
    procedure QueryClick(Sender: TObject);
    procedure DefaultpriceKeyPress(Sender: TObject; var Key: Char);
    procedure FormShow(Sender: TObject);
    procedure DBGrid1DblClick(Sender: TObject);
  private
    { Private declarations }
  public
    Procedure ClearEdit;//清空编辑框中的文本
    Function TextIsNull: Boolean;//判断编辑框中的文本是否为空
    Procedure Editvalue;//将数据集中的数据显示在编辑框中
    { Public declarations }
  end;

var
  f_storeinfo: Tf_storeinfo;

implementation
  uses data;
{$R *.dfm}

procedure Tf_storeinfo.storenameKeyDown(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  inherited;
  if Key = vk_Return then
    FindNext(True);
end;
//防止输入非法字符
procedure Tf_storeinfo.BarcodeKeyPress(Sender: TObject; var Key: Char);
begin
  inherited;
  if  not (Key in ['0'..'9',#8]) then
    Key := #0;
end;
//自定义过程,用于清空编辑框
procedure Tf_storeinfo.ClearEdit;
var
  i: Integer;
begin
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i]is TEdit then
      TEdit(Panel1.Controls[i]).Clear;
end;

procedure Tf_storeinfo.CancelClick(Sender: TObject);
begin
  inherited;
  ClearEdit;
  Field.ItemIndex := 0;
  With t_data.Query1 do
  begin
    CLose;
    SQL.Clear;
    SQL.Add('Select * from tb_storeinfo');
    Open;
  end;
  if t_data.Query1.RecordCount>0 then
    StoreSource.DataSet := t_data.Query1
  else
  begin
    t_data.Query1.Close;
    StoreSource.DataSet := Nil;
  end;
end;

function Tf_storeinfo.TextIsNull: Boolean;
var
  i: Integer;
begin
  Result := False;
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i] is TEdit then
    begin
      if Trim(TEdit(Panel1.Controls[i]).Text)='' then
      begin
        Result := True;
        Break;
      end;
    end;
end;
procedure Tf_storeinfo.AddClick(Sender: TObject);
begin
  inherited;
  if TextIsNull = False then
  begin
    With t_data.Query2 do
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_storeinfo where storename = :name');
      Parameters.ParamByName('name').Value := Trim(Storename.Text);
      Open;
    end;
    if t_data.Query2.RecordCount>0 then
    begin
      Application.MessageBox('该物资名称已经存在,请重新输入.','提示',64);
      Storename.SelectAll;
      Storename.SetFocus;
      Exit;
    end;
    Try
      with t_data.Add1 do
      begin
        Close;
        SQL.Clear;
        SQL.Add('Insert into tb_storeinfo  Values (:storename,:shortname,:spec,:defaultprice,:barcode,:basicunit,:stockunit,:conversion)');
        Parameters.ParamByName('storename').Value := Trim(StoreName.Text);
        Parameters.ParamByName('shortname').Value := Trim(Nameshort.Text);
        Parameters.ParamByName('spec').Value := Trim(Spec.Text);
        Parameters.ParamByName('defaultprice').Value := StrToFloat(Defaultprice.Text);
        Parameters.ParamByName('barcode').Value := Trim(Barcode.Text);
        Parameters.ParamByName('basicunit').Value := Trim(Basicunit.Text);
        Parameters.ParamByName('stockunit').Value := Trim(Stockunit.Text);
        Parameters.ParamByName('conversion').Value := Trim(Conversion.Text);
        ExecSQL;
      end;
      Application.MessageBox('操作成功.','提示',64);
      Cancel.Click;
    Except
      On E: Exception do
        ShowMessage(E.Message);
    End;
  end
  else
  begin
    Application.MessageBox('物资信息不能为空.','提示',64);
  end;
end;

procedure Tf_storeinfo.UpdateClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
  begin
    if TextIsNull = False then
    begin
      if Application.MessageBox(Pchar('确实要修改物资名称为: '+t_data.Query1.FieldByName('storename').AsString+' 的物资信息吗?'),'提示',mb_YesNo)= ID_Yes then
      begin
        Try
          With t_data.update1 do
          begin
            CLose;
            SQL.Clear;
            SQL.Add('update tb_storeinfo set storename = :name,nameshort = :short,spec =:spec,defaultprice = :defaultprice,barcode = :barcode,basicunit = :basicunit,stockunit = :stockunit,conversion = :conversion where storename = :oldname');
            Parameters.ParamByName('name').Value := Trim(Storename.Text);
            Parameters.ParamByName('short').Value := Trim(Nameshort.Text);
            Parameters.ParamByName('spec').Value := Trim(spec.Text);
            Parameters.ParamByName('defaultprice').Value := StrToFloat(Defaultprice.Text);
            Parameters.ParamByName('barcode').Value := Trim(Barcode.Text);
            Parameters.ParamByName('basicunit').Value := Trim(Basicunit.Text);
            Parameters.ParamByName('stockunit').Value := Trim(Stockunit.Text);
            Parameters.ParamByName('conversion').Value := StrToFloat(Conversion.Text);
            Parameters.ParamByName('oldname').Value := Trim(t_data.Query1.FieldByName('storename').AsString);
            ExecSQL;
          end;
          Application.MessageBox('修改成功.','提示',64);
          Cancel.Click;
        Except
          On E: Exception do
            ShowMessage(E.Message);
        End;
      end;
    end
    else
      Application.MessageBox('物资信息不能为空.','提示',64);
  end
  else
    Application.MessageBox('当前没有可修改的数据.','提示',64);
end;

procedure Tf_storeinfo.DeleteClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
  begin
    if Application.MessageBox(Pchar('确实要删除物资名称为: ' + Trim(t_data.Query1.FieldByName('storename').AsString)+' 的物资信息吗?'),'提示',mb_YesNo)= ID_Yes then
    begin
      Try
        t_data.Query1.Delete;
        Cancel.Click;
      Except
        On E: Exception do
          ShowMessage(E.Message);
      End;
    end
  end
  else
    Application.MessageBox('当前没有可删除的信息.','提示',64);
end;
//处理查询按钮的单击事件
procedure Tf_storeinfo.QueryClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
  begin
    With t_data.Query1 do
    begin
      CLose;
      SQL.Clear;
      SQL.Add('select * from tb_storeinfo where ');
      if Field.ItemIndex = 0 then
      begin
        SQL.Add('storename Like :Value');
        Parameters.ParamByName('Value').Value := '%'+Trim(Value.Text)+'%';
      end
      else
      begin
        if Field.ItemIndex = 1 then
          SQL.Add('nameshort ')
        else
          SQL.Add('barcode ');
        SQL.Add(' = :Value');
        Parameters.ParamByName('value').Value := Trim(Value.Text);
      end;
      Open;
    end;
    if t_data.Query1.RecordCount<1 then
    begin
      Cancel.Click;
      Application.MessageBox('没有找到符合条件的记录.','提示',64);
    end;
  end
  else
    Application.MessageBox('当前没有可查询的数据.','提示',64);
end;
//防止输入非法字符,只允许输入数字
procedure Tf_storeinfo.DefaultpriceKeyPress(Sender: TObject;
  var Key: Char);
begin
  inherited;
  if Sender is TEdit then
  begin
    if  not (Key in ['0'..'9','.',#8]) then
      Key := #0;
    if key = '.' then
      if Pos('.',Trim(TEdit(Sender).Text)) <>0 then
        Key := #0;
  end;
end;

procedure Tf_storeinfo.FormShow(Sender: TObject);
begin
  inherited;
  Cancel.Click;
end;

procedure Tf_storeinfo.DBGrid1DblClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
    Editvalue;
end;

procedure Tf_storeinfo.Editvalue;
begin
  with t_data.Query1 do
  begin
    Storename.Text := Trim(FieldByName('storename').AsString);
    Nameshort.Text := Trim(FieldByName('nameshort').AsString);
    Spec.Text := Trim(FieldByName('spec').AsString);
    Defaultprice.Text := Trim(FieldByName('Defaultprice').AsString);
    Barcode.Text := Trim(FieldByName('Barcode').AsString);
    Basicunit.Text := Trim(FieldByName('basicunit').AsString);
    Stockunit.Text := Trim(FieldByName('stockunit').AsString);
    Conversion.Text := Trim(FieldByName('Conversion').AsString);
  end;
end;

end.
💿 文件大小 5665 K
👤 上传用户 jccg1000146752
📂 所属分类数据库系统
🏷️ 相关标签

#物流管理系统 #典型 #数据库 #应用程序
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -