scan.l

一个C语言的编译器

%{
/****************************************************************************
scan.l
ParserWizard generated Lex file.
BY:计算机科学与技术系 0610386 蒲凌君
Date: 2008年12月22日 星期一
****************************************************************************/

#include "globals.h"
#include "util.h"
#include "scan.h"
#include "parse.h"

char tokenString[MAXTOKENLEN+1];
%}

%include {
    #define MAXTOKENLEN 40

	extern char tokenString[MAXTOKENLEN+1];

	TokenType getToken(void);
}
/////////////////////////////////////////////////////////////////////////////
// declarations section

letter      [_a-zA-Z]
letnum		[_a-zA-Z0-9]
identifier  {letter}{letnum}*
digit       [0-9]
number      {digit}+
fnumber     {number}"."{number}
constchar	'.'
newline		\n
whitespace  [ \t]+

%%

/////////////////////////////////////////////////////////////////////////////
// rules section

"int"           {return INT;}
"float"         {return DOUBLE;}
"char"          {return CHAR;}
"void"          {return VOID;}
"if"            {return IF;}
"else"          {return ELSE;}
"while"         {return WHILE;}
"for"           {return FOR;}
"return"        {return RETURN;}
"input"         {return INPUT;}
"output"        {return OUTPUT;}

  
"++"            {return INC;}
"--"            {return DEC;}
"<"             {return LT;}
"<="            {return LE;}
">"             {return GT;}
">="            {return GE;}
"=="            {return EQ;}
"+"             {return PLUS;}
"-"             {return SUB;}
"*"             {return MUT;}
"/"             {return DIV;}
"%"             {return MOD;}
"!="            {return NEQ;}
"&&"            {return AND;}
"||"            {return OR;}
"!"             {return NOT;}
"<<"            {return B_LEFT;}
">>"            {return B_RIGHT;}
"~"             {return B_NOT;}
"&"             {return B_AND;}
"|"             {return B_OR;}
"^"             {return B_XOR;}
"="             {return ASSIGN;}
";"             {return SEMI;}
","             {return COMMA;}
"("             {return LP;}
")"             {return RP;}
"["             {return LSP;}
"]"             {return RSP;}
"{"             {return LFP;}
"}"             {return RFP;}
{identifier}    {return ID;}
{number}        {return NUM;}
{fnumber}       {return FNUM;}
{constchar}		{return SCHAR;}
{newline}		{lineno++;}
{whitespace}    {}
"//"			{ char c;
				  while ((c = yyinput()) != '\n')
				    if (c == EOF) return ENDFILE;
				  yyunput(c);
				}
"/*"            { char c;
                  int done = FALSE;
                  do {
                    while ((c = yyinput()) != '*')
                      if (c == EOF) return ERROR;
                    while ((c = yyinput()) == '*');
                    if (c == '/') done = TRUE;
                  } while (!done);
                }
.               {return ERROR;}



%%

/////////////////////////////////////////////////////////////////////////////
// programs section
TokenType getToken(void)
{
    static int firstTime = TRUE;
    TokenType currentToken;
    if (firstTime) {
        firstTime = FALSE;
        lineno++;
        yyin = source;
        yyout = listing;
    }
    currentToken = yylex();
    strncpy(tokenString, yytext, MAXTOKENLEN);
    if (TraceScan) {
		lineno = yylineno;
        fprintf(listing,"\t%d: ",lineno);
        printToken(currentToken,tokenString);
    }
    return currentToken;
}