providerinfo.pas

物流管理系统是一个典型的数据库应用程序

unit providerinfo;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, frame, DB, Grids, DBGrids, StdCtrls, Buttons,
  ExtCtrls;

type
  Tf_providerinfo = class(Tf_frame)
    Label6: TLabel;
    Panel2: TPanel;
    Label7: TLabel;
    Label8: TLabel;
    Add: TBitBtn;
    Cancel: TBitBtn;
    Update: TBitBtn;
    Delete: TBitBtn;
    Field: TComboBox;
    Query: TBitBtn;
    DBGrid1: TDBGrid;
    ProviderSource: TDataSource;
    Panel1: TPanel;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label9: TLabel;
    providername: TEdit;
    Nameshort: TEdit;
    Phone: TEdit;
    Principal: TEdit;
    Address: TEdit;
    Web: TEdit;
    Value: TEdit;
    procedure providernameKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure FormShow(Sender: TObject);
    procedure CancelClick(Sender: TObject);
    procedure AddClick(Sender: TObject);
    procedure UpdateClick(Sender: TObject);
    procedure DeleteClick(Sender: TObject);
    procedure QueryClick(Sender: TObject);
    procedure DBGrid1DblClick(Sender: TObject);
    procedure PhoneKeyPress(Sender: TObject; var Key: Char);
  private
    { Private declarations }
  public
    Procedure ClearEdit;//清空编辑框中的文本
    Function TextIsNull: Boolean;//判断编辑框中的文本是否为空
    Procedure Editvalue;//将数据集中的数据显示在编辑框中

    { Public declarations }
  end;

var
  f_providerinfo: Tf_providerinfo;

implementation
  uses data;
{$R *.dfm}
//按回车键控制焦点移动
procedure Tf_providerinfo.providernameKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  inherited;
  if Key = vk_Return then
    Findnext(True);
end;
//窗体显示时调用取消按钮的单击事件代码初始化
procedure Tf_providerinfo.FormShow(Sender: TObject);
begin
  inherited;
  Cancel.Click;
end;
//自定义过程,用于清空编辑框中的文本
procedure Tf_providerinfo.ClearEdit;
var
  i: Integer;
begin
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i]is TEdit then
      TEdit(Panel1.Controls[i]).Clear;
end;
//取消按钮单击事件,用于进行初始化
procedure Tf_providerinfo.CancelClick(Sender: TObject);
begin
  inherited;
  ClearEdit; //清空编辑框文本
  Field.ItemIndex := 0;
  With t_data.Query1 do //向表格中加载供应商信息
  begin
    CLose;
    SQL.Clear;
    SQL.Add('Select * from tb_providerinfo');
    Open;
  end;
  if t_data.Query1.RecordCount>0 then
    ProviderSource.DataSet := t_data.Query1
  else
  begin
    t_data.Query1.Close;
    ProviderSource.DataSet := Nil;
  end;
end;
//自定义过程,将当前记录数据显示在编辑框中
procedure Tf_providerinfo.Editvalue;
begin
  with t_data.Query1 do
  begin
    Providername.Text := Trim(FieldByName('Providername').AsString);
    Nameshort.Text := Trim(FieldByName('nameshort').AsString);
    Phone.Text := Trim(FieldByName('phone').AsString);
    Principal.Text := Trim(FieldByName('Principal').AsString);
    Address.Text := Trim(FieldByName('Address').AsString);
    Web.Text := Trim(FieldByName('web').AsString);
  end;
end;
//自定义函数,用于判断编辑框文本是否空,如果为空,返回值为True,否则为False
function Tf_providerinfo.TextIsNull: Boolean;
var
  i: Integer;
begin
  Result := False;
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i] is TEdit then
    begin
      if Trim(TEdit(Panel1.Controls[i]).Text)='' then
      begin
        Result := True;
        Break;
      end;
    end;
end;
//处理添加按钮的单击事件,
procedure Tf_providerinfo.AddClick(Sender: TObject);
begin
  inherited;
  if TextIsNull = False then //判断编辑框文本是否为空
  begin
    With t_data.Query2 do  //判断供应商是否存在
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_providerinfo where providername = :name');
      Parameters.ParamByName('name').Value := Trim(Providername.Text);
      Open;
    end;
    if t_data.Query2.RecordCount>0 then
    begin
      Application.MessageBox('该供应商已经存在,请重新输入.','提示',64);
      Providername.SelectAll;
      Providername.SetFocus;
      Exit;
    end;
    Try
      with t_data.Add1 do  //保存供应商信息
      begin
        Close;
        SQL.Clear;
        SQL.Add('Insert into tb_providerinfo Values (:providername,:shortname,:principal,:phone,:address,:web)');
        Parameters.ParamByName('providername').Value := Trim(Providername.Text);
        Parameters.ParamByName('shortname').Value := Trim(Nameshort.Text);
        Parameters.ParamByName('principal').Value := Trim(Principal.Text);
        Parameters.ParamByName('phone').Value := Trim(Phone.Text);
        Parameters.ParamByName('address').Value := Trim(Address.Text);
        Parameters.ParamByName('web').Value := Trim(Web.Text);
        ExecSQL;
      end;
      Application.MessageBox('操作成功.','提示',64);
      Cancel.Click;
    Except
      On E: Exception do    //如果产生异常,显示异常信息
        ShowMessage(E.Message);
    End;
  end
  else
  begin
    Application.MessageBox('供应商信息不能为空.','提示',64);
  end;
end;
//处理修改按钮的单击事件
procedure Tf_providerinfo.UpdateClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //判断当前是否有可修改的数据
  begin
    if TextIsNull = False then //判断基础信息是否为空
    begin
      //提示是否修改数据
      if Application.MessageBox(Pchar('确实要修改供应商名称为: '+t_data.Query1.FieldByName('Providername').AsString+' 的供应商信息吗?'),'提示',mb_YesNo)= ID_Yes then
      begin
        Try
          With t_data.update1 do
          begin
            CLose;
            SQL.Clear;
            SQL.Add('update tb_providerinfo set providername = :name,nameshort = :short,principal =:principal,phone = :phone,address = :address,web = :web where providername = :oldname');
            Parameters.ParamByName('name').Value := Trim(Providername.Text);
            Parameters.ParamByName('short').Value := Trim(Nameshort.Text);
            Parameters.ParamByName('principal').Value := Trim(principal.Text);
            Parameters.ParamByName('phone').Value := Trim(phone.Text);
            Parameters.ParamByName('address').Value := Trim(address.Text);
            Parameters.ParamByName('web').Value := Trim(web.Text);
            Parameters.ParamByName('oldname').Value := Trim(t_data.Query1.FieldByName('providername').AsString);
            ExecSQL;
          end;
          Application.MessageBox('修改成功.','提示',64);
          Cancel.Click;
        Except
          On E: Exception do //如果产生异常则显示错误提示
            ShowMessage(E.Message);
        End;
      end;
    end
    else
      Application.MessageBox('供应商信息不能为空.','提示',64);
  end
  else
    Application.MessageBox('当前没有可修改的数据.','提示',64);
end;
//处理删除按钮的单击事件
procedure Tf_providerinfo.DeleteClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then  //如果当前有可删除的数据
  begin
    //提示是否删除数据
    if Application.MessageBox(Pchar('确实要删除供应商名称为: ' + Trim(t_data.Query1.FieldByName('providername').AsString)+' 的供应商信息吗?'),'提示',mb_YesNo)= ID_Yes then
    begin
      Try
        t_data.Query1.Delete;
        Cancel.Click;
      Except
        On E: Exception do  //如果产生异常则显示错误提示
          ShowMessage(E.Message);
      End;
    end
  end
  else
    Application.MessageBox('当前没有可删除的信息.','提示',64);
end;
procedure Tf_providerinfo.QueryClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //是否有可查询的信息
  begin
    With t_data.Query1 do
    begin
      CLose;
      SQL.Clear;
      SQL.Add('select * from tb_providerinfo where ');
      if Field.ItemIndex = 0 then
      begin
        SQL.Add('providername Like :Value');
        Parameters.ParamByName('Value').Value := '%'+Trim(Value.Text)+'%';
      end
      else
      begin
        if Field.ItemIndex = 1 then
          SQL.Add('nameshort ')
        else
          SQL.Add('principal ');
        SQL.Add(' = :Value');
        Parameters.ParamByName('value').Value := Trim(Value.Text);
      end;
      Open;
    end;
    if t_data.Query1.RecordCount<1 then
    begin
      Cancel.Click;
      Application.MessageBox('没有找到符合条件的记录.','提示',64);
    end;
  end
  else
    Application.MessageBox('当前没有可查询的数据.','提示',64);
end;
//双击表格,将当前记录信息显示在编辑框中
procedure Tf_providerinfo.DBGrid1DblClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
    Editvalue;
end;
//防止在电话号码中输入非法字符
procedure Tf_providerinfo.PhoneKeyPress(Sender: TObject; var Key: Char);
begin
  inherited;
  if Not(key in ['0'..'9','-',#8]) then
    Key := #0;
end;

end.