login.asp

WAPmo手机网站管理平台是一款创建与管理维护WAP网站的的软件产品

<%
Class ImplMocomWAPmoWAPLogin
Private blnError
Private strError
Private strReferer

Private Sub Class_Initialize()
    Set MyXML = MyKernel.XMLParser
End Sub

Private Sub Class_Terminate()
End Sub

Public Sub main()
    strReferer = MyIO.QueryString("Referer")
    MyXML.Align = "center"
    MyXML.Println MyKernel.Config("SiteName") & "会员登录"
    MyXML.Align = "left"
    If MyIO.Env("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
    If strReferer <> "" Then
        MyXML.Println MyXML.CreateA(strReferer, "快速返回", GetImagePrefix("images/back.gif"), "")
    End If
    Call BackHomeX(0)
    Call SetLog("login", 0)
    Call MyKernel.OutputXML(Empty)
End Sub

Private Sub doGet()
    MyXML.SetF GetURL("login.asp", "Referer", strReferer), "post", "", True
    MyXML.SetN "UserName", "text", "", "昵称：", "", True, 0, 0, ""
    MyXML.SetN "Passwd", "password", "", "密码：", "", True, 0, 0, ""
    MyXML.SetN "", "submit", "确定", "", "", True, 0, 0, ""
    MyXML.Printf "还没有注册？"
    MyXML.Println MyXML.CreateA(GetURL("register.asp", "Referer", strReferer), "点此注册", "", "")
    MyXML.Printf "忘记密码了？"
    MyXML.Println MyXML.CreateA(GetURL("forget.asp", "Referer", strReferer), "点此取回", "", "")
End Sub

Private Sub doPost()
    Dim strUserName, strPass
    Dim objCmd, strSQL
    Dim lngTime
    strUserName = Trim(MyIO.Form("UserName"))
    strPass = Trim(MyIO.Form("Passwd"))
    Set objCmd = MyKernel.Command(T_USER)
    objCmd.CommandType = "SELECT"
    objCmd.Where = "USERNAME='" & SafeString(strUserName) & "'"
    If strUserName = "" Then
        strError = "请输入您的昵称"
    ElseIf strPass = "" Then
        strError = "请输入您的密码"
    ElseIf MyKernel.Memory("UserName") = strUserName And MyKernel.Memory("Passwd") = MD5(strPass) Then
        strError = "请勿重复登陆"
    ElseIf Not objCmd.Exec Then
        strError = "昵称或密码错误"
    ElseIf objCmd("Passwd") <> MD5(strPass) Then
        strError = "昵称或密码错误"
    Else
        blnError = False
        strError = "登录成功" & vbCrLf & _
        "现在您可以尽情使用本站提供的服务了！" & vbCrLf & _
        "友情提示：返回首页后，把首页加入手机书签，以后通过书签访问本站即可快速进入"
        lngTime = GetTime(Now())
        objCmd("LastLogin") = lngTime
        objCmd("LastVisitIP") = MyIO.Env("REMOTE_ADDR")
        objCmd("LastVisitTime") = lngTime
        objCmd("LastUserAgent") = MyIO.Env("HTTP_USER_AGENT")
        objCmd.CommandType = "UPDATE"
        objCmd.Where = "SEQID=" & objCmd("SeqId")
        objCmd.Add "LastLogin", objCmd("LastLogin")
        objCmd.Add "LastVisitIP", objCmd("LastVisitIP")
        objCmd.Add "LastVisitTime", objCmd("LastVisitTime")
        objCmd.Add "LastUserAgent", objCmd("LastUserAgent")
        objCmd.Exec
        Call AsyncMemory(objCmd)
        If AddOnline(objCmd("SeqID"), strUserName, lngTime) Then
            Call SetUserStat(stOnlineUser & "|" & stVisitToday, 1)
        End If
    End IF
    Set objCmd = Nothing
    MyXML.Println strError
    If blnError Then
        Call doGet
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoWAPLogin
End Function
End Class
%>