generate-java.xsl

a a a a a a a a a a a a a a a a a a a a a a

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<!-- Copyright (C) 2006 Ferdinand Prantl <[e-mail]> -->
<!-- All rights reserved. -->
<!-- -->
<!-- This work is licensed under a Creative Commons Attribution 2.5 -->
<!-- License. See the attached file LICENSE for more information. -->
<!-- See also http://creativecommons.org/licenses/by/2.5/. -->
<!-- -->
<!-- See http://domino-javadoc.sourceforge.net for the most recent version -->
<!-- and more information. -->

<xsl:param name="output-directory" select="'output/java'" />
<xsl:param name="documentation-file" select="'output/documentation.xml'" />
<xsl:param name="documentation-root" select="document($documentation-file)" />
<xsl:param name="external-examples" select="true()" />

<xsl:template match="/">
  <xsl:apply-templates select="/types/interface | /types/class" />
</xsl:template>

<xsl:template match="interface | class">
<xsl:document method="html" encoding="iso8859-1" href="{$output-directory}/{translate(@scope,'.','/')}/{@name}.java">
  <xsl:text>package lotus.domino;

import java.io.*;
import java.util.*;
import java.applet.*;
import java.lang.reflect.*;

</xsl:text>
  <xsl:variable name="name" select="@name" />
  <xsl:variable name="scope" select="@scope" />
  <xsl:apply-templates select="$documentation-root/documentation/topics/class[@name=$name and @scope=$scope]/description">
    <xsl:with-param name="type" select="'class'" />
    <xsl:with-param name="class" select="$name" />
  </xsl:apply-templates>
  <xsl:call-template name="modifiers" />
  <xsl:value-of select="name()" /><xsl:text> </xsl:text>
  <xsl:value-of select="@name" />
  <xsl:if test="@extends">
    <xsl:text> extends </xsl:text>
    <xsl:call-template name="simple-type">
      <xsl:with-param name="type" select="@extends" />
    </xsl:call-template>
  </xsl:if>
  <xsl:if test="extends">
    <xsl:text> extends</xsl:text>
    <xsl:apply-templates select="extends" />
  </xsl:if>
  <xsl:if test="implements">
    <xsl:text> implements</xsl:text>
    <xsl:apply-templates select="implements" />
  </xsl:if>
  <xsl:text> {
</xsl:text>
  <xsl:apply-templates select="field" />
  <xsl:apply-templates select="method" />
  <xsl:text>}</xsl:text>
</xsl:document>
</xsl:template>

<xsl:template match="extends | implements">
  <xsl:text> </xsl:text>
  <xsl:call-template name="simple-type">
    <xsl:with-param name="type" select="@name" />
    <xsl:with-param name="scope" select="../@scope" />
  </xsl:call-template>
  <xsl:if test="position() != last()"><xsl:text>,</xsl:text></xsl:if>
</xsl:template>

<xsl:template match="field">
  <xsl:if test="position() = 1"><xsl:text>
</xsl:text></xsl:if>
  <xsl:call-template name="modifiers" />
  <xsl:call-template name="simple-type">
    <xsl:with-param name="scope" select="../@scope" />
  </xsl:call-template>
  <xsl:call-template name="dimension" />
  <xsl:text> </xsl:text><xsl:value-of select="@name" />
  <xsl:if test="@final = 'true'">
    <xsl:text> = </xsl:text>
    <xsl:call-template name="value" />
  </xsl:if>
  <xsl:text>;
</xsl:text>
  <xsl:if test="position() = last()"><xsl:text>
</xsl:text></xsl:if>
</xsl:template>

<xsl:template match="method">
  <xsl:if test="position() = 1 and not(../field)"><xsl:text>
</xsl:text></xsl:if>
  <xsl:call-template name="member-description" />
  <xsl:call-template name="modifiers" />
  <xsl:call-template name="simple-type">
    <xsl:with-param name="scope" select="../@scope" />
  </xsl:call-template>
  <xsl:call-template name="dimension" />
  <xsl:text> </xsl:text><xsl:value-of select="@name" /><xsl:text>(</xsl:text>
  <xsl:apply-templates select="parameter" />
  <xsl:text>)</xsl:text>
  <xsl:if test="exception">
    <xsl:text> throws </xsl:text>
    <xsl:apply-templates select="exception" />
  </xsl:if>
  <xsl:choose>
    <xsl:when test="@abstract = 'true'">
    <xsl:text>;

</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:text> {
</xsl:text>
      <xsl:if test="@type">
        <xsl:text>        return </xsl:text>
        <xsl:call-template name="default-value" />
        <xsl:text>;
</xsl:text>
      </xsl:if>
      <xsl:text>    }

</xsl:text>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template match="parameter">
  <xsl:call-template name="simple-type">
    <xsl:with-param name="scope" select="../../@scope" />
  </xsl:call-template>
  <xsl:text> arg</xsl:text><xsl:value-of select="position()" />
  <xsl:if test="position() != last()"><xsl:text>, </xsl:text></xsl:if>
</xsl:template>

<xsl:template match="exception">
  <xsl:call-template name="simple-type">
    <xsl:with-param name="scope" select="../../@scope" />
  </xsl:call-template>
  <xsl:if test="position() != last()"><xsl:text>, </xsl:text></xsl:if>
</xsl:template>

<xsl:template name="modifiers">
  <xsl:if test="parent::node()[name() != 'interface']">
    <xsl:if test="@public = 'true'"><xsl:text>public </xsl:text></xsl:if>
  </xsl:if>
  <xsl:if test="@protected = 'true'"><xsl:text>protected </xsl:text></xsl:if>
  <xsl:if test="@private = 'true'"><xsl:text>private</xsl:text></xsl:if>
  <xsl:if test="@static = 'true'"><xsl:text>static </xsl:text></xsl:if>
  <xsl:if test="name() = 'class' or parent::node()[name() = 'class']">
    <xsl:if test="@abstract = 'true'"><xsl:text>abstract </xsl:text></xsl:if>
  </xsl:if>
  <xsl:if test="@final = 'true'"><xsl:text>final </xsl:text></xsl:if>
</xsl:template>

<xsl:template name="member-description">
  <xsl:param name="name" select="@name" />
  <xsl:param name="class" select="../@name" />
  <xsl:param name="scope" select="../@scope" />
  <xsl:variable name="description" select="$documentation-root/documentation/topics/method[@name=$name and @class=$class and @scope=$scope]/description" />
  <xsl:choose>
    <xsl:when test="$description">
      <xsl:apply-templates select="$description">
        <xsl:with-param name="type" select="'member'" />
        <xsl:with-param name="class" select="$class" />
      </xsl:apply-templates>
    </xsl:when>
    <xsl:when test="starts-with($name, 'is')">
      <xsl:call-template name="property-description">
        <xsl:with-param name="name" select="substring($name, 3)" />
        <xsl:with-param name="class" select="$class" />
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="starts-with($name, 'has') or starts-with($name, 'get') or starts-with($name, 'set')">
      <xsl:call-template name="property-description">
        <xsl:with-param name="name" select="substring($name, 4)" />
        <xsl:with-param name="class" select="$class" />
      </xsl:call-template>
    </xsl:when>
    <xsl:when test="$class != '*'">
      <xsl:call-template name="member-description">
        <xsl:with-param name="name" select="$name" />
        <xsl:with-param name="class" select="'*'" />
      </xsl:call-template>
    </xsl:when>
  </xsl:choose>
</xsl:template>

<xsl:template name="property-description">
  <xsl:param name="name" select="@name" />
  <xsl:param name="class" select="../@name" />
  <xsl:param name="scope" select="../@scope" />
  <xsl:variable name="name-is" select="concat('Is', $name)" />
  <xsl:variable name="description-is" select="$documentation-root/documentation/topics/property[@name=$name-is and @class=$class and @scope=$scope]/description" />
  <xsl:choose>
    <xsl:when test="$description-is">
      <xsl:apply-templates select="$description-is">
        <xsl:with-param name="type" select="'member'" />
        <xsl:with-param name="class" select="$class" />
      </xsl:apply-templates>
    </xsl:when>
    <xsl:otherwise>
      <xsl:variable name="name-has" select="concat('Has', $name)" />
      <xsl:variable name="description-has" select="$documentation-root/documentation/topics/property[@name=$name-has and @class=$class and @scope=$scope]/description" />
      <xsl:choose>
        <xsl:when test="$description-has">
          <xsl:apply-templates select="$description-has">
            <xsl:with-param name="type" select="'member'" />
            <xsl:with-param name="class" select="$class" />
          </xsl:apply-templates>
        </xsl:when>
        <xsl:otherwise>
          <xsl:variable name="description-get" select="$documentation-root/documentation/topics/property[@name=$name and @class=$class and @scope=$scope]/description" />
          <xsl:choose>
            <xsl:when test="$description-get">
              <xsl:apply-templates select="$description-get">
                <xsl:with-param name="type" select="'member'" />
                <xsl:with-param name="class" select="$class" />
              </xsl:apply-templates>
            </xsl:when>
            <xsl:when test="$class != '*'">
              <xsl:call-template name="property-description">
                <xsl:with-param name="name" select="$name" />
                <xsl:with-param name="class" select="'*'" />
              </xsl:call-template>
            </xsl:when>
          </xsl:choose>
        </xsl:otherwise>
      </xsl:choose>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="simple-type">
  <xsl:param name="type" select="@type" />
  <xsl:param name="scope" select="@scope" />
  <xsl:choose>
    <xsl:when test="string($type) = ''">
      <xsl:text>void</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="cut-scope">
        <xsl:with-param name="type">
          <xsl:call-template name="cut-scope">
            <xsl:with-param name="type">
              <xsl:call-template name="cut-scope">
                <xsl:with-param name="type">
                  <xsl:call-template name="cut-scope">
                    <xsl:with-param name="type">
                      <xsl:call-template name="cut-scope">
                        <xsl:with-param name="type">
                          <xsl:call-template name="cut-scope">
                            <xsl:with-param name="type" select="$type" />
                            <xsl:with-param name="scope" select="$scope" />
                          </xsl:call-template>
                        </xsl:with-param>
                        <xsl:with-param name="scope" select="'java.lang.reflect'" />
                      </xsl:call-template>
                    </xsl:with-param>
                    <xsl:with-param name="scope" select="'java.applet'" />
                  </xsl:call-template>
                </xsl:with-param>
                <xsl:with-param name="scope" select="'java.util'" />
              </xsl:call-template>
            </xsl:with-param>
            <xsl:with-param name="scope" select="'java.io'" />
          </xsl:call-template>
        </xsl:with-param>
        <xsl:with-param name="scope" select="'java.lang'" />
      </xsl:call-template>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="cut-scope">
  <xsl:param name="type" select="@type" />
  <xsl:param name="scope" select="@scope" />
  <xsl:variable name="prefix" select="concat($scope, '.')" />
  <xsl:choose>
    <xsl:when test="starts-with($type, $prefix)">
      <xsl:value-of select="substring-after($type, $prefix)" />
    </xsl:when>
    <xsl:otherwise><xsl:value-of select="$type" /></xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="value">
  <xsl:choose>
    <xsl:when test=". != ''">
      <xsl:choose>
        <xsl:when test="@type = 'java.lang.String'">
          <xsl:text>"</xsl:text><xsl:value-of select="." /><xsl:text>"</xsl:text>
        </xsl:when>
        <xsl:when test="@type = 'char'">
          <xsl:text>'</xsl:text><xsl:value-of select="." /><xsl:text>'</xsl:text>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="." />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:when>
    <xsl:otherwise>
      <xsl:call-template name="default-value" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="default-value">
  <xsl:choose>
    <xsl:when test="contains(@type, '.') or @dimension">
      <xsl:text>null</xsl:text>
    </xsl:when>
    <xsl:when test="@type = 'boolean'">
      <xsl:text>false</xsl:text>
    </xsl:when>
    <xsl:when test="@type = 'char'">
      <xsl:text>'\0'</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:text>0</xsl:text>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="dimension">
  <xsl:call-template name="subdimension">
    <xsl:with-param name="count" select="@dimension" />
  </xsl:call-template>
</xsl:template>

<xsl:template name="subdimension">
  <xsl:param name="count" />
  <xsl:if test="$count > 0">
    <xsl:text>[]</xsl:text>
    <xsl:call-template name="subdimension">
      <xsl:with-param name="count" select="$count - 1" />
    </xsl:call-template>
  </xsl:if>
</xsl:template>

<xsl:template match="description">
  <xsl:param name="type" />
  <xsl:param name="class" />
  <xsl:variable name="name" select="../@name" />
  <xsl:variable name="scope" select="../@scope" />
  <xsl:text>/**
</xsl:text>
  <xsl:apply-templates select="*" />
  <xsl:choose>
    <xsl:when test="$external-examples">
      <xsl:if test="not(see) and ($type = 'class' or $type = 'member') and $documentation-root/documentation/topics/example[@name=$name and @class=$class and @scope=$scope and @type=$type]/description">
       <xsl:text> *
 * </xsl:text>