📄 msgbox.asp

📁 WAPmo手机网站管理平台是一款创建与管理维护WAP网站的的软件产品
💻 ASP
字号:
<%
Class ImplMocomWAPmoManagerMsgbox
Private blnError
Private strError
Private objPage
Private rs, strSQL

Private Sub Class_Initialize()
    blnError = True
    strError = "无错误"
End Sub

Public Sub main()
    If MyIO.Env("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
End Sub

Private Sub doGet()
    Select Case LCase(MyIO.QueryString("Handle"))
    Case "list"
        Call doGetList
    Case "option"
        Call doGetOption
    Case Else
        Call doGetMain
    End Select
End Sub

Private Sub doPost()
    Select Case LCase(MyIO.QueryString("Handle"))
    Case "remove"
        Call doPostRemove
    Case Else
        MyIO.Echo "未知操作"
    End Select
End Sub

Private Sub doGetMain()
    MyIO.Echo "<html>"
    MyIO.Echo "<head>"
    MyIO.Echo "<meta http-equiv=""Content-Type"" content=""text/html; charset=utf-8"" />"
    MyIO.Echo "<meta http-equiv=""Cache-Control"" content=""no-cache, max-age=0"" />"
    MyIO.Echo "<title>短消息管理</title>"
    MyIO.Echo "<link rel=""stylesheet"" href=""images/xw.css"" />"
    MyIO.Echo "<script language=""javascript"" src=""jspp/jspp.js""></script>"
    MyIO.Echo "<script language=""javascript"" src=""images/wm_msg.js""></script>"
    MyIO.Echo "</head>"
    MyIO.Echo "<body style=""padding:5;margin:0;overflow:auto;border:0"">"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"" style=""border:1px solid #000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td align=""right"" bgcolor=""#A2ADC4"" style=""border-bottom:1px solid #000000;padding-right:1px;padding-top:1px"" height=""24""><img src=""images/xw_cls0.gif"" border=""0"" align=""absMiddle"" onMouseOver=""this.src='images/xw_cls1.gif'"" onMouseOut=""this.src='images/xw_cls0.gif'"" onMouseDown=""this.src='images/xw_cls2.gif'"" onMouseUp=""this.src='images/xw_cls1.gif'"" /></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""100%"" border=""0"" cellpadding=""0"" cellspacing=""0"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td height=""24"" style=""background-image:url(images/xw_back4.gif)"">&nbsp;</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td>"
    MyIO.Echo "<table width=""98%"" border=""0"" cellpadding=""0"" cellspacing=""0"" align=""center"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td id=""_OPTION"" class=""f12""></td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
    MyIO.Echo "</table>"
    MyIO.Echo "<iframe id=""console"" name=""console"" frameborder=""0"" scrolling=""no"" width=""0"" height=""0"" style=""display:none""></iframe>"
    MyIO.Echo "</body>"
    MyIO.Echo "</html>"
End Sub

Private Sub doGetOption()
    Select Case MyIO.QueryString("Option")
    Case "0"
        MyIO.Echo "<form id=""frmMain"" onsubmit=""return(false)"">"
        MyIO.Echo "<table width=""100%"" border=""1"" cellpadding=""2"" cellspacing=""0"" align=""center"" style=""border-collapse:collapse"" bordercolor=""#000000"">"
        MyIO.Echo "<tr>"
        MyIO.Echo "<td colspan=""2"" class=""winT0"">"
        MyIO.Echo " <b>所有短信息</b>"
        MyIO.Echo " <a href=""javascript:void(0)"" class=""a1"" onclick=""jspp.Msg.doPage(jspp.Msg.page)"">刷新短信息列表</a>"
        MyIO.Echo "</td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "<tr class=""winT1"">"
        MyIO.Echo "<td colspan=""2"" id=""_list_""></td>"
        MyIO.Echo "</tr>"
        MyIO.Echo "</table>"
        MyIO.Echo "</form>"
    Case Else
        MyIO.Echo "未知选项"
    End Select
End Sub

Private Sub doGetList()
    Dim i
    Dim strKey
    Dim xmlNode
    strKey = Trim(MyIO.QueryString("Keyword"))
    Set objPage = vbsre.mocom.WAPmo.Page.newInstance()

    objPage.ID = atol(MyIO.QueryString("Page"))
    objPage.Size = 20
    objPage.DataType = WM_DataType
    objPage.Table = T_MSGBOX
    If strKey <> "" Then
        objPage.Where = Replace("SENDER LIKE '%$(Keyword)%' OR SENDTO LIKE '%$(Keyword)%'", "$(Keyword)", SafeString(strKey))
    End If
    objPage.Count = GetPageCount(objPage)
    objPage.Index = "SEQID"
    objPage.Sort = "SEQID DESC"
    objPage.SortType = 1
    objPage.Build "msgs", "msg"

    MyIO.Echo "<table width=""100%"" border=""1"" cellpadding=""2"" cellspacing=""0"" align=""center"" style=""border-collapse:collapse;word-break:break-all;word-wrap:break-word;"" bordercolor=""#000000"">"
    MyIO.Echo "<tr>"
    MyIO.Echo "<td width=""8%"" class=""winT0""><b>选择</b></td>"
    MyIO.Echo "<td width=""10%"" class=""winT0""><b>发件人<b/></td>"
    MyIO.Echo "<td width=""10%"" class=""winT0""><b>收件人<b/></td>"
    MyIO.Echo "<td width=""50%"" class=""winT0""><b>短信息<b/></td>"
    MyIO.Echo "<td width=""14%"" class=""winT0""><b>时间<b/></td>"
    MyIO.Echo "<td width=""8%"" class=""winT0""><b>管理</b></td>"
    MyIO.Echo "</tr>"
    If objPage.Rows.hasChildNodes Then
        i = 0
        For Each xmlNode In objPage.Rows.childNodes
            MyIO.Echo "<tr class=""winT1"">"
            MyIO.Echo "<td align=""center""><input type=""checkbox"" id=""SeqId"" name=""SeqId"" value=""" & XMLAttr(xmlNode, "seqid") & """ /></td>"
            If atol(XMLAttr(xmlNode, "sender")) = 0 Then
                MyIO.Echo "<td>站长</td>"
            Else
                MyIO.Echo "<td><a href=""javascript:void(0)"" onclick=""getUserDetail(" & XMLAttr(xmlNode, "sender") & ")"">" & MyIO.HTMLEncode(XMLAttr(xmlNode, "sendername")) & "</a></td>"
            End If
            If atol(XMLAttr(xmlNode, "sendto")) = 0 Then
                MyIO.Echo "<td>所有用户</td>"
            Else
                MyIO.Echo "<td><a href=""javascript:void(0)"" onclick=""getUserDetail(" & XMLAttr(xmlNode, "sendto") & ")"">" & MyIO.HTMLEncode(XMLAttr(xmlNode, "sendtoname")) & "</a></td>"
            End If
            MyIO.Echo "<td>" & MyIO.HTMLEncode(XMLAttr(xmlNode, "title")) & "</td>"
            MyIO.Echo "<td align=""right"">" & FormatTime(XMLAttr(xmlNode, "intime"), "y-m-d H:i") & "</td>"
            MyIO.Echo "<td align=""center"">"
            MyIO.Echo "<select class=""sel"" onchange=""jspp.Msg.control(this, " & XMLAttr(xmlNode, "seqid") & ")"">"
            MyIO.Echo "<option value=""0"">管理</option>"
            MyIO.Echo "<option value=""1"">删除</option>"
            MyIO.Echo "</select>"
            MyIO.Echo "</td>"
            MyIO.Echo "</tr>"
            i = i + 1
        Next
        Call ShowControl
        Call ShowPage
    Else
        MyIO.Echo "<tr class=""winT4"">"
        MyIO.Echo "<td colspan=""6"">尚无任何短信息</td>"
        MyIO.Echo "</tr>"
        Call ShowControl
    End If
    MyIO.Echo "</table>"
    Set objPage = Nothing
End Sub

Private Sub ShowControl()
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td align=""center""><input type=""checkbox"" onclick=""chkAll(this)"" /></td>"
    MyIO.Echo "<td colspan=""5"">"
    MyIO.Echo " <input type=""button"" class=""btn"" value=""删除"" onclick=""jspp.Msg.removeAll(this.form)"" />"
    MyIO.Echo " <input type=""button"" class=""btn"" value=""搜索"" onclick=""jspp.Msg.query(this.form)"" />"
    MyIO.Echo " <input name=""Keyword"" type=""text"" class=""txt"" value=""" & MyIO.HTMLEncode(MyIO.QueryString("Keyword")) & """ />"
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
End Sub

Private Sub ShowPage()
    MyIO.Echo "<tr class=""winT4"">"
    MyIO.Echo "<td colspan=""7"" align=""right"">"
    MyIO.Echo "共 " & objPage.Count & " 条信息 "
    MyIO.Echo objPage.Size & " 条/页 "
    MyIO.Echo objPage.ID & "/" & objPage.Total & " 页"
    If objPage.ID > 1 Then
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Msg.doPage(1)"" class=""a1"" />首  页</a>"
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Msg.doPage(" & (objPage.ID - 1) & ")"" class=""a1"" />上一页</a>"
    Else
        MyIO.Echo " <a class=""a1"">首  页</a>"
        MyIO.Echo " <a class=""a1"">上一页</a>"
    End If
    If objPage.ID < objPage.Total Then
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Msg.doPage(" & (objPage.ID + 1) & ")"" class=""a1"" />下一页</a>"
        MyIO.Echo " <a href=""javascript:void(0)"" onclick=""jspp.Msg.doPage(" & objPage.Total & ")"" class=""a1"" />尾  页</a>"
    Else
        MyIO.Echo " <a class=""a1"">下一页</a>"
        MyIO.Echo " <a class=""a1"">尾  页</a>"
    End If
    MyIO.Echo "</td>"
    MyIO.Echo "</tr>"
End Sub

Private Sub doPostRemove()
    If MyPower("DeleteRemark") = 0 Then
        MyIO.Echo "您没有删除短信息的权限"
    Else
        Dim arr
        Dim blnUpdate, blnDelete
        Dim xmlDoc, xmlNode
        arr = Split(MyIO.Form("SeqId"), ",")
        If Not IsNumericArray(arr) Then
            MyIO.Echo "请选择您要删除的短消息"
        Else
            strSQL = "SELECT * FROM $(Table) WHERE SEQID IN ($(SeqId))"
            strSQL = Replace(strSQL, "$(Table)", T_MSGBOX)
            strSQL = Replace(strSQL, "$(SeqId)", Join(arr, ","))
            Set xmlDoc = MyKernel.DB.SQLToXML(strSQL, "msgs", "msg")
            If Not xmlDoc.documentElement.hasChildNodes Then
                MyIO.Echo "找不到您要删除的短消息"
            Else
                MyKernel.DB.Exec str_format("DELETE FROM $0 WHERE SEQID IN ($1)", Array(T_MSGBOX, Join(arr, ",")))
                For Each xmlNode In xmlDoc.documentElement.childNodes
                    If atol(XMLAttr(xmlNode, "sender")) > 0 Then
                        strSQL = "UPDATE $(Table) SET MSGSEND=MSGSEND-1 WHERE SEQID=$(SeqID)"
                        strSQL = Replace(strSQL, "$(Table)", T_USER)
                        strSQL = Replace(strSQL, "$(SeqID)", XMLAttr(xmlNode, "sender"))
                        MyKernel.DB.Exec strSQL
                    ElseIf atol(XMLAttr(xmlNode, "sendto")) > 0 Then
                        If atoi(XMLAttr(xmlNode, "status")) = 0 Then
                            strSQL = "UPDATE $(Table) SET MSGRECV=MSGRECV-1,MSGNEW=MSGNEW-1 WHERE SEQID=$(SeqID)"
                        Else
                            strSQL = "UPDATE $(Table) SET MSGRECV=MSGRECV-1 WHERE SEQID=$(SeqID)"
                        End If
                        strSQL = Replace(strSQL, "$(Table)", T_USER)
                        strSQL = Replace(strSQL, "$(SeqID)", XMLAttr(xmlNode, "sendto"))
                        MyKernel.DB.Exec strSQL
                    Else
                        blnUpdate = True
                    End If
                Next
                If blnUpdate Then
                    SetCache "WAPmo.MsgCount", atol(MyKernel.DB.GetRow("SELECT COUNT(SeqId) FROM " & T_MSGBOX & " WHERE SENDER=0"))
                End If
                MyIO.Echo "OK"
            End If
            Set xmlDoc = Nothing
        End If
    End If
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoManagerMsgbox
End Function
End Class
%>
💿 文件大小 2007 K
👤 上传用户 yangjiuhe
📂 所属分类手机WAP编程
🏷️ 相关标签

#WAPmo #WAP #网站 #手机
⌨️ 快捷键说明

复制代码 Ctrl + C
搜索代码 Ctrl + F
全屏模式 F11
切换主题 Ctrl + Shift + D
显示快捷键 ?
增大字号 Ctrl + =
减小字号 Ctrl + -