remark.asp

WAPmo手机网站管理平台是一款创建与管理维护WAP网站的的软件产品

<%
Class ImplMocomWAPmoWAPRemark
Private MyCore
Private strHandle
Private arr1, arr2

Private Sub Class_Initialize()
    Set MyCore = vbsre.mocom.WAPmo.WAP.Core
    Set MyXML = MyKernel.XMLParser
End Sub

Private Sub Class_Terminate()
    Set MyCore = Nothing
End Sub

Public Sub main()
    strHandle = MyIO.QueryString("Handle")
    If Not MyCore.CheckContent() Then
        MyXML.Println "找不到您要评论的内容1"
    ElseIf MyCore.Staple("Category") <> wmStapleNormal Then
        MyXML.Println "找不到您要评论的内容2"
    ElseIf MyCore.Staple("Remark") <> 1 Then
        MyXML.Println "找不到您要评论的内容3"
    ElseIf MyCore.Content("Category") <> wmContentNormal Then
        MyXML.Println "找不到您要评论的内容4"
    Else
        MyXML.Println "对[" & MyCore.Content("Title") & "]的评论"
        MyXML.Println String(16, "-")
        arr1 = Array("StapleId", "PageNo", "CateId", "ContentId", "Intime", "PageId")
        arr2 = Array(MyCore.Staple("SeqId"), MyCore.PageNo, MyCore.CateId, MyCore.Content("SeqId"), MyCore.Content("Intime"), MyCore.PageId)
        If MyIO.Env("REQUEST_METHOD") = "POST" Then
            If MyCore.Staple("RemarkType") = 0 And IsGuest() Then
                Call RegisterHint("只有注册用户才能发表评论")
            Else
                Call doPost
            End If
        Else
            Call doGet
        End If
        MyXML.Println MyXML.CreateA(GetURL("content.asp", arr1, arr2), "返回" & MyCore.Content("Title"), GetImagePrefix("images/back.gif"), "")
        MyXML.Println MyXML.CreateA(GetStapleURL(MyCore.Staple("SeqId"), MyCore.PageNo), "返回" & MyCore.Staple("Title"), GetImagePrefix("images/back.gif"), "")
    End If
    Call BackHomeX(0)
    Call SetLog("remark", 0)
    Call MyKernel.OutputXML(Empty)
End Sub

Private Sub doGet()
    Call doGetMain
    Call doGetAdd
End Sub

Private Sub doPost()
    Call doPostAdd
End Sub

Private Sub doGetMain()
    Dim objPage, xmlNode
    Dim i
    Set objPage = vbsre.mocom.WAPmo.Page.newInstance()
    objPage.ID = atol(MyIO.QueryString("Page"))
    objPage.Size = 10
    objPage.DataType = WM_DataType
    objPage.Table = T_REMARK
    objPage.Where = "ContentId=" & MyCore.Content("SeqId")
    objPage.Count = MyCore.Content("RemarkTotal")
    objPage.Index = "SEQID"
    objPage.Sort = "SEQID DESC"
    objPage.SortType = 1
    objPage.Build "remarks", "remark"
    MyXML.Println "共有评论 " & objPage.Count & " 条"
    If objPage.Rows.hasChildNodes Then
        i = 0
        For Each xmlNode In objPage.Rows.childNodes
            If atol(XMLAttr(xmlNode, "userid")) > 0 Then
                MyXML.Println "昵称：" & XMLAttr(xmlNode, "username") & "[游客]"
            ElseIf MyKernel.Config("IsMsgbox") = "1" Then
                MyXML.Printf "昵称："
                MyXML.Println MyXML.CreateA(GetMsgSendURL(XMLAttr(xmlNode, "userid")), XMLAttr(xmlNode, "username"), "", "")
            Else
                MyXML.Println "昵称：" & XMLAttr(xmlNode, "username")
            End If
            MyXML.Println "评论：" & XMLAttr(xmlNode, "content")
            MyXML.Println "时间：" & FormatTime(XMLAttr(xmlNode, "intime"), "Y-m-d H:i:s")
            MyXML.Println String(16, "-")
            i = i + 1
        Next
        If objPage.ID < objPage.Total Then
            MyXML.Printf MyXML.CreateA(GetURL("remark.asp?Page=" & (objPage.ID + 1), arr1, arr2), "下一页", "", "")
            MyXML.Printf "|"
            MyXML.Println MyXML.CreateA(GetURL("remark.asp?Page=" & objPage.Total, arr1, arr2), "最末页", "", "")
        End If
        If objPage.ID > 1 Then
            MyXML.Printf MyXML.CreateA(GetURL("remark.asp?Page=" & (objPage.ID - 1), arr1, arr2), "上一页", "", "")
            MyXML.Printf "|"
            MyXML.Println MyXML.CreateA(GetURL("remark.asp", arr1, arr2), "第一页", "", "")
        End If
        If objPage.Total > 2 Then
            MyXML.SetF "remark.asp", "get", "", True
            Call SetQuery
            MyXML.SetN "StapleId", "hidden", MyCore.Staple("SeqId"), "", "", False, 0, 0, ""
            MyXML.SetN "PageNo", "hidden", MyCore.PageNo, "", "", False, 0, 0, ""
            MyXML.SetN "CateId", "hidden", MyCore.CateId, "", "", False, 0, 0, ""
            MyXML.SetN "ContentId", "hidden", MyCore.Content("SeqId"), "", "", False, 0, 0, ""
            MyXML.SetN "Intime", "hidden", MyCore.Content("Intime"), "", "", False, 0, 0, ""
            MyXML.SetN "PageId", "hidden", MyCore.PageId, "", "", False, 0, 0, ""
            MyXML.SetN "Page", "text", "", objPage.ID & "/" & objPage.Total & "页>>跳到", "页", False, 5, 5, "N*"
            MyXML.SetN "", "submit", "GO", "", "", True, 0, 0, ""
        End If
    End If
    Set objPage = Nothing
End Sub

Private Sub doGetAdd()
    If MyCore.Staple("RemarkType") = 0 And IsGuest() Then
        Call RegisterHint("只有注册用户才能发表评论")
    Else
        MyXML.SetF GetURL("remark.asp", arr1, arr2), "post", "", True
        If IsGuest() Then
            MyXML.SetN "UserName", "text", "", "您的昵称：", "", True, 0, 0, ""
        End If
        MyXML.SetN "Content", "text", "", "您的评论：", "", True, 0, 0, ""
        MyXML.SetN "", "submit", "确定发表", "", "", True, 0, 0, ""
    End If
End Sub

Private Sub doPostAdd()
    Dim blnError
    Dim strError
    Dim strUserName
    Dim strContent
    Dim objCmd, strSQL
    Dim lngTime
    blnError = True
    strUserName = Trim(MyIO.Form("UserName"))
    strContent = Trim(MyIO.Form("Content"))
    If IsGuest() And Not ValidName(strUserName) Then
        strError = "请勿在昵称中使用特殊字符" & strUserName
    ElseIf strContent = "" Then
        strError = "请输入您的评论"
    ElseIf GetTime(Now()) - atol(MyKernel.Memory("LastRemark")) < atoi(MyKernel.Config("RemarkInterval")) Then
        strError = "感谢您的参与，请不要频繁发表评论1"
    ElseIf atoi(MyKernel.Memory("RemarkTotal")) >= atoi(MyKernel.Config("RemarkTotal")) Then
        strError = "感谢您的参与，请不要频繁发表评论2"
    Else
        blnError = False
        strError = "感谢您的评论"
        lngTime = GetTime(Now())
        If MyKernel.Memory("LastRemark") >= lngTime Then
            MyKernel.Memory("RemarkTotal") = atoi(MyKernel.Memory("RemarkTotal")) + 1
        Else
            MyKernel.Memory("RemarkTotal") = 1
        End If
        MyKernel.Memory("LastRemark") = lngTime
        Set objCmd = MyKernel.Command(T_REMARK)
        objCmd.CommandType = "INSERT"
        objCmd.Add "StapleId", MyCore.Staple("SeqId")
        objCmd.Add "ContentId", MyCore.Content("SeqId")
        objCmd.Add "Title", MyCore.Content("Title")
        objCmd.Add "Content", strContent
        If IsGuest() Then
            objCmd.Add "UserName", strUserName
            objCmd.Add "UserID", 0
        Else
            objCmd.Add "UserName", MyKernel.Memory("UserName")
            objCmd.Add "UserID", MyKernel.Memory("SeqID")
        End If
        objCmd.Add "IPAddr", MyIO.Env("REMOTE_ADDR")
        objCmd.Add "Intime", lngTime
        objCmd.Exec
        Set objCmd = Nothing
        If Not IsGuest() Then
            strSQL = "UPDATE $(Table) SET REMARKTOTAL=$(RemarkTotal),LASTREMARK=$(Timeval) WHERE SEQID=$(SeqId)"
            strSQL = Replace(strSQL, "$(Table)", T_USER)
            strSQL = Replace(strSQL, "$(RemarkTotal)", MyKernel.Memory("RemarkTotal"))
            strSQL = Replace(StrSQL, "$(Timeval)", lngTime)
            strSQL = Replace(strSQL, "$(SeqId)", MyKernel.Memory("SeqId"))
            MyKernel.DB.Exec strSQL
        End If
        strSQL = "UPDATE $(Table) SET REMARKTOTAL=$(RemarkTotal) WHERE SEQID=$(SeqId)"
        strSQL = Replace(strSQL, "$(Table)", T_CONTENT)
        strSQL = Replace(strSQL, "$(RemarkTotal)", MyCore.Content("RemarkTotal") + 1)
        strSQL = Replace(strSQL, "$(SeqId)", MyCore.Content("SeqId"))
        MyKernel.DB.Exec strSQL
        RemoveCache "content", MyCore.Content("SeqId"), MyCore.Content("Intime"), MyCore.Staple("SeqId")
    End If
    MyXML.Println strError
    If blnError Then
        Call doGetAdd
    Else
        MyXML.Println MyXML.CreateA(GetURL("remark.asp", arr1, arr2), "查看评论", "", "")
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPRemark
End Function
End Class
%>