vmlinux.lds.s

来自「优龙2410linux2.6.8内核源代码」· S 代码 · 共 139 行

/* ld script to make ARM Linux kernel
 * taken from the i386 version by Russell King
 * Written by Martin Mares <[e-mail]>
 */
OUTPUT_ARCH(arm)
ENTRY(stext)

jiffies = jiffies_64;



SECTIONS
{
        . = 0xC0008000;
        .init : { /* Init code and data		*/
                _stext = .;
                __init_begin = .;
                        _sinittext = .;
                        *(.init.text)
                        _einittext = .;
                __proc_info_begin = .;
                        *(.proc.info)
                __proc_info_end = .;
                __arch_info_begin = .;
                        *(.arch.info)
                __arch_info_end = .;
                __tagtable_begin = .;
                        *(.taglist)
                __tagtable_end = .;
                        *(.init.data)
                . = ALIGN(16);
                __setup_start = .;
                        *(.init.setup)
                __setup_end = .;
                __early_begin = .;
                        *(__early_param)
                __early_end = .;
                __start___param = .;
                        *(__param)
                __stop___param = .;
                __initcall_start = .;
                        *(.initcall1.init)
                        *(.initcall2.init)
                        *(.initcall3.init)
                        *(.initcall4.init)
                        *(.initcall5.init)
                        *(.initcall6.init)
                        *(.initcall7.init)
                __initcall_end = .;
                __con_initcall_start = .;
                        *(.con_initcall.init)
                __con_initcall_end = .;
                __security_initcall_start = .;
                        *(.security_initcall.init)
                __security_initcall_end = .;
                . = ALIGN(32);
                __initramfs_start = .;
                        usr/built-in.o(.init.ramfs)
                __initramfs_end = .;
                . = ALIGN(4096);
                __init_end = .;
        }

        /DISCARD/ : { /* Exit code and data		*/
                *(.exit.text)
                *(.exit.data)
                *(.exitcall.exit)
        }

        .text : { /* Real text segment		*/
                _text = .; /* Text and read-only data	*/
                        *(.text)
                        __sched_text_start = .; *(.sched.text) __sched_text_end = .;
                        *(.fixup)
                        *(.gnu.warning)
                        *(.rodata)
                        *(.rodata.*)
                        *(.glue_7)
                        *(.glue_7t)
                *(.got) /* Global offset table		*/

                _etext = .; /* End of text section		*/
        }

        . = ALIGN(16);
        __ex_table : { /* Exception table		*/
                __start___ex_table = .;
                        *(__ex_table)
                __stop___ex_table = .;
        }

        .rodata : AT(ADDR(.rodata) - 0) { *(.rodata) *(.rodata.*) *(__vermagic) } .rodata1 : AT(ADDR(.rodata1) - 0) { *(.rodata1) } __ksymtab : AT(ADDR(__ksymtab) - 0) { __start___ksymtab = .; *(__ksymtab) __stop___ksymtab = .; } __ksymtab_gpl : AT(ADDR(__ksymtab_gpl) - 0) { __start___ksymtab_gpl = .; *(__ksymtab_gpl) __stop___ksymtab_gpl = .; } __kcrctab : AT(ADDR(__kcrctab) - 0) { __start___kcrctab = .; *(__kcrctab) __stop___kcrctab = .; } __kcrctab_gpl : AT(ADDR(__kcrctab_gpl) - 0) { __start___kcrctab_gpl = .; *(__kcrctab_gpl) __stop___kcrctab_gpl = .; } __ksymtab_strings : AT(ADDR(__ksymtab_strings) - 0) { *(__ksymtab_strings) }

        . = ALIGN(8192);

        .data : {
                /*
		 * first, the init task union, aligned
		 * to an 8192 byte boundary.
		 */
                *(.init.task)

                . = ALIGN(4096);
                __nosave_begin = .;
                *(.data.nosave)
                . = ALIGN(4096);
                __nosave_end = .;

                /*
		 * then the cacheline aligned data
		 */
                . = ALIGN(32);
                *(.data.cacheline_aligned)

                /*
		 * and the usual data section
		 */
                *(.data)
                CONSTRUCTORS

                _edata = .;
        }

        .bss : {
                __bss_start = .; /* BSS				*/
                *(.bss)
                *(COMMON)
                _end = . ;
        }
                                        /* Stabs debugging sections.	*/
        .stab 0 : { *(.stab) }
        .stabstr 0 : { *(.stabstr) }
        .stab.excl 0 : { *(.stab.excl) }
        .stab.exclstr 0 : { *(.stab.exclstr) }
        .stab.index 0 : { *(.stab.index) }
        .stab.indexstr 0 : { *(.stab.indexstr) }
        .comment 0 : { *(.comment) }
}