manager.asp

WAPmo手机网站管理平台是一款创建与管理维护WAP网站的的软件产品

        blnRedirect = True
        Session("Compact") = "YES"
    End If
    MyKernel.Config("Protect") = 0
    ExportHead "压缩数据库"
    MyIO.Echo "<script language=""javascript"">"
    MyIO.Echo "function myload()"
    MyIO.Echo "{"
    If blnRedirect Then
        MyIO.Echo "location.replace(""admin_manager.asp?Handle=Compact&Path=" & MyIO.URLEncode(strPath) & """);"
    Else
        MyIO.Echo "MessageBox.show(" & IIf(blnError = False, "MSG_HINT", "MSG_WARNING") & ", """ & strError & """);"
        MyIO.Echo "MessageBox.doAccept(function()"
        MyIO.Echo "{"
        MyIO.Echo "location.replace(""admin_manager.asp?Handle=Space"");"
        MyIO.Echo "}, true);"
    End If
    MyIO.Echo "}"
    MyIO.Echo "</script>"
    ExportFoot
End Sub

Private Sub doPostAdd()
    If Not ValidAdmin() Then
        strError = "您没有添加管理员的权限"
    Else
        Dim strName, strPwd, strCfm
        Dim lngGroupId
        Dim objCmd
        strName = Trim(MyIO.Form("Name"))
        strPwd = Trim(MyIO.Form("Passwd"))
        strCfm = Trim(MyIO.Form("CfmPwd"))
        lngGroupId = atol(MyIO.Form("GroupId"))
        Set objCmd = MyKernel.Command(T_ADMIN)
        objCmd.CommandType = "SELECT"
        objCmd.Where = "NAME='" & SafeString(strName) & "'"
        If strName = "" Then
            strError = "请输入管理员帐号"
        ElseIf strPwd = "" Then
            strError = "请输入管理员密码"
        ElseIf strPwd <> strCfm Then
            strError = "管理员密码与确认密码不符"
        ElseIf MyPower.Status = 1 And lngGroupId <= 0 Then
            strError = "请先选择管理员分组"
        ElseIf objCmd.Exec Then
            strError = "该管理员帐号已被占用"
        Else
            blnError = False
            strError = "管理员添加成功"
            objCmd.CommandType = "INSERT"
            objCmd.Add "Name", strName
            objCmd.Add "Passwd", MD5(strPwd)
            If MyPower.Status = 1 Then
                objCmd.Add "GroupId", lngGroupId
                objCmd.Add "TeamId", 0
                objCmd.Add "Follow", 0
            Else
                objCmd.Add "GroupId", MyAdmin("GroupId")
                objCmd.Add "TeamId", lngGroupId
                objCmd.Add "Follow", MyAdmin("SeqId")
            End If
            objCmd.Add "LoginCount", 0
            objCmd.Add "Intime", GetTime(Now())
            objCmd.Exec
            WM_SetCache "group"
        End If
        Set objCmd = Nothing
    End If
    ExportHead "添加管理员"
    MyIO.Echo "<script language=""javascript"">"
    MyIO.Echo "function myload()"
    MyIO.Echo "{"
    MyIO.Echo "var prt = window.parent;"
    MyIO.Echo "var frm = prt.document.getElementById(""frmMain"");"
    If Not blnError Then
        MyIO.Echo "prt.opt.cache[0] = null;"
        MyIO.Echo "prt.MessageBox.show(MSG_HINT, """ & strError & """);"
    Else
        MyIO.Echo "prt.MessageBox.show(MSG_WARNING, """ & strError & """);"
    End If
    MyIO.Echo "frm.btnPost.disabled = false;"
    MyIO.Echo "}"
    MyIO.Echo "</script>"
    ExportFoot
End Sub

Private Sub doPostPassword()
    If MyPower("ChangePassword") = 0 Then
        strError = "您没有修改密码的权限"
    Else
        Dim strOld, strNew, strCfm
        Dim objCmd, objCookie
        strOld = Trim(MyIO.Form("OldPwd"))
        strNew = Trim(MyIO.Form("NewPwd"))
        strCfm = Trim(MyIO.Form("NewCfm"))
        If strOld = "" Then
            strError = "请输入旧密码"
        ElseIf strNew = "" Then
            strError = "请输入新密码"
        ElseIf MyAdmin("Passwd") <> MD5(strOld) Then
            strError = "旧密码错误"
        ElseIf strNew <> strCfm Then
            strError = "新密码与确认密码不符"
        Else
            Set objCmd = MyKernel.Command(T_ADMIN)
            objCmd.CommandType = "UPDATE"
            objCmd.Where = "SEQID=" & MyAdmin("SeqId")
            objCmd.Add "Passwd", MD5(strNew)
            objCmd.Exec
            Set objCookie = vbsre.mocom.util.Cookie
            objCookie("WM_Admin")("Passwd") = strNew
            Set objCookie = Nothing
            blnError = False
            strError = "密码修改成功<br/>新密码为：" & strNew
        End If
    End If
    ExportHead "修改密码"
    MyIO.Echo "<script language=""javascript"">"
    MyIO.Echo "function myload()"
    MyIO.Echo "{"
    MyIO.Echo "var prt = window.parent;"
    If Not blnError Then
        MyIO.Echo "prt.MessageBox.show(MSG_HINT, """ & strError & """);"
    Else
        MyIO.Echo "prt.MessageBox.show(MSG_WARNING, """ & strError & """);"
    End If
    MyIO.Echo "prt.document.getElementById(""frmMain"").btnPost.disabled = false;"
    MyIO.Echo "}"
    MyIO.Echo "</script>"
    ExportFoot
End Sub

Private Sub doPostChange()
    If Not ValidAdmin() Then
        MyIO.Echo "您没有编辑管理员的权限"
    Else
        Dim intType
        Dim arr
        intType = atoi(MyIO.Form("Type"))
        arr = Trim(MyIO.Form("SeqId"))
        If Not IsNumericArray(arr) Then
            MyIO.Echo "请选择您要编辑的管理员"
        Else
            If MyPower.Status = 0 Then
                strSQL = "SELECT A.SEQID,A.FORBID,B.Power AS Power FROM $(TableA) A,$(TableB) B WHERE A.FOLLOW=$(Follow) AND A.SeqId IN ($(SeqId)) AND A.GroupId=B.SeqId"
                strSQL = Replace(strSQL, "$(Follow)", MyAdmin("SeqId"))
            Else
                strSQL = "SELECT A.SEQID,A.FORBID,B.Power AS Power FROM $(TableA) A,$(TableB) B WHERE A.SeqId IN ($(SeqId)) AND A.GroupId=B.SeqId"
            End If
            strSQL = Replace(strSQL, "$(TableA)", T_ADMIN)
            strSQL = Replace(strSQL, "$(TableB)", T_ADMIN_GROUP)
            strSQL = Replace(strSQL, "$(SeqId)", Join(arr, ","))
            Set rs = MyKernel.DB.Query(strSQL, adOpenKeyset, adLockOptimistic, adCmdText)
            If rs.EOF Then
                MyIO.Echo "找不到您要编辑的管理员或者您没有编辑该管理员的权限"
            Else
                Do While Not rs.EOF
                    If rs("SeqId") <> MyAdmin("SeqId") Then
                        rs("Forbid") = IIf(intType = 0, 1, 0)
                        rs.Update
                    End If
                    rs.MoveNext
                Loop
                MyIO.Echo "OK"
            End If
            rs.Close
            Set rs = Nothing
        End If
    End If
End Sub

Private Sub doPostRemove()
    If Not ValidAdmin() Then
        MyIO.Echo "您没有删除管理员的权限"
    Else
        Dim arr
        arr = Split(MyIO.Form("SeqId"), ",")
        If Not IsNumericArray(arr) Then
            MyIO.Echo "请选择您要删除的管理员"
        ElseIf InArray(arr, MyAdmin("SeqId"), True) Then
            MyIO.Echo "不能删除自身"
        Else
            If MyPower.Status = 0 Then
                strSQL = "DELETE FROM $(Table) WHERE FOLLOW=$(Follow) AND SeqId IN ($(SeqId))"
                strSQL = Replace(strSQL, "$(Follow)", MyAdmin("SeqId"))
            Else
                strSQL = "DELETE FROM $(Table) WHERE SeqId IN ($(SeqId))"
            End If
            strSQL = Replace(strSQL, "$(Table)", T_ADMIN)
            strSQL = Replace(strSQL, "$(SeqId)", Join(arr, ","))
            MyKernel.DB.Exec strSQL
            MyIO.Echo "OK"
        End If
    End If
End Sub

Private Sub doPostModify()
    Dim objCmd
    Dim lngId
    Dim strPwd, strCfm
    Dim lngGroupId
    lngId = atol(MyIO.QueryString("SeqId"))
    strPwd = Trim(MyIO.Form("Passwd"))
    strCfm = Trim(MyIO.Form("CfmPwd"))
    lngGroupId = atol(MyIO.Form("GroupId"))
    Set objCmd = MyKernel.Command(T_ADMIN)
    objCmd.CommandType = "SELECT"
    If MyPower.Status = 0 Then
        strSQL = "SEQID=$(SeqId) AND FOLLOW=$(Follow)"
        strSQL = Replace(strSQL, "$(Follow)", MyAdmin("SeqId"))
    Else
        strSQL = "SEQID=$(SeqId)"
    End If
    strSQL = Replace(strSQL, "$(Table)", T_ADMIN)
    strSQL = Replace(strSQL, "$(SeqId)", lngId)
    objCmd.Where = strSQL
    If Not ValidAdmin() Then
        strError = "您没有编辑管理员的权限"
    ElseIf lngId <= 0 Then
        strError = "请选择您要编辑的管理员"
    ElseIf strPwd <> "" And strPwd <> strCfm Then
        strError = "管理员密码与确认密码不符"
    ElseIf MyPower.Status = 1 And lngGroupId <= 0 Then
        strError = "请先选择管理员分组"
    ElseIf Not objCmd.Exec Then
        strError = "找不到您要编辑的管理员或者您没有编辑该管理员的权限"
    ElseIf objCmd("SeqId") = MyAdmin("SeqId") Then
        strError = "不能编辑自身"
    Else
        blnError = False
        strError = "管理员编辑成功"
        objCmd.CommandType = "UPDATE"
        objCmd.Where = "SEQID=" & objCmd("SeqId")
        If strPwd <> "" Then
            objCmd.Add "Passwd", MD5(strPwd)
        End If
        If MyPower.Status = 1 Then
            objCmd.Add "GroupId", lngGroupId
        Else
            objCmd.Add "TeamId", lngGroupId
        End If
        objCmd.Exec
    End If
    Set objCmd = Nothing
    ExportHead "编辑管理员"
    MyIO.Echo "<script language=""javascript"">"
    MyIO.Echo "function myload()"
    MyIO.Echo "{"
    MyIO.Echo "var prt = window.parent;"
    If Not blnError Then
        MyIO.Echo "prt.MessageBox.show(MSG_HINT, """ & strError & """);"
    Else
        MyIO.Echo "prt.MessageBox.show(MSG_WARNING, """ & strError & """);"
    End If
    MyIO.Echo "prt.document.getElementById(""frmMain"").btnPost.disabled = false;"
    MyIO.Echo "}"
    MyIO.Echo "</script>"
    ExportFoot
End Sub