vba16-2.txt

vb.net的开发及应用程序属性查询及应用程序属性查询

Public Sub ClearPageLayout()
    ' Remove all frames except maps.
    Dim pMxDocument As IMxDocument
    Dim pPageLayout As IPageLayout
    Dim pGraphicsContainer As IGraphicsContainer
    Dim pElementsSet As ISet
    Dim pElement As IElement
    Dim pActiveView As IActiveView
    ' Access page layout.
    Set pMxDocument = Application.Document
    Set pPageLayout = pMxDocument.PageLayout
    Set pGraphicsContainer = pPageLayout
    Set pActiveView = pPageLayout
    ' First create a set of elements to be deleted.
    Set pElementsSet = New esriCore.Set
    pGraphicsContainer.Reset
    Set pElement = pGraphicsContainer.Next
    Do While Not pElement Is Nothing
        If Not TypeOf pElement Is IMapFrame Then
            pElementsSet.Add pElement
        End If
        Set pElement = pGraphicsContainer.Next
    Loop
    ' Next remove the elements from the
    ' graphics container.
    pElementsSet.Reset
    Set pElement = pElementsSet.Next
    Do While Not pElement Is Nothing
        pGraphicsContainer.DeleteElement pElement
        Set pElement = pElementsSet.Next
    Loop
    ' Finaly refresh the view.
    pActiveView.Refresh
End Sub