console.asp

WAPmo手机网站管理平台是一款创建与管理维护WAP网站的的软件产品

<%
Class ImplMocomWAPmoWAPConsole
Private strHandle
Private blnError
Private strError

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
    strHandle = MyIO.QueryString("Handle")
    blnError = True
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    MyXML.Align = "center"
    MyXML.Println "我的控制台"
    MyXML.Align = "left"
    If IsGuest() Then
        Call RegisterHint("只有注册用户才能使用控制台")
    ElseIf MyIO.Env("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
    Call BackHome
    Call SetLog("console", 0)
    Call MyKernel.OutputXML(Empty)
End Sub

Private Sub doGet()
    Select Case LCase(strHandle)
    Case "info"
        Call doGetInfo
    Case "modify"
        Call doGetModify
    Case "password"
        Call doGetPassword
    Case "publish"
        Call doGetPublish
    Case "publish.modify"
        Call doGetPublishModify
    Case Else
        Call doGetMain
    End Select
End Sub

Private Sub doPost()
    Select Case LCase(strHandle)
    Case "modify"
        Call doPostModify
    Case "password"
        Call doPostPassword
    Case "publish.modify"
        Call doPostPublishModify
    Case Else
        Call doGetMain
    End Select
End Sub

Private Sub doGetInfo()
    MyXML.Println "[我的基本资料]"
    MyXML.Println String(16, "-")
    MyXML.Println "昵称：" & MyKernel.Memory("UserName")
    MyXML.Println "真实姓名：" & MyKernel.Memory("RealName")
    MyXML.Println "手机号码：" & IIf(ValidMobile(MyKernel.Memory("Mobile")), MyKernel.Memory("Mobile"), "")
    MyXML.Println "注册时间：" & FormatTime(MyKernel.Memory("RegTime"), "Y-m-d H:i:s")
    MyXML.Println "终端名称：" & MyKernel.Memory("FirstUserAgent")
    MyXML.Println MyXML.CreateA("console.asp?Handle=Modify", "修改资料", "", "")
    MyXML.Println MyXML.CreateA("console.asp?Handle=Password", "修改密码", "", "")
    MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
End Sub

Private Sub doGetModify()
    MyXML.Println "[修改资料]"
    MyXML.SetF "console.asp?Handle=Modify", "post", "", True
    MyXML.SetN "UserName", "text", "", "您的昵称：", "", True, 0, 0, ""
    MyXML.SetN "Name", "text", "", "真实姓名：", "", True, 0, 0, ""
    MyXML.SetN "Mobile", "text", "", "手机号码：", "", True, 11, 0, "NNNNNNNNNNN"
    MyXML.SetN "", "submit", "确定", "", "", True, 0, 0, ""
    MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
End Sub

Private Sub doGetPassword()
    MyXML.Println "[修改密码]"
    MyXML.SetF "console.asp?Handle=Password", "post", "", True
    MyXML.SetN "Passwd", "password", "", "旧密码：", "", True, 0, 0, ""
    MyXML.SetN "NewPwd", "password", "", "新密码：", " 区分大小写，最少６位", True, 0, 0, ""
    MyXML.SetN "CfmPwd", "password", "", "确认密码：", " 再输入一遍新密码，以便确认", True, 0, 0, ""
    MyXML.SetN "", "submit", "确定", "", "", True, 0, 0, ""
    MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
End Sub

Private Sub doGetMain()
    MyXML.Println MyXML.CreateA("msgbox.asp", "我的信箱", GetImagePrefix("images/msgbox.gif"), "")
    MyXML.Println MyXML.CreateA("marker.asp", "我的书签", GetImagePrefix("images/marker.gif"), "")
    MyXML.Println MyXML.CreateA("console.asp?Handle=Info", "我的资料", GetImagePrefix("images/info.gif"), "")
    MyXML.Println MyXML.CreateA("console.asp?Handle=Publish", "我的信息", GetImagePrefix("images/publish.gif"), "")
End Sub

Private Sub doPostModify()
    MyXML.Println "[修改资料]"
    Dim strUserName, strName, strMobile
    Dim strSQL
    strUserName = Trim(MyIO.Form("UserName"))
    strName = Trim(MyIO.Form("Name"))
    strMobile = Trim(MyIO.Form("Mobile"))
    If strUserName = "" Then strUserName = MyKernel.Memory("UserName")
    If strName = "" Then strName = MyKernel.Memory("Name")
    If strMobile = "" Then strMobile = MyKernel.Memory("Mobile")
    strSQL = MyKernel.DB.GetLimitSQL(1, "SEQID", T_USER, "USERNAME='$(UserName)' AND SEQID<>$(SeqId)", "", "")
    strSQL = Replace(strSQL, "$(UserName)", SafeString(strUserName))
    strSQL = Replace(strSQL, "$(SeqId)", MyKernel.Memory("SeqId"))
    If strMobile <> "" And Not ValidMobile(strMobile) Then
        strError = "手机号码格式错误"
    ElseIf LenC(strUserName) > 20 Then
        strError = "昵称的长度不能超过20个字节（即10个汉字）"
    ElseIf Not ValidName(strUserName) Then
        strError = "请勿在昵称中使用特殊字符"
    ElseIf MyKernel.DB.HasRow(strSQL) Then
        strError = "该昵称已被占用"
    Else
        blnError = False
        strError = "资料修改成功"
        strSQL = "UPDATE $(Table) SET USERNAME='$(UserName)',USERNAME='$(Name)',MOBILE='$(Mobile)' WHERE SEQID=$(SeqId)"
        strSQL = Replace(strSQL, "$(Table)", T_USER)
        strSQL = Replace(strSQL, "$(UserName)", SafeString(strUserName))
        strSQL = Replace(strSQL, "$(Name)", SafeString(strName))
        strSQL = Replace(strSQL, "$(Mobile)", SafeString(strMobile))
        strSQL = Replace(strSQL, "$(SeqId)", MyKernel.Memory("SeqId"))
        MyKernel.DB.Exec strSQL
    End If
    MyXML.Println strError
    If blnError Then
        Call doGetModify
    Else
        MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
    End If
End Sub

Private Sub doPostPassword()
    MyXML.Println "[修改密码]"
    Dim strOld, strNew, strCfm
    Dim strSQL
    strOld = Trim(MyIO.Form("Passwd"))
    strNew = Trim(MyIO.Form("NewPwd"))
    strCfm = Trim(MyIO.Form("CfmPwd"))
    If strOld = "" Then
        strError = "请输入旧密码"
    ElseIf MyKernel.Memory("Passwd") <> MD5(strOld) Then
        strError = "旧密码错误"
    ElseIf strNew = "" Then
        strError = "请输入新密码"
    ElseIf strNew <> strCfm Then
        strError = "新密码与确认密码不符合"
    Else
        blnError = False
        strError = "密码修改成功，您的新密码是：" & strNew
        MyKernel.Memory("Passwd") = MD5(strNew)
        strSQL = "UPDATE $(Table) SET PASSWD='$(Passwd)' WHERE SEQID=$(SeqId)"
        strSQL = Replace(strSQL, "$(Table)", T_USER)
        strSQL = Replace(strSQL, "$(Passwd)", MyKernel.Memory("Passwd"))
        strSQL = Replace(strSQL, "$(SeqId)", MyKernel.Memory("SeqId"))
        MyKernel.DB.Exec strSQL
    End If
    MyXML.Println strError
    If blnError Then
        Call doGetPassword
    Else
        MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
    End If
End Sub

Private Sub doGetPublish
    MyXML.Println "[我发布的信息]"
    MyXML.Println String(16, "-")
    Dim objPage, xmlNode
    Dim rs
    Dim i
    Set objPage = vbsre.mocom.WAPmo.Page.newInstance()
    objPage.ID = atol(MyIO.QueryString("Page"))
    objPage.Size = 10
    objPage.DataType = WM_DataType
    objPage.Column = "SEQID,STAPLEID,TITLE,INTIME,EXAMINE"
    objPage.Table = T_CONTENT
    objPage.Where = "UserID=" & MyKernel.Memory("SeqID")
    objPage.Count = atol(MyKernel.Memory("ContentTotal"))
    objPage.Index = "SEQID"
    objPage.Sort = "SEQID DESC"
    objPage.SortType = 1
    objPage.Build "contents", "content"
    MyXML.Println "共发布信息" & objPage.Count & "条"
    If objPage.Rows.hasChildNodes Then
        i = 0
        For Each xmlNode In objPage.Rows.childNodes
            MyXML.Printf ((objPage.ID - 1) * objPage.Size + i + 1) & "." & XMLAttr(xmlNode, "title") & "[" & IIf(atoi(XMLAttr(xmlNode, "examine")) = "1", "已审核", "未审核") & "/"
            MyXML.Printf MyXML.CreateA(GetContentURL(XMLAttr(xmlNode, "stapleid"), 1, XMLAttr(xmlNode, "cate"), XMLAttr(xmlNode, "seqid"), XMLAttr(xmlNode, "intime"), 1), "查看", "", "")
            MyXML.Printf "/"
            MyXML.Printf MyXML.CreateA("console.asp?Handle=Publish.Modify&SeqId=" & XMLAttr(xmlNode, "seqid"), "编辑", "", "")
            MyXML.Println "]"
            i = i + 1
        Next
        If objPage.ID < objPage.Total Then
            MyXML.Printf MyXML.CreateA("console.asp?Handle=Publish&Page=" & (objPage.ID + 1), "下一页", "", "")
            MyXML.Printf "|"
            MyXML.Println MyXML.CreateA("console.asp?Handle=Publish&Page=" & (objPage.Total), "最末页", "", "")
        End If
        If objPage.ID > 1 Then
            MyXML.Printf MyXML.CreateA("console.asp?Handle=Publish&Page=" & (objPage.ID - 1), "上一页", "", "")
            MyXML.Printf "|"
            MyXML.Println MyXML.CreateA("console.asp?Handle=Publish", "第一页", "", "")
        End If
        If objPage.Total > 2 Then
            MyXML.SetF "console.asp", "get", "", True
            Call SetQuery
            MyXML.SetN "Handle", "hidden", "Publish", "", "", False, 0, 0, ""
            MyXML.SetN "Page", "text", "", objPage.ID & "/" & objPage.Total & "页>>跳到", "页", False, 5, 5, "N*"
            MyXML.SetN "", "submit", "GO", "", "", True, 0, 0, ""
        End If
    End If
    Set objPage = Nothing
    MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
End Sub

Private Sub doGetPublishModify()
    MyXML.Println "[编辑信息]"
    Dim objCmd
    Set objCmd = MyKernel.Command(T_CONTENT)
    objCmd.CommandType = "SELECT"
    objCmd.Column = "SEQID,TITLE,CONTENT"
    objCmd.Where = "SeqId=" & atol(MyIO.QueryString("SeqId")) & " AND UserID=" & MyKernel.Memory("SeqID")
    If Not objCmd.Exec Then
        MyXML.Println "未找到您要编辑的信息"
    Else
        MyXML.SetF "console.asp?Handle=Publish.Modify&SeqId=" & objCmd("SeqId"), "post", "", True
        MyXML.SetN "Title", "text", objCmd("Title"), "标题：", "", True, 0, 0, ""
        MyXML.SetN "Content", "text", objCmd("Content"), "内容：", "", True, 0, 0, ""
        MyXML.SetN "", "submit", "确定编辑", "", "", True, 0, 0, ""
    End If
    Set objCmd = Nothing
    MyXML.Println MyXML.CreateA("console.asp?Handle=Publish", "返回我的信息", GetImagePrefix("images/back.gif"), "")
    MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
End Sub

Private Sub doPostPublishModify()
    MyXML.Println "[编辑信息]"
    Dim objCmd, strSQL
    Set objCmd = MyKernel.Command(T_CONTENT)
    objCmd.CommandType = "SELECT"
    objCmd.Column = "SEQID,STAPLEID,INTIME"
    objCmd.Where = "SEQID=" & atol(MyIO.QueryString("SeqId")) & " AND USERID=" & MyKernel.Memory("SeqID")
    If objCmd.Exec Then
        Dim strTitle, strContent
        strTitle = MyIO.Form("Title")
        strContent = MyIO.Form("Content")
        If strTitle = "" Then
            MyXML.Println "编辑失败：请先输入标题"
        Else
            MyXML.Println "信息编辑成功"
            objCmd.CommandType = "UPDATE"
            objCmd.Where = "SEQID=" & objCmd("SeqId")
            objCmd.Add "Title", strTitle
            objCmd.Add "Content", strContent
            objCmd.Add "Outime", GetTime(Now())
            objCmd.Exec
            RemoveCacheZ objCmd("SeqId"), objCmd("Intime"), objCmd("StapleId")
        End If
    Else
        MyXML.Println "未找到您要编辑的信息"
    End If
    Set objCmd = Nothing
    MyXML.Println MyXML.CreateA("console.asp?Handle=Publish", "返回我的信息", GetImagePrefix("images/back.gif"), "")
    MyXML.Println MyXML.CreateA("console.asp", "返回控制台", GetImagePrefix("images/back.gif"), "")
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPConsole
End Function
End Class
%>