code223a.txt

来自「VB大全（精华版）源代码」· 文本 代码 · 共 39 行

Public Sub Quick_Sort(ByRef SortArray() As Integer, ByVal First As _
    Integer, ByVal Last As Integer)
  Dim Temp As Integer, Low As Integer, High As Integer
  Dim List_Separator As Integer
  Low = First
  High = Last
  List_Separator = SortArray((First + Last) / 2)
  Do
    Do While (SortArray(Low) < List_Separator)
      Low = Low + 1
    Loop
    Do While (SortArray(High) > List_Separator)
      High = High - 1
    Loop
    If (Low <= High) Then
      Temp = SortArray(Low)
      SortArray(Low) = SortArray(High)
      SortArray(High) = Temp
      Low = Low + 1
      High = High - 1
    End If
  Loop While (Low <= High)
  If (First < High) Then Quick_Sort SortArray, First, High
  If (Low < Last) Then Quick_Sort SortArray, Low, Last
End Sub

Public Sub Main()
  Dim Values(99) As Integer, I As Integer

  Randomize
  For I = 0 To UBound(Values)
    Values(I) = CInt(Rnd() * 100)
  Next
  Quick_Sort Values(), 0, 99
  For I = 0 To UBound(Values)
    Debug.Print Values(I)
  Next
End Sub