idlemouse.dpr

一个朋友写的delphi的漂亮时钟

{*******************************************************}
{*            Email: [e-mail]               *}
{*               QQ: 39262884                          *}
{*******************************************************}

library IdleMouse;

uses
  Windows,
  Messages,
  IdleConst in 'IdleConst.pas';

var
  MSG_MOUSE: UINT;
  hMappingFile: THandle;
  pMapMem: PMouseMappingMem;
  mhook: HHook;
  fblocked: BOOL = True;

function MouseHookProc(iCode: Integer; wParam: WPARAM; lParam: LPARAM): LRESULT; stdcall
begin
  {WM_MOUSEMOVE, WM_NCMouseMove, WM_LBUTTONDOWN, WM_NCLBUTTONDOWN, WM_LBUTTONUP,
    WM_LBUTTONDBLCLK, WM_RBUTTONDOWN, WM_RBUTTONUP, WM_RBUTTONDBLCLK, WM_MBUTTONDOWN,
    WM_MBUTTONUP, WM_MBUTTONDBLCLK}
  case wParam of
    WM_NCMOUSEMOVE, WM_NCLBUTTONDOWN, WM_NCLBUTTONUP, WM_NCLBUTTONDBLCLK,
    WM_NCRBUTTONDOWN, WM_NCRBUTTONUP, WM_NCRBUTTONDBLCLK, WM_LBUTTONDOWN,
    WM_RBUTTONDOWN:
      begin
        pMapMem^.MsgID := MSG_MOUSE;
        pMapMem^.MouseStruct := pMOUSEHOOKSTRUCT(lparam)^;
        SendMessage(pMapMem^.Handle, pMapMem^.MsgID, 0, 0);
      end;
  end;
  Result := CallNextHookEx(mhook, iCode, wParam, lParam);
end;

function EnableMouseHook(hWindow: HWND; Blocked: BOOL): BOOL; stdcall;
begin
  Result := False;
  if mhook <> 0 then
    Exit;
  pMapMem^.Handle := hWindow;
  fblocked := Blocked;
  mhook := SetWindowsHookEx(WH_MOUSE, MouseHookProc, HInstance, 0);
  Result := mhook <> 0;
end;

function DisableMouseHook: BOOL; stdcall;
begin
  if mhook <> 0 then
  begin
    UnhookWindowshookEx(mhook);
    mhook := 0;
  end;
  Result := mhook = 0;
end;

procedure DllMain(dwReason: DWORD);
begin
  case dwReason of
    DLL_PROCESS_ATTACH:
      begin
        hMappingFile := OpenFileMapping(FILE_MAP_WRITE, False, MouseMappingFileName);
        if hMappingFile = 0 then
        begin
          hMappingFile := CreateFileMapping($FFFFFFFF, nil, PAGE_READWRITE,
            0, SizeOf(TMouseMappingMem), MouseMappingFileName);
        end;
        if hMappingFile = 0 then
          MessageBox(0, 'cannot create share memory!', 'Error', MB_OK or MB_ICONERROR);

        pMapMem := MapViewOfFile(hMappingFile, FILE_MAP_WRITE or FILE_MAP_READ,
          0, 0, 0);
        if pMapMem = nil then
        begin
          CloseHandle(hMappingFile);
          MessageBox(0, 'cannot map share memory!', 'Error', MB_OK or MB_ICONERROR);
        end;
        mhook := 0;
        MSG_MOUSE := RegisterWindowMessage(MSGMOUSE);
      end;
    DLL_PROCESS_DETACH:
      begin
        UnMapViewOfFile(pMapMem);
        CloseHandle(hMappingFile);
        if mhook <> 0 then
          DisableMouseHook;
      end;
    DLL_THREAD_ATTACH:
      begin
      end;
    DLL_THREAD_DETACH:
      begin
      end;
  end;
end;

exports
  EnableMouseHook,
  DisableMouseHook;

begin
  DisableThreadLibraryCalls(HInstance);
  DLLProc := @DLLMain;
  DLLMain(DLL_PROCESS_ATTACH);
end.