gtweeny.as

Actionscript - Great effect libraries for Actionscript Flash/Air

		public function set reversed(value:Boolean):void {
			if (value == _reversed) { return; }
			_reversed = value;
			// we force an init so that it jumps to the proper position immediately without flicker.
			if (!inited) { init(); }
			setPosition(_position,true);
		}
		
		/**
		* The length of the delay in frames or seconds (depending on the timingMode). The delay occurs before a tween reads initial values or starts playing.
		**/
		public function get delay():Number {
			return _delay;
		}
		public function set delay(value:Number):void {
			_delay = value;
			if (_position == -_delay) {
				_position = -_delay;
			}
		}
		
	// public methods:
		
		/**
		* Shorthand method for making multiple setProperty calls quickly. This removes any existing target property values on the tween.
		* <br/><br/>
		* <b>Example:</b> set x and y end values:<br/>
		* <code>myGTween.setProperties({x:200, y:400});</code>
		*
		* @param properties An object containing end property values.
		**/
		public function setProperties(properties:Object):void {
			endValues = {};
			for (var n:String in properties) {
				setProperty(n, properties[n]);
			}
		}
		
		/**
		* Sets the numeric end value for a property on the target object that you would like to tween.
		* For example, if you wanted to tween to a new x position, you could use: myGTween.setProperty("x",400). Non-numeric values are ignored.
		*
		* @param name The name of the property to tween.
		* @param value The numeric end value (the value to tween to).
		**/
		public function setProperty(name:String, value:Number):void {
			if (isNaN(value)) { return; }
			endValues[name] = value;
			invalidate();
		}
		
		/**
		* Returns the destination value for the specified property if one exists.
		*
		* @param name The name of the property to return a destination value for.
		**/
		public function getProperty(name:String):Number {
			return endValues[name];
		}
		
		/**
		* Removes a end value from the tween. This prevents the GTween instance from tweening the property.
		*
		* @param name The name of the end property to delete.
		**/
		public function deleteProperty(name:String):Boolean {
			return delete(endValues[name]);
		}
		
		/**
		* Shortcut method for setting multiple properties on the tween instance quickly. This does not set destination values (ie. the value to tween to).
		* This method also provides you with a quick method for adding listeners to specific events, using the special properties:
		* initListener, completeListener, changeListener.
		* <br/><br/>
		* <b>Example:</b> This will set the duration, reflect, and nextTween properties of a tween, and add a listener for the complete event:<br/>
		* <code>myTween.setTweenProperties({duration:4, reflect:true, nextTween:anotherTween, completeListener:completeHandlerFunction});</code>
		**/
		public function setTweenProperties(properties:Object):void {
			if (!properties) { return; }
			
			var positionValue:Number;
			if ("position" in properties) { positionValue = properties.position; delete(properties.position); }
			if ("initListener" in properties) { addEventListener(Event.INIT,properties.initListener,false,0,true); delete(properties.initListener); }
			if ("completeListener" in properties) { addEventListener(Event.COMPLETE,properties.completeListener,false,0,true); delete(properties.completeListener); }
			if ("changeListener" in properties) { addEventListener(Event.CHANGE,properties.changeListener,false,0,true); delete(properties.changeListener); }
			
			for (var n:String in properties) {
				this[n] = properties[n];
			}
			
			if (!isNaN(positionValue)) { position = positionValue; }
		}
		
		/**
		* Toggles the reversed property and inverts the current tween position.
		* This will cause a tween to reverse playing visually.
		* There is currently an issue with this functionality for tweens with a repeat of -1
		*
		* @param suppressEvents Indicates whether to suppress any events or callbacks that are generated as a result of the position change.
		**/
		public function reverse(suppressEvents:Boolean=true):void {
			var pos:Number = repeat == -1 ? duration-_position%duration : (repeat+1)*duration-_position;
			if (reflect) {
				_reversed = ((position/duration%2>=1) == (pos/duration%2>=1)) != _reversed;
			} else {
				_reversed = !_reversed;
			}
			setPosition(pos,suppressEvents);
		}
		
		/**
		* Invalidate forces the tween to repopulate all of the initial properties from the target object, and start playing if autoplay is set to true.
		* If the tween is currently playing, then it will also set the position to 0. For example, if you changed the x and y position of a the target
		* object while the tween was playing, you could call invalidate on it to force it to resume the tween with the new property values.
		**/
		public function invalidate():void {
			inited = false;
			if (_position > 0) {
				_position = 0;
				updatePositionOffset();
			}
			if (autoPlay) { paused = false; }
		}
		
		/**
		* Pauses the tween by stopping tick from being automatically called. This also releases the tween for garbage collection if
		* it is not referenced externally.
		**/
		public function pause():void {
			paused = true;
		}
		
		/**
		* Plays a tween by incrementing the position property each frame. This also prevents the tween from being garbage collected while it is active.
		* This is achieved by way of two methods:<br/>
		* 1. If the target object is an IEventDispatcher, then the tween will subscribe to a dummy event using a hard reference. This allows
		* the tween to be garbage collected if its target is also collected, and there are no other external references to it.<br/>
		* 2. If the target object is not an IEventDispatcher, then the tween is placed in the activeTweens list, to prevent collection until it is paused or reaches the end of the transition).
		* Note that pausing all tweens via the GTween.pauseAll static property will not free the tweens for collection.
		**/
		public function play():void {
			paused = false;
		}
		
		/**
		* Jumps the tween to its beginning. This is the same as setting <code>position=-delay</code>.
		**/
		public function beginning():void {
			setPosition(-_delay);
		}
		
		/**
		* Jumps the tween to its end. This is the same as setting <code>position=(repeat+1)*duration</code>.
		**/
		public function end():void {
			setPosition( (repeat == -1) ? duration : (repeat+1)*duration );
		}
		
		/**
		* Sets the position of the tween. Using the position property will always suppress events and callbacks, whereas the
		* setPosition method allows you to manually set the position and specify whether to suppress events or not.
		*
		* @param value The position to jump to in seconds or frames (depending on the timingMode).
		* @param suppressEvents Indicates whether to suppress events and callbacks generated from the change in position.
		**/
		public function setPosition(position:Number,suppressEvents:Boolean=true):void {
			_previousPosition = _position;
			_position = position;
			if (!inTick && !paused) { updatePositionOffset(); }
			var maxPos:Number = (repeat+1)*duration;
			var tp:Number;
			if (position < 0) {
				tp = _reversed ? duration : 0;
			} else if (repeat == -1 || position < maxPos) {
				tp = position%duration;
				if ((reflect && position/duration%2>=1) != _reversed) { tp = duration-tp; }
			} else {
				tp = ((reflect && repeat%2>=1) != _reversed) ? 0 : duration;
			}
			if (tp == _tweenPosition) { return; }
			_previousTweenPosition = _tweenPosition;
			_tweenPosition = tp;
			
			if (!suppressEvents && hasEventListener(Event.CHANGE)) { dispatchEvent(new Event(Event.CHANGE)); }
			
			
			if (!inited && _previousPosition <= 0 && _position >= 0) {
				init();
				if (!suppressEvents && hasEventListener(Event.INIT)) { dispatchEvent(new Event(Event.INIT)); }
			}
			
			updateProperties();
			
			if (repeat != -1 && _previousPosition < maxPos && position >= maxPos) {
				if (!suppressEvents && hasEventListener(Event.COMPLETE)) { dispatchEvent(new Event(Event.COMPLETE)); }
				paused = true;
				if (nextTween) { nextTween.paused = false; }
			}
		}
		
	// private methods
		// copies the initial target properties into the local startValues store.
		/** @private **/
		protected function init():void {
			inited = true;
			startValues = {};
			for (var n:String in endValues) {
				if (autoRotation && rotationProperties[n]) {
					var r:Number = endValues[n] = endValues[n] %360;
					var tr:Number = _target[n] %360;
					startValues[n] = tr + ((Math.abs(tr-r) < 180) ? 0 : (tr>r) ? -360 : 360);
				} else {
					startValues[n] = _target[n];
				}
			}
		}
		
		// logic that runs each frame. Calculates eased position, updates properties, and reassigns the target if an assignmentTarget was set.
		/** @private **/
		protected function updateProperties():void {
			var ratio:Number = ease(_tweenPosition/duration, 0, 1, 1);
			for (var n:String in endValues) {
				updateProperty(n,startValues[n],endValues[n],ratio);
			}
			if (autoVisible && "alpha" in endValues && "alpha" in _target && "visible" in _target) { _target.visible = _target.alpha > 0; }
		}
		
		// updates a single property. Mostly for overriding.
		/** @private **/
		protected function updateProperty(property:String, startValue:Number, endValue:Number, tweenRatio:Number):void {
			var value:Number = startValue+(endValue-startValue)*tweenRatio;
			if (snapping && snappingProperties[property]) { value = Math.round(value); }
			if (property == "currentFrame") { _target.gotoAndStop(value<<0); }
			else { _target[property] = value; }
		}
		
		// locks or unlocks the tween in memory.
		/** @private **/
		protected function setGCLock(value:Boolean):void {
			if (value) {
				if (_target is IEventDispatcher) { _target.addEventListener("GDS__NONEXISTENT_EVENT", nullListener,false,0,false); }
				else { activeTweens[this] = true; }
			} else {
				if (_target is IEventDispatcher) { _target.removeEventListener("GDS__NONEXISTENT_EVENT", nullListener); }
				delete(activeTweens[this]);
			}
		}
		
		// updates the current positionOffset based on the current ticker position.
		/** @private **/
		protected function updatePositionOffset():void {
			positionOffset = ticker.position-_position;
		}
		
		// empty listener used by setGCLock.
		/** @private **/
		protected function nullListener(evt:Event):void {};
		
		// handles tick events while playing.
		/** @private **/
		protected function handleTick(evt:Event):void {
			inTick = true;
			if (pauseAll) { updatePositionOffset(); }
			else { setPosition(ticker.position - positionOffset, false); }
			inTick = false;
		}
		
		
	}
	
}



import flash.events.EventDispatcher;
import flash.events.Event;
import flash.display.Shape;
import flash.utils.getTimer;
class HybridTicker extends EventDispatcher {
	
	protected var shape:Shape;
	
	public function HybridTicker():void {
		shape = new Shape();
		shape.addEventListener(Event.ENTER_FRAME,tick);
	}
	
	public function get position():Number {
		return getTimer()/1000;
	}
	
	protected function tick(evt:Event):void {
		dispatchEvent(new Event("tick"));
	}
}