remove.asp

WAPmo手机网站管理平台是一款创建与管理维护WAP网站的的软件产品

<%
Class ImplMocomWAPmoManagerRemove

Public Sub main()
    If MyIO.Env("REQUEST_METHOD") = "POST" Then
        Call doPost
    Else
        Call doGet
    End If
End Sub

Private Sub doGet()
    Dim strTarget
    Dim strName
    Dim lngID
    strTarget = LCase(MyIO.QueryString("target"))
    strName = LCase(MyIO.QueryString("name"))
    lngID = atol(MyIO.QueryString("id"))
    Select Case strTarget
    Case "site"
        If strName = "logo" Then
            ClearImage "logo"
            MyKernel.Config("SiteLogo") = ""
            MyIO.Echo "OK"
        ElseIf strName = "backimage" Then
            ClearImage "backimage"
            MyKernel.Config("BackImage") = ""
            MyIO.Echo "OK"
        ElseIf strName = "backsound" Then
            ClearFile "backsound", "AllowRing"
            MyKernel.Config("BackSound") = ""
            MyIO.Echo "OK"
        Else
            MyIO.Echo "未知操作[" & strTarget & "." & strName & "]"
        End If
    Case "staple"
        If lngID = 0 Then
            MyIO.Echo "请选择您要删除的文件"
        ElseIf strName = "icon" Then
            ClearImage "icon" & lngID
            MyKernel.DB.Exec "UPDATE " & T_STAPLE & " SET Icon='' WHERE SeqId=" & lngID
            MyIO.Echo "OK"
        ElseIf strName = "logo" Then
            ClearImage "logo" & lngID
            MyKernel.DB.Exec "UPDATE " & T_STAPLE & " SET Logo='' WHERE SeqId=" & lngID
            MyIO.Echo "OK"
        Else
            MyIO.Echo "未知操作[" & strTarget & "." & strName & "]"
        End If
    Case "matter"
        If lngID = 0 Then
            MyIO.Echo "请选择您要删除的素材"
        ElseIf strName = "jad" Or strName = "preview" Then
            DeleteOther strName, lngID
        ElseIf strName = "all" Then
            DeleteMatter lngID
        Else
            MyIO.Echo "未知操作[" & strTarget & "." & strName & "]"
        End If
    Case Else:
        MyIO.Echo "未知操作[" & strTarget & "]"
    End Select
End Sub

Private Sub doPost()
End Sub

Private Sub DeleteOther(ByVal strHandle, ByVal lngID)
    Dim objCmd
    Dim strName
    Dim strPath
    Set objCmd = MyKernel.Command(T_MATTER)
    objCmd.CommandType = "SELECT"
    objCmd.Where = "SEQID=" & atol(lngID)
    If objCmd.Exec Then
        strName = GetMatterName(objCmd("Category")) & "/" & FormatTime(objCmd("Intime"), "Ymd") & "/" & Hex(objCmd("Mark"))
        If strHandle = "jad" Then
            strPath = getMapPath("images/" & strName & ".jad")
            If fso.FileExists(strPath) Then
                fso.DeleteFile strPath
            End If
        Else
            ClearImage strName & "P"
            ClearImage strName & "F"
            ClearImage strName
            MyKernel.DB.Exec "UPDATE " & T_MATTER & " SET Preview='' WHERE SeqId=" & objCmd("SeqId")
        End If
        MyIO.Echo "OK"
    Else
        MyIO.Echo "未找不到您要删除的" & IIf(strHandle = "jad", "JAD 文件", "预览图片")
    End If
    Set objCmd = Nothing
End Sub

Private Sub DeleteMatter(ByVal lngID)
    Dim objCmd
    Dim strName, intCate
    Dim strPath
    Set objCmd = MyKernel.Command(T_MATTER)
    objCmd.CommandType = "SELECT"
    objCmd.Where = "SEQID=" & atol(lngID)
    If objCmd.Exec Then
        intCate = objCmd("Category")
        strName = GetMatterName(intCate) & "/" & FormatTime(objCmd("Intime"), "Ymd") & "/" & Hex(objCmd("Mark"))
        If intCate = wmTypeImage Then
            ClearImage strName & "D"
            ClearImage strName & "P"
            ClearImage strName & "F"
            ClearImage strName
        ElseIf intCate = wmTypeVideo Or intCate = wmTypeSoft Then
            ClearFile strName, IIf(intCate = wmTypeVideo, "AllowVideo", "AllowSoft")
            ClearImage strName & "P"
            ClearImage strName & "F"
            ClearImage strName
        Else
            ClearFile strName, "AllowRing"
        End If
        MyKernel.DB.Exec "DELETE FROM " & T_MATTER & " WHERE SEQID=" & objCmd("SeqId")
        MyKernel.DB.Exec "UPDATE " & T_CONTENT & " SET MATTER=0 WHERE MATTER=" & objCmd("Mark")
        MyIO.Echo "OK"
    Else
        MyIO.Echo "未找不到您要删除的素材"
    End If
    Set objCmd = Nothing
End Sub

Public Function newInstance()
    Set newInstance = New ImplMocomWAPmoManagerRemove
End Function
End Class
%>