operatorinfo.pas

物流管理系统是一个典型的数据库应用程序

unit operatorinfo;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, frame, StdCtrls, Buttons, Grids, DBGrids, ExtCtrls,
  DB;

type
  Tf_operatorinfo = class(Tf_frame)
    Panel1: TGroupBox;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Level: TComboBox;
    DBGrid1: TDBGrid;
    Add: TBitBtn;
    Cancel: TBitBtn;
    Update: TBitBtn;
    Delete: TBitBtn;
    Image1: TImage;
    OperatorSource: TDataSource;
    Operatorname: TEdit;
    Password: TEdit;
    procedure CancelClick(Sender: TObject);
    procedure AddClick(Sender: TObject);
    procedure DeleteClick(Sender: TObject);
    procedure UpdateClick(Sender: TObject);
    procedure OperatornameKeyDown(Sender: TObject; var Key: Word;
      Shift: TShiftState);
    procedure DBGrid1DblClick(Sender: TObject);
  private
    { Private declarations }
  public
    Procedure ClearEdit;//清空编辑框中的文本
    Function TextIsNull: Boolean;//判断编辑框中的文本是否为空
    Procedure Editvalue;//将数据集中的数据显示在编辑框中
    { Public declarations }
  end;

var
  f_operatorinfo: Tf_operatorinfo;

implementation
  uses data;
{$R *.dfm}

{ Tf_operatorinfo }
//自定义过程,用于清空编辑框中的文本
procedure Tf_operatorinfo.ClearEdit;
var
  i: Integer;
begin
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i]is TEdit then
      TEdit(Panel1.Controls[i]).Clear;
end;
//为编辑框赋值
procedure Tf_operatorinfo.Editvalue;
begin
  with t_data.Query1 do
  begin
    Operatorname.Text := Trim(FieldByName('Operatorname').AsString);
    Password.Text := Trim(FieldByName('password').AsString);
    Level.ItemIndex := Level.Items.IndexOf(Trim(FieldByName('Level').AsString));
  end;
end;
//判断信息是否为空
function Tf_operatorinfo.TextIsNull: Boolean;
var
  i: Integer;
begin
  Result := False;
  For i := 0 to Panel1.ControlCount-1 do
    if Panel1.Controls[i] is TEdit then
    begin
      if Trim(TEdit(Panel1.Controls[i]).Text)='' then
      begin
        Result := True;
        Exit;
      end;
    end
    else if Panel1.Controls[i] is TComboBox then
    begin
      if Trim(TComboBox(Panel1.Controls[i]).Text)='' then
      begin
        Result := True;
        Exit;
      end;
    end;
end;
//取消按钮单击事件
procedure Tf_operatorinfo.CancelClick(Sender: TObject);
begin
  inherited;
  ClearEdit; //请空编辑框文本
  With t_data.Query1 do //显示当前操作员信息
  begin
    CLose;
    SQL.Clear;
    SQL.Add('Select * from tb_operatorinfo');
    Open;
  end;
  if t_data.Query1.RecordCount>0 then
    OperatorSource.DataSet := t_data.Query1
  else
  begin
    t_data.Query1.Close;
    OperatorSource.DataSet := Nil;
  end;
  Level.ItemIndex := 0;
end;
//添加按钮单击事件
procedure Tf_operatorinfo.AddClick(Sender: TObject);
begin
  inherited;
  if TextIsNull = False then //如果基础信息不为空
  begin
    With t_data.Query2 do //判断操作员信息是否在员工信息表中存在
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_employeeinfo where workername = :name');
      Parameters.ParamByName('name').Value := Trim(Operatorname.Text);
      Open;
    end;
    if t_data.Query2.RecordCount<1 then //如果操作员信息在员工信息表中不存在,进行提示并退出
    begin
      Application.MessageBox('该操作员在员工信息表中不存在,请重新输入.','提示',64);
      Operatorname.SelectAll;
      Operatorname.SetFocus;
      Exit;
    end;
    With t_data.Query2 do  //判断操作员信息在操作员信息表中是否存在
    begin
      CLose;
      SQL.Clear;
      SQL.Add('Select * from tb_operatorinfo where operatorname = :name');
      Parameters.ParamByName('name').Value := Trim(Operatorname.Text);
      Open;
    end;
    if t_data.Query2.RecordCount>0 then //如果操作员信息在操作员信息表中存在,进行退出并退出
    begin
      Application.MessageBox('该操作员已经存在,请重新输入.','提示',64);
      Operatorname.SelectAll;
      Operatorname.SetFocus;
      Exit;
    end;
    Try
      with t_data.Add1 do //将操作员工信息添加到操作员信息表中
      begin
        Close;
        SQL.Clear;
        SQL.Add('Insert into tb_operatorinfo Values (:operatorname,:password,:level)');
        Parameters.ParamByName('operatorname').Value := Trim(Operatorname.Text);
        Parameters.ParamByName('password').Value := Trim(Password.Text);
        Parameters.ParamByName('level').Value := Trim(Level.Text);
        ExecSQL;
      end;
      Application.MessageBox('操作成功.','提示',64);
      Cancel.Click;
    Except
      On E: Exception do
        ShowMessage(E.Message);
    End;
  end
  else
  begin
    Application.MessageBox('操作员信息不能为空.','提示',64);
  end;
end;
//处理删除按钮单击事件
procedure Tf_operatorinfo.DeleteClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
  begin
    if Application.MessageBox(Pchar('确实要删除操作员名称为: ' + Trim(t_data.Query1.FieldByName('operatorname').AsString)+' 的操作员信息吗?'),'提示',mb_YesNo)= ID_Yes then
    begin
      Try
        t_data.Query1.Delete;
        Cancel.Click;
      Except
        On E: Exception do
          ShowMessage(E.Message);
      End;
    end
  end
  else
    Application.MessageBox('当前没有可删除的信息.','提示',64);
end;
//处理修改按钮单击事件
procedure Tf_operatorinfo.UpdateClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then //判断数据集是否激活
  begin
    if TextIsNull = False then //判断信息是否为空
    begin
      //提示是否修改数据
      if Application.MessageBox(Pchar('确实要修改操作员名称为: '+t_data.Query1.FieldByName('Operatorname').AsString+' 的操作员信息吗?'),'提示',mb_YesNo)= ID_Yes then
      begin
        Try
          With t_data.update1 do  //利用SQL语句修改数据
          begin
            CLose;
            SQL.Clear;
            SQL.Add('update tb_operatorinfo set operatorname = :operatorname,password = :password,level = :level where operatorname = :oldname');
            Parameters.ParamByName('operatorname').Value := Trim(Operatorname.Text);
            Parameters.ParamByName('password').Value := Trim(password.Text);
            Parameters.ParamByName('level').Value := Trim(Level.Text);
            Parameters.ParamByName('oldname').Value := Trim(t_data.Query1.FieldByName('Operatorname').AsString);
            ExecSQL;
          end;
          Application.MessageBox('修改成功.','提示',64);
          Cancel.Click;
        Except //如果出现异常,显示异常信息
          On E: Exception do
            ShowMessage(E.Message);
        End;
      end;
    end
    else
      Application.MessageBox('职务信息不能为空.','提示',64);
  end
  else
    Application.MessageBox('当前没有可修改的数据.','提示',64);
end;

procedure Tf_operatorinfo.OperatornameKeyDown(Sender: TObject;
  var Key: Word; Shift: TShiftState);
begin
  inherited;
  if Key = vk_Return then //按回车键控制焦点移动
    FindNext(True);
end;
//双击表格,将当前记录信息显示在编辑框中
procedure Tf_operatorinfo.DBGrid1DblClick(Sender: TObject);
begin
  inherited;
  if t_data.Query1.Active then
    Editvalue;
end;

end.