configure.in

c++的guiQt做的开发

dnl                    -*- Autoconf -*-
dnl Process this file with autoconf to produce a configure script.

AC_PREREQ(2.59)
define([APP_VERSION], patsubst(esyscmd(./getversion),[]))
AC_INIT([MP View], APP_VERSION, [ https://sourceforge.net/tracker/?group_id=194952&atid=951489 ],[mpview])
AC_CONFIG_SRCDIR([src/main.cc])
AC_CONFIG_HEADER(src/aconf.h)

dnl Optional features.
dnl AC_ARG_ENABLE(jpeg,[AS_HELP_STRING([--enable-jpeg],[Use native JPEG support in CImg])],AC_DEFINE(cimg_use_jpeg))
dnl AC_ARG_ENABLE(tiff,[AS_HELP_STRING([--enable-tiff],[Use native TIFF support in CImg])],AC_DEFINE(cimg_use_tiff))
dnl AC_ARG_ENABLE(magick,[AS_HELP_STRING([--enable-magick],[Use native ImageMagick support in CImg])],AC_DEFINE(cimg_use_magick))
dnl AC_ARG_ENABLE(fftw,[AS_HELP_STRING([--enable-fftw],[Use native FFTW 3 support in CImg])],AC_DEFINE(cimg_use_fftw3))

AC_ARG_WITH_DF(libpng,[AS_HELP_STRING([--with-libpng],[Use native PNG support using libpng if available (default=yes)])])
AC_LIBCHECK_DF(libpng,png,png_create_read_struct,cimg_use_png,[png.h])

AC_ARG_WITH_DF(jpeg,[AS_HELP_STRING([--with-jpeg],[Use native JPEG support in CImg if available (default=yes)])])
AC_LIBCHECK_DF(jpeg,jpeg,jpeg_read_header,cimg_use_jpeg,[jpeglib.h])

AC_ARG_WITH_DF(tiff,[AS_HELP_STRING([--with-tiff],[Use native TIFF support in CImg if available (default=yes)])])
AC_LIBCHECK_DF(tiff,tiff,TIFFOpen,cimg_use_tiff,[tiffio.h])

AC_ARG_WITH_DF(fftw,[AS_HELP_STRING([--with-fftw],[Use native FFTW 3 support in CImg if available (default=yes)])])
AC_LIBCHECK_DF(fftw,fftw3,fftw_malloc,cimg_use_fftw3,[fftw3.h])

AC_LANG_PUSH(C++)
AC_ARG_WITH_DF(magick,[AS_HELP_STRING([--with-magick],[Use native ImageMagick support in CImg if available (default=yes)])])
AC_LIBCHECK_MAGICK(magick,[Magick++-config --ldflags --libs],cimg_use_magick,[Magick++.h])
AC_LANG_POP(C++)

dnl Release/debug mode. Debug is default (for now)
AC_ARG_ENABLE(release,
[AS_HELP_STRING([--enable-release],[Turn on compiler optimizations, turn off debugging symbols])]
,,[enable_release=no])
AC_SUBST(enable_release)

dnl check for QTDIR
CHK_ENV_VAR([QTDIR],[QTDIR environment variable must be set])

dnl check for Qt
AC_LOOK_QMAKE
AC_SUBST(ac_qmake)
if test "$ac_qmake" = "";
then
AC_MSG_ERROR([No qmake from QT4 was found.])
fi

dnl check if big or little endian
AC_C_BIGENDIAN

dnl Checks for programs. (c++ compiler,...)
AC_LANG_CPLUSPLUS
AC_PROG_CXX

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS([stdlib.h string.h])

dnl Checks for library functions.
AC_FUNC_ERROR_AT_LINE
AC_FUNC_MALLOC
AC_CHECK_FUNCS([atexit floor])

AC_CONFIG_FILES([Makefile])

dnl Workaround a bug in autoconf
AC_OUTPUT()
EXPAND_VAR(exec_prefix)
EXPAND_VAR(datarootdir)
EXPAND_VAR(datadir)
EXPAND_VAR(mandir)
EXPAND_VAR(bindir)

AC_OUTPUT([libmpw/config.cf src/config.cf src/config.h])

echo ""
echo "Configuration complete"
echo " Using libpng    : $using_libpng"
echo " Using jpeg      : $using_jpeg"
echo " Using tiff      : $using_tiff"
echo " Using FFTW3     : $using_fftw"
echo " Using Magick++  : $using_magick"
echo ""
echo "Type 'make' to build $PACKAGE_STRING"
echo ""