cancelstorelogout.pas

物流管理系统是一个典型的数据库应用程序

unit cancelstorelogout;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, instorelogout, DB, StdCtrls,ComCtrls, Buttons,
  Grids, DBGrids, ExtCtrls,ADODB;

type
  Tf_Cancelstorelogout = class(Tf_Instorelogout)
    procedure QueryClick(Sender: TObject);override;
    procedure ConfirmClick(Sender: TObject); override;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  f_Cancelstorelogout: Tf_Cancelstorelogout;

implementation
  uses data,main;
{$R *.dfm}
//处理查询按钮的单击事件
procedure Tf_Cancelstorelogout.QueryClick(Sender: TObject);
begin
  if (Storageid.Checked = True)or(Date.Checked = True) then
  begin
    if (Storageid.Checked)and(not Date.Checked) then  //只按票号查询
    begin
      if Trim(InRegid.Text)<>'' then
      begin
        With t_data.Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from v_cancelstorequery where cancelid = :cancelid');
          Parameters.ParamByName('cancelid').Value := Trim(inregid.Text);
          Open;
        end;
      end
      else
      begin
        Application.MessageBox('请输入票号.','提示',64);
        Exit;
      end;
    end
    else if (not storageid.Checked)and(date.Checked) then  //只按时间查询
    begin
      with t_data.Query1 do
      begin
        Close;
        SQL.Clear;
        SQL.Add('select * from v_cancelstorequery where');
        SQL.Add(' TimeDate >= :FromDate and Timedate < :ToDate');
        Parameters.ParamByName('FromDate').Value := Trunc(FromDate.DateTime);
        Parameters.ParamByName('ToDate').Value := Trunc(ToDate.DateTime)+1;
        Open;
      end;
    end
    else  //即按票号又按时间查询
    begin
      if Trim(Inregid.Text)<>'' then
      begin
        With t_data.Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from v_cancelstorequery where cancelid = :cancelid and TimeDate >= :FromDate and Timedate < :ToDate');
          Parameters.ParamByName('FromDate').Value := Trunc(FromDate.DateTime);
          Parameters.ParamByName('ToDate').Value := Trunc(ToDate.DateTime)+1;
          Parameters.ParamByName('cancelid').Value := Trim(Inregid.Text);
          Open;
        end;
      end
      else
      begin
        Application.MessageBox('请输入票号.','提示',64);
        Exit;
      end;
    end;
    if t_data.Query1.RecordCount>0 then
    begin
      master.DataSet := t_data.Query1;
      Confirm.Enabled := True;
    end
    else
    begin
      t_data.Query1.Close;
      Confirm.Enabled := False;
      Application.MessageBox('没有找到符合条件的记录.','提示',64);
    end;
  end
  else
  begin
    Application.MessageBox('请设置查询条件.','提示',64);
  end;
end;
//处理确定按钮的单击事件
procedure Tf_Cancelstorelogout.ConfirmClick(Sender: TObject);
var
  Connect1: TADOConnection;
  Query1,Query2: TADOQuery;
begin
  Connect1 := Nil;
  Query1 := Nil;
  Query2 := Nil;
  //提示是否进行冲销操作
  if Application.MessageBox(Pchar('确实要冲销票号为: '+ t_data.Query1.FieldByName('Cancelid').AsString+' 的入库退货信息吗?'),'提示',mb_yesno)= Id_Yes then
  begin
    Try
      //动态创建TADOConnection组件以进行事务控制
      Connect1 := TADOConnection.Create(Nil);
      Query1 := TADOQuery.Create(Nil);
      Query2 := TADOQuery.Create(nil);
      Connect1.ConnectionString := t_data.Connection1.ConnectionString;
      Connect1.LoginPrompt := False;
      Connect1.Open;
      Query1.Connection := Connect1;
      Query2.Connection := Connect1;
      Try
        Connect1.BeginTrans;//开始一个事务
        //修改库存
        With Query2 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from v_cancelstorequery where cancelid = :cancelid');
          Parameters.ParamByName('cancelid').Value := Trim(t_data.Query1.FieldByName('cancelid').AsString);
          Open;
        end;
        while not Query2.Eof do
        begin
          With Query1 do
          begin
            Close;
            SQL.Clear;
            SQL.Add('update tb_comstorage set storesum = storesum + :sum where storagename = :storagename and storename = :storename');
            Parameters.ParamByName('sum').Value := Query2.FieldByName('storesum').AsFloat;
            Parameters.ParamByName('storagename').Value := Query2.FieldByName('storagename').AsString;
            Parameters.ParamByName('storename').Value := Query2.FieldByName('storename').AsString;
            ExecSQL;
          end;
          Query2.Next;
        end;
        //修改供应商结款信息
        With query1 do
        begin
          CLose;
          SQL.Clear;
          SQL.Add('update tb_providerpayment set paymoney = paymoney + :paymoney where providername = :providername');
          Parameters.ParamByName('paymoney').Value := t_data.Query1.FieldByName('paymoney').AsFloat- t_data.Query1.FieldByName('factmoney').AsFloat;
          Parameters.ParamByName('providername').Value := Trim(t_data.Query1.FieldByName('providername').AsString);
          ExecSQL;
        end;
        //删除入库票号历史记录
        With Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('delete from tb_storecancelid where cancelid = :cancelid'); //会级联删除明细表中的数据(tb_storelist)
          Parameters.ParamByName('cancelid').Value := Trim(t_data.Query1.FieldByName('cancelid').AsString);
          ExecSQL;
        end;
        //执行存储过程保存冲销信息
        With Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('Exec Add_IDLogout :Id,:kind,:operator');
          Parameters.ParamByName('Id').Value := Trim(t_data.Query1.FieldByName('cancelid').AsString);
          Parameters.ParamByName('Kind').Value := cancelstore ;
          Parameters.ParamByName('operator').Value := Trim(t_main.Operatorname);
          ExecSQL;
        end;
        Connect1.CommitTrans; //提交事务
        Cancel.Click;
        Application.MessageBox('操作成功.','提示',64);
      Except
        Connect1.RollbackTrans; //出现异常则回滚事务
        Application.MessageBox('系统出错.','提示',64);
      end;
    Finally
      Connect1.Free;
      Query1.Free;
      Query2.Free;
    end;
  end;
end;

end.