checkmorelogout.pas

物流管理系统是一个典型的数据库应用程序

unit checkmorelogout;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, checkloselogout, DB, StdCtrls, ComCtrls, Buttons,
  Grids, DBGrids, ExtCtrls,ADODB;

type
  Tf_checkmorelogout = class(Tf_checkloselogout)
    procedure QueryClick(Sender: TObject);override;
    procedure ConfirmClick(Sender: TObject);override;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  f_checkmorelogout: Tf_checkmorelogout;

implementation

uses data, main;

{$R *.dfm}
//处理查询按钮的单击事件
procedure Tf_checkmorelogout.QueryClick(Sender: TObject);
begin
  if (Storageid.Checked = True)or(Date.Checked = True) then
  begin
    if (Storageid.Checked)and(not Date.Checked) then  //只按票号查询
    begin
      if Trim(InRegid.Text)<>'' then
      begin
        With t_data.Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from v_morestorequery where moreid = :moreid');
          Parameters.ParamByName('moreid').Value := Trim(inregid.Text);
          Open;
        end;
      end
      else
      begin
        Application.MessageBox('请输入票号.','提示',64);
        Exit;
      end;
    end
    else if (not storageid.Checked)and(date.Checked) then //只按事件查询
    begin
      with t_data.Query1 do
      begin
        Close;
        SQL.Clear;
        SQL.Add('select * from v_morestorequery where');
        SQL.Add(' TimeDate >= :FromDate and Timedate < :ToDate');
        Parameters.ParamByName('FromDate').Value := Trunc(FromDate.DateTime);
        Parameters.ParamByName('ToDate').Value := Trunc(ToDate.DateTime)+1;
        Open;
      end;
    end
    else //即按票号又按时间查询
    begin
      if Trim(Inregid.Text)<>'' then
      begin
        With t_data.Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from v_morestorequery where moreid = :moreid and TimeDate >= :FromDate and Timedate < :ToDate');
          Parameters.ParamByName('FromDate').Value := Trunc(FromDate.DateTime);
          Parameters.ParamByName('ToDate').Value := Trunc(ToDate.DateTime)+1;
          Parameters.ParamByName('moreid').Value := Trim(Inregid.Text);
          Open;
        end;
      end
      else
      begin
        Application.MessageBox('请输入票号.','提示',64);
        Exit;
      end;
    end;
    if t_data.Query1.RecordCount>0 then
    begin
      master.DataSet := t_data.Query1;
      Confirm.Enabled := True;
    end
    else
    begin
      t_data.Query1.Close;
      Confirm.Enabled := False;
      Application.MessageBox('没有找到符合条件的记录.','提示',64);
    end;
  end
  else
  begin
    Application.MessageBox('请设置查询条件.','提示',64);
  end;
end;
//处理确定按钮单击事件
procedure Tf_checkmorelogout.ConfirmClick(Sender: TObject);
var
  Connect1: TADOConnection;
  Query1,Query2: TADOQuery;
begin
  //提示是否进行冲销操作
  if Application.MessageBox(Pchar('确实要冲销票号为: '+ t_data.Query1.FieldByName('moreid').AsString+' 的报溢信息吗?'),'提示',mb_yesno)= Id_Yes then
  begin
    Try
      //动态创建TADOConnection组件以进行事务控制
      Connect1 := TADOConnection.Create(Nil);
      Query1 := TADOQuery.Create(Nil);
      Query2 := TADOQuery.Create(nil);
      Connect1.ConnectionString := t_data.Connection1.ConnectionString; //设置连接字符串
      Connect1.LoginPrompt := False; //取消登录对话框
      Connect1.Open;
      Query1.Connection := Connect1;
      Query2.Connection := Connect1;
      Try
        Connect1.BeginTrans;//开始一个事务
        //修改库存
        With Query2 do   //查询报溢信息
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from v_morestorequery where moreid = :moreid');
          Parameters.ParamByName('moreid').Value := Trim(t_data.Query1.FieldByName('moreid').AsString);
          Open;
        end;
        while not Query2.Eof do //利用循环的方式修改库存数量,将其修改为未进行报溢处理的状态
        begin
          With Query1 do
          begin
            Close;
            SQL.Clear;
            SQL.Add('update tb_comstorage set storesum = storesum - :num where storagename = :storagename and storename = :storename');
            Parameters.ParamByName('num').Value := Query2.FieldByName('num').AsFloat;
            Parameters.ParamByName('storagename').Value := Query2.FieldByName('storagename').AsString;
            Parameters.ParamByName('storename').Value := Query2.FieldByName('storename').AsString;
            ExecSQL;
          end;
          Query2.Next;
        end;
        //删除报损票号历史记录
        With Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('delete from tb_checkmoreid where moreid = :moreid'); //会级联删除明细表中的数据(tb_storelist)
          Parameters.ParamByName('moreid').Value := Trim(t_data.Query1.FieldByName('moreid').AsString);
          ExecSQL;
        end;
        //执行存储过程保存冲销信息
        With Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('Exec Add_IDLogout :Id,:kind,:operator');
          Parameters.ParamByName('Id').Value := Trim(t_data.Query1.FieldByName('moreid').AsString);
          Parameters.ParamByName('Kind').Value := morestore;
          Parameters.ParamByName('operator').Value := Trim(t_main.Operatorname);
          ExecSQL;
        end;
        Connect1.CommitTrans; //提交事务
        Cancel.Click;
        Application.MessageBox('操作成功.','提示',64);
      Except   //如果出现异常则回滚事务
        Connect1.RollbackTrans;
        Application.MessageBox('系统出错.','提示',64);
      end;
    Finally
      Connect1.Free;
      Query1.Free;
      Query2.Free;
    end;
  end;
end;

end.