providerchecklogout.pas

物流管理系统是一个典型的数据库应用程序

unit providerchecklogout;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, instorelogout, DB, StdCtrls, ComCtrls, Buttons,
  Grids, DBGrids, ExtCtrls,ADODB;

type
  Tf_providerchecklogout = class(Tf_Instorelogout)
    procedure QueryClick(Sender: TObject);override;
    procedure ConfirmClick(Sender: TObject);override;
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  f_providerchecklogout: Tf_providerchecklogout;

implementation
  uses Data, main;
{$R *.dfm}
//处理查询按钮单击事件
procedure Tf_providerchecklogout.QueryClick(Sender: TObject);
begin
  if (Storageid.Checked = True)or(Date.Checked = True) then //是否设置了查询条件
  begin
    if (Storageid.Checked)and(not Date.Checked) then  //只按票号查询
    begin
      if Trim(InRegid.Text)<>'' then //是否输入输入结款票号
      begin
        With t_data.Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from tb_providercheck where checkid = :checkid');
          Parameters.ParamByName('checkid').Value := Trim(inregid.Text);
          Open;
        end;
      end
      else
      begin
        Application.MessageBox('请输入票号.','提示',64);
        Exit;
      end;
    end
    else if (not storageid.Checked)and(date.Checked) then //按时间查询
    begin
      with t_data.Query1 do
      begin
        Close;
        SQL.Clear;
        SQL.Add('select * from tb_providercheck where');
        SQL.Add(' TimeDate >= :FromDate and Timedate < :ToDate');
        Parameters.ParamByName('FromDate').Value := Trunc(FromDate.DateTime);
        Parameters.ParamByName('ToDate').Value := Trunc(ToDate.DateTime)+1;
        Open;
      end;
    end
    else  //即按票号又按时间查询
    begin
      if Trim(Inregid.Text)<>'' then
      begin
        With t_data.Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('select * from tb_providercheck where checkid = :checkid and TimeDate >= :FromDate and Timedate < :ToDate');
          Parameters.ParamByName('FromDate').Value := Trunc(FromDate.DateTime);
          Parameters.ParamByName('ToDate').Value := Trunc(ToDate.DateTime)+1;
          Parameters.ParamByName('checkid').Value := Trim(Inregid.Text);
          Open;
        end;
      end
      else
      begin
        Application.MessageBox('请输入票号.','提示',64);
        Exit;
      end;
    end;
    if t_data.Query1.RecordCount>0 then
    begin
      master.DataSet := t_data.Query1;
      Confirm.Enabled := True;
    end
    else
    begin
      t_data.Query1.Close;
      Confirm.Enabled := False;
      Application.MessageBox('没有找到符合条件的记录.','提示',64);
    end;
  end
  else
  begin
    Application.MessageBox('请设置查询条件.','提示',64);
  end;
end;
//处理确定按钮单击事件
procedure Tf_providerchecklogout.ConfirmClick(Sender: TObject);
var
  Connect1: TADOConnection;
  Query1: TADOQuery;
begin
  //提示是否进行冲销操作
  if Application.MessageBox(Pchar('确实要冲销票号为: '+ t_data.Query1.FieldByName('checkid').AsString+' 的结款信息吗?'),'提示',mb_yesno)= Id_Yes then
  begin
    Try
      //动态创建TADOConnection组件,用于进行事务控制
      Connect1 := TADOConnection.Create(Nil);
      Query1 := TADOQuery.Create(Nil);
      Connect1.ConnectionString := t_data.Connection1.ConnectionString;
      Connect1.LoginPrompt := False; //取消登录对话框
      Connect1.Open;
      Query1.Connection := Connect1;
      Try
        Connect1.BeginTrans; //开始一个事务
        With Query1 do //修改供应商结款金额,使其恢复到未结款的状态
        begin
          Close;
          SQL.Clear;
          SQL.Add('update tb_providerpayment set paymoney = paymoney + :paymoney where providername = :providername');
          Parameters.ParamByName('paymoney').Value := t_data.Query1.FieldByName('paymoney').AsFloat;
          Parameters.ParamByName('providername').Value := Trim(t_data.Query1.FieldByName('providername').AsString);
          ExecSQL;
        end;
        With Query1 do   //删除结款信息
        begin
          Close;
          SQL.Clear;
          SQL.Add('delete from tb_providercheck where checkid = :checkid'); //会级联删除明细表中的数据(tb_storelist)
          Parameters.ParamByName('checkid').Value := Trim(t_data.Query1.FieldByName('checkid').AsString);
          ExecSQL;
        end;
        //执行存储过程保存冲销信息
        With Query1 do
        begin
          Close;
          SQL.Clear;
          SQL.Add('Exec Add_IDLogout :Id,:kind,:operator');
          Parameters.ParamByName('Id').Value := Trim(t_data.Query1.FieldByName('checkid').AsString);
          Parameters.ParamByName('Kind').Value := providerpay;
          Parameters.ParamByName('operator').Value := Trim(t_main.Operatorname);
          ExecSQL;
        end;
        Connect1.CommitTrans; //提交事务
        Cancel.Click;
        Application.MessageBox('操作成功.','提示',64);
      Except
        Connect1.RollbackTrans;//回滚事务
        Application.MessageBox('系统出错.','提示',64);
      end;
    Finally
      Connect1.Free;
      Query1.Free;
    end;
  end;
end;

end.