article.asp

WAPmo手机网站管理平台是一款创建与管理维护WAP网站的的软件产品

<%
Class ImplMocomWAPmoWAPBbsArticle
Private lngForumId, lngArtId
Private intPageNo, intPageId
Private objCmd

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    MyXML.Align = "center"
    MyXML.Println MyKernel.Config("BBSTitle")
    MyXML.Align = "left"
    lngForumId = atol(MyIO.QueryString("ForumId"))
    lngArtId = atol(MyIO.QueryString("ArticleId"))
    intPageNo = atoi(MyIO.QueryString("PageNo"))
    intPageId = atoi(MyIO.QueryString("PageId"))
    If MyKernel.Config("IsBBS") <> "1" Then
        MyXML.Println "该功能已被站长关闭"
    ElseIf lngForumId < 1 Then
        MyRedirect "bbs/index.asp"
    ElseIf lngArtId < 1 Then
        MyRedirect "bbs/forum.asp?ForumId=" & lngForumId
    ElseIf MyIO.Env("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
    MyXML.Println MyXML.CreateA("bbs/index.asp", "返回" & MyKernel.Config("BBSTitle"), GetImagePrefix("images/back.gif"), "")
    Call BackHomeX(BBS_SEQID)
    Call SetLog("bbs", 0)
    Call MyKernel.OutputXML(Empty)
End Sub

Private Sub doGet()
    Set objCmd = MyKernel.Command(T_ARTICLE)
    objCmd.CommandType = "SELECT"
    objCmd.Where = "FORUMID=" & lngForumId & " AND SEQID=" & lngArtId
    If Not objCmd.Exec Then
        MyXML.Println "找不到您要访问的帖子"
    Else
        objCmd("Hit") = objCmd("Hit") + 1
        objCmd.CommandType = "UPDATE"
        objCmd.Where = "SEQID=" & lngArtId
        objCmd.Add "Hit", objCmd("Hit")
        objCmd.Exec
        MyXML.Println "[" & objCmd("ForumName") & "]"
        MyXML.Printf MyXML.CreateA("bbs/post.asp?ForumId=" & lngForumId & "&PageNo=" & intPageNo, "我要发帖", "", "")
        MyXML.Printf " "
        MyXML.Println MyXML.CreateA("bbs/post.asp?ForumId=" & lngForumId & "&PageNo=" & intPageNo & "&ArticleId=" & lngArtId & "&PageId=" & intPageId, "我要回帖", "", "")
        MyXML.Println "标题：" & objCmd("Title")
        If intPageId < 2 Then
            MyXML.Println "内容：" & objCmd("Content")
            If Not ValidCoop() And MyKernel.Config("IsMsgbox") = "1" Then
                MyXML.Printf "作者："
                MyXML.Println MyXML.CreateA(GetMsgSendURL(objCmd("UserId")), objCmd("UserName"), "", "")
            Else
                MyXML.Println "作者：" & objCmd("UserName")
            End If
            MyXML.Println "时间：" & FormatTime(objCmd("Intime"), "Y-m-d H:i:s")
        End If
        Call doGetArticle
        MyXML.Println String(16, "-")
        MyXML.Println MyXML.CreateA("bbs/forum.asp?ForumId=" & lngForumId & "&PageNo=" & intPageNo, "返回" & objCmd("ForumName"), GetImagePrefix("images/back.gif"), "")
    End If
    Set objCmd = Nothing
End Sub

Private Sub doPost()
End Sub

Private Sub doGetArticle()
    Dim objPage, xmlNode
    Dim i
    Dim arr1, arr2
    Set objPage = vbsre.mocom.WAPmo.Page.newInstance()
    objPage.ID = atol(MyIO.QueryString("PageId"))
    objPage.Size = 10
    objPage.DataType = WM_DataType
    objPage.Table = T_ARTICLE
    objPage.Where = "FORUMID=" & lngForumId & " AND FOLLOW=" & lngArtId
    objPage.Count = objCmd("Reply")
    objPage.Index = "SEQID"
    objPage.Sort = "SEQID ASC"
    objPage.SortType = 0
    objPage.Build "arts", "art"
    If objPage.Rows.hasChildNodes Then
        i = 0
        For Each xmlNode In objPage.Rows.childNodes
            MyXML.Println String(16, "-")
            MyXML.Println "跟帖：" & XMLAttr(xmlNode, "content")
            If Not ValidCoop() And MyKernel.Config("IsMsgbox") = "1" Then
                MyXML.Printf "作者："
                MyXML.Println MyXML.CreateA(GetMsgSendURL(XMLAttr(xmlNode, "userid")), XMLAttr(xmlNode, "username"), "", "")
            Else
                MyXML.Println "作者：" & XMLAttr(xmlNode, "username")
            End If
            MyXML.Println "时间：" & FormatTime(XMLAttr(xmlNode, "intime"), "Y-m-d H:i:s")
            i = i + 1
        Next
        MyXML.Println ""
        arr1 = Array("ForumId", "PageNo", "ArticleId", "PageId")
        arr2 = Array(lngForumId, intPageNo, lngArtId, 0)
        If objPage.ID < objPage.Total Then
            arr2(3) = (objPage.ID + 1)
            MyXML.Printf MyXML.CreateA(GetURL("bbs/article.asp", arr1, arr2), "下一页", "", "")
            MyXML.Printf "|"
            arr2(3) = objPage.Total
            MyXML.Println MyXML.CreateA(GetURL("bbs/article.asp", arr1, arr2), "最末页", "", "")
        End If
        If objPage.ID > 1 Then
            arr2(3) = (objPage.ID - 1)
            MyXML.Printf MyXML.CreateA(GetURL("bbs/article.asp", arr1, arr2), "上一页", "", "")
            MyXML.Printf "|"
            arr2(3) = 1
            MyXML.Println MyXML.CreateA(GetURL("bbs/article.asp", arr1, arr2), "第一页", "", "")
        End If
        If objPage.Total > 2 Then
            MyXML.SetF GetPathName("bbs/article.asp"), "get", "", True
            Call SetQuery
            MyXML.SetN "ForumId", "hidden", lngForumId, "", "", False, 0, 0, ""
            MyXML.SetN "PageNo", "hidden", intPageNo, "", "", False, 0, 0, ""
            MyXML.SetN "ArticleId", "hidden", lngArtId, "", "", False, 0, 0, ""
            MyXML.SetN "PageId", "text", "", objPage.ID & "/" & objPage.Total & "页>>跳到", "页", False, 5, 5, "*N"
            MyXML.SetN "", "submit", "GO", "", "", True, 0, 0, ""
        End If
    End If
    Set objPage = Nothing
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPBbsArticle
End Function
End Class
%>