mpv.pro

c++的guiQt做的开发

TEMPLATE = app
TARGET = mpv

# Include general config
include(config.cf)

# Include Windows-specific config
windows:include(config.win)

# Directories for storing temporary files
MOC_DIR = .moc
OBJECTS_DIR = .obj

# Directories with includes
INCLUDEPATH += cimg $$EXTRA_INCLUDES
INCLUDEPATH += ../libmpw

# Directories with libraries
LIBS += -L../libmpw -lmpw $$EXTRA_LIBS

# Dependencies on used libraries
TARGETDEPS += ../libmpw/libmpw.a

# Do not build debug and release binaries at once
CONFIG -= debug_and_release

# Do not put generated binaries into release/ or debug/ subdirs on windows
windows:DESTDIR = ./

# Check debug/release mode
contains( E_RELEASE, no ) {
 # Debug mode
 # Turns off optimalizations
 CONFIG += debug
 CONFIG -= release
 QMAKE_CXXFLAGS += -O0 -g
}
contains( E_RELEASE, yes ) {
 # Release mode
 # Turns on optimalizations
 CONFIG += release
 CONFIG -= debug
 QMAKE_CXXFLAGS += -O2 -DNDEBUG
}

# Input files
HEADERS += argb.h
HEADERS += paramdialog.h
HEADERS += aboutwindow.h
HEADERS += base.h
HEADERS += commandline.h
HEADERS += statusbar.h
HEADERS += dialog.h
HEADERS += fileoption.h
HEADERS += lookandfeel.h
HEADERS += main.h
HEADERS += mainwindow.h
HEADERS += menu.h
HEADERS += mpviewoptionwindow.h
HEADERS += imageview.h
HEADERS += image.h
HEADERS += toolfactory.h

SOURCES += argb.cc
SOURCES += paramdialog.cc
SOURCES += aboutwindow.cc
SOURCES += base.cc
SOURCES += commandline.cc
SOURCES += statusbar.cc
SOURCES += dialog.cc
SOURCES += fileoption.cc
SOURCES += imageview.cc
SOURCES += image.cc
SOURCES += lookandfeel.cc
SOURCES += main.cc
SOURCES += mainwindow.cc
SOURCES += menu.cc
SOURCES += mpviewoptionwindow.cc
SOURCES += toolfactory.cc

# Autoconf-created headers
HEADERS += config.h aconf.h

# Dummy header file for menu translation, needed by lupdate
exists( .menu-trans.h  ) {
 HEADERS += .menu-trans.h 
}

# Translation files
DEPENDPATH += lang
TRANSLATIONS += lang/mpv_cs.ts lang/mpv_pl.ts

# Installation target
program.path    = $$BIN_PATH
program.files   = mpv

# Installation subtarget - Basic data files
data.path       = $$DATA_PATH
data.files      = *.cfg

# Installation subtarget - Icons
data_icon.path  = $$DATA_PATH/icon
data_icon.files = icon/*.png icon/*.svg

# Installation subtarget - Translation files
data_lang.path  = $$DATA_PATH/lang
data_lang.files = lang/*.qm

# Installation subtarget - Documentation
doc.path	= $$DOC_PATH
doc.files	= ../doc/README ../doc/LICENSE.GPL ../doc/AUTHORS ../Changelog

# Installation subtarget - Documentation from CImg
doc_cimg.path	= $$DOC_PATH/cimg
doc_cimg.files	= ../doc/cimg/README.txt ../doc/cimg/Licence_CeCILL-C_V1-en.txt ../doc/cimg/Licence_CeCILL_V2-en.txt

# Installation rule (for "make install")
INSTALLS  = program data data_icon data_lang doc doc_cimg