frmclass.frm

适用一般于毕业设计！ VB代码源加SQL 数据库 ··

VERSION 5.00
Object = "{831FDD16-0C5C-11D2-A9FC-0000F8754DA1}#2.0#0"; "MSCOMCTL.OCX"
Begin VB.Form FrmClass 
   BorderStyle     =   3  'Fixed Dialog
   Caption         =   "班级设置"
   ClientHeight    =   5070
   ClientLeft      =   45
   ClientTop       =   435
   ClientWidth     =   6810
   Icon            =   "FrmClass.frx":0000
   LinkTopic       =   "Form1"
   LockControls    =   -1  'True
   MaxButton       =   0   'False
   MDIChild        =   -1  'True
   MinButton       =   0   'False
   ScaleHeight     =   5070
   ScaleWidth      =   6810
   ShowInTaskbar   =   0   'False
   Begin MSComctlLib.TreeView TreeView1 
      Height          =   4035
      Left            =   180
      TabIndex        =   4
      Top             =   180
      Width           =   6375
      _ExtentX        =   11245
      _ExtentY        =   7117
      _Version        =   393217
      HideSelection   =   0   'False
      LabelEdit       =   1
      Style           =   7
      ImageList       =   "ImageList1"
      Appearance      =   1
   End
   Begin MSComctlLib.ImageList ImageList1 
      Left            =   6180
      Top             =   4140
      _ExtentX        =   1005
      _ExtentY        =   1005
      BackColor       =   -2147483628
      ImageWidth      =   16
      ImageHeight     =   16
      MaskColor       =   16777215
      _Version        =   393216
      BeginProperty Images {2C247F25-8591-11D1-B16A-00C0F0283628} 
         NumListImages   =   5
         BeginProperty ListImage1 {2C247F27-8591-11D1-B16A-00C0F0283628} 
            Picture         =   "FrmClass.frx":06EA
            Key             =   "imgGlobalFolder"
         EndProperty
         BeginProperty ListImage2 {2C247F27-8591-11D1-B16A-00C0F0283628} 
            Picture         =   "FrmClass.frx":307C
            Key             =   "imgClosedFolder"
         EndProperty
         BeginProperty ListImage3 {2C247F27-8591-11D1-B16A-00C0F0283628} 
            Picture         =   "FrmClass.frx":3416
            Key             =   "imgOpenedFolder"
         EndProperty
         BeginProperty ListImage4 {2C247F27-8591-11D1-B16A-00C0F0283628} 
            Picture         =   "FrmClass.frx":37B0
            Key             =   "imgDeselectedFile"
         EndProperty
         BeginProperty ListImage5 {2C247F27-8591-11D1-B16A-00C0F0283628} 
            Picture         =   "FrmClass.frx":3B4A
            Key             =   "imgSelectedFile"
         EndProperty
      EndProperty
   End
   Begin VB.CommandButton cmdAdd 
      Caption         =   "添加"
      Default         =   -1  'True
      Height          =   400
      Left            =   660
      TabIndex        =   0
      Top             =   4440
      Width           =   1125
   End
   Begin VB.CommandButton cmdEdit 
      Caption         =   "修改"
      Height          =   400
      Left            =   2100
      TabIndex        =   1
      Top             =   4440
      Width           =   1125
   End
   Begin VB.CommandButton cmdDel 
      Caption         =   "删除"
      Height          =   400
      Left            =   3540
      TabIndex        =   2
      Top             =   4440
      Width           =   1125
   End
   Begin VB.CommandButton cmdClose 
      Cancel          =   -1  'True
      Caption         =   "关闭"
      Height          =   400
      Left            =   4980
      TabIndex        =   3
      Top             =   4440
      Width           =   1125
   End
End
Attribute VB_Name = "FrmClass"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = True
Attribute VB_Exposed = False
Option Explicit

Private Sub Form_Load()
  Dim TmpNode As Node

  '加入根节点（学校）
  Set TmpNode = TreeView1.Nodes.Add(, , "a0", "长沙环境保护职业技术学院", "imgGlobalFolder")
  TmpNode.Selected = True
  TmpNode.Expanded = True
  TreeView1.LabelEdit = tvwManual
  TreeView1.HideSelection = False
  
  '调用通用函数将所有班级或院系添加到TreeView1中
  Call Add_ClassToTree(TreeView1, "a0")

  Left = 0
  Top = 0
End Sub

Private Sub Form_Unload(Cancel As Integer)
  Set FrmClass = Nothing
End Sub

Private Sub cmdAdd_Click()
  ModifyFlag = 0                '以添加记录方式，打开班级编辑窗体
  FrmClassUpdate.Show 1
End Sub

Private Sub cmdEdit_Click()
  '不能修改根节点
  If TreeView1.SelectedItem.Key = "a0" Then
    MsgBox "此项不能修改", vbExclamation + vbOKOnly, "操作提示"
    Exit Sub
  End If
  
  ModifyFlag = 1                '以修改记录方式，打开班级编辑窗体
  FrmClassUpdate.Show 1
End Sub

Private Sub cmdDel_Click()
  Dim sClassID As String      '当前班级或院系的内码ID
  Dim strSql As String
  Dim Rs As New ADODB.Recordset

  '不能删除根节点
  If TreeView1.SelectedItem.Key = "a0" Then
    MsgBox "此项不能删除", vbExclamation + vbOKOnly, "操作提示"
    Exit Sub
  End If
  '如果当前项还含有下一级数据，则不能删除
  If TreeView1.SelectedItem.Children > 0 Then
    MsgBox "当前项中还含有下一级数据，不能删除", _
            vbExclamation + vbOKOnly, "操作提示"
    Exit Sub
  End If
  '如果当前班级已在学生表中使用，则不能删除
  sClassID = Right(TreeView1.SelectedItem.Key, Len(TreeView1.SelectedItem.Key) - 1)
  strSql = "select count(*) as s_count from Students where ClassID='" & sClassID & "'"
  Rs.Open strSql, Conn, adOpenStatic, adLockReadOnly
  If Rs!s_count > 0 Then
    MsgBox "当前班级已在学生表中使用，不能删除", _
            vbExclamation + vbOKOnly, "操作提示"
    Rs.Close
    Set Rs = Nothing
    Exit Sub
  End If
  Rs.Close
  Set Rs = Nothing
  
  '再次确认删除
  If MsgBox("确实要删除当前项吗？", _
            vbYesNo + vbQuestion, "操作提示") = vbNo Then
    Exit Sub
  End If
  '开始删除
  '从Classes表删除该内码ID的班级或院系
  Conn.Execute "delete from Classes where ClassID='" & sClassID & "'"
  '从TreeView1中清除当前节点
  TreeView1.Nodes.Remove TreeView1.SelectedItem.Index
  '判断是否要更改节点图标
  If (TreeView1.SelectedItem.Key <> "a0") And _
     (TreeView1.SelectedItem.Children = 0) Then
      '无下一级数据，显示为叶节点图标
      TreeView1.SelectedItem.Image = "imgDeselectedFile"
      TreeView1.SelectedItem.SelectedImage = "imgSelectedFile"
      TreeView1.SelectedItem.ExpandedImage = 0
  End If
End Sub

Private Sub cmdClose_Click()
  Unload Me
End Sub