install.vbs

一个非常好的jsp+wml的例子（包括代码） 源码,对初接触wap编程的爱好者 ...

'''''''''''''''''''''''''''''''''''''''''''''
'
'          WAPmo v1.1 IIS Setup Script
'
'  说明：
'  WAPmo v1.1 IIS 自动安装脚本，用户请根据自己的情况作设置
'
'''''''''''''''''''''''''''''''''''''''''''''

Option Explicit

On Error Resume Next

'站点定义，请修改如下定义
Const WebName		= "WAPmo"			'站点名称，可以不修改
Const WebAddress	= ""				'站点IP，可以置空
Const WebPort		= "80"				'站点端口
Const WebHost		= "wapmo.vicp.net"	'域名，请更改成自己的域名，如果是IP访问，那么可以置空
Const WebRoot		= "E:\www\wapmo"	'WAPmo的目录，请更改成WAPmo安装包的解压目录
Const WebMark		= 2005				'站点标识，可以不修改

Dim WebBind: ReDim WebBind(0)
WebBind(0) = WebAddress & ":" & WebPort & ":" & WebHost

Dim ServiceObj: Set ServiceObj = GetObject("IIS://Localhost/W3SVC")
'建立站点
Dim ServerObj: Set ServerObj = ServiceObj.Create("IISWebServer", WebMark)
If (Err.Number <> 0) Then
	Wscript.Echo "创建站点失败，请确认是否有同标识符的站点存在，或者服务器不支持自动创建站点"
	Wscript.Quit
End If

ServerObj.ServerSize = 1   ' Medium-sized server
ServerObj.ServerComment = WebName
ServerObj.ServerBindings = WebBind
ServerObj.SetInfo

'建立根目录
Dim RootDir: Set RootDir = ServerObj.Create("IISWebVirtualDir", "ROOT")
If (Err.Number <> 0) Then
	Wscript.Echo "创建虚拟目录ROOT失败"
	Wscript.Quit
End If

RootDir.Path = WebRoot & "\html"
RootDir.DefaultDoc = "index.asp,index.wml"
RootDir.AccessRead = True
RootDir.AccessWrite = False
RootDir.EnableDirBrowsing = False
RootDir.AccessScript = True
RootDir.AppFriendlyName = "默认应用程序"
RootDir.AppCreate True
RootDir.HttpCustomHeaders = Array("X-Powered-By: ANSI C", "X-CopyRight: WAPmo Mobile Factory")
Dim MimeMap: ReDim MimeMap(1)
Set MimeMap(0) = CreateObject("MimeMap")
MimeMap(0).Extension = ".wml"
MimeMap(0).MimeType = "text/vnd.wap.wml"
Set MimeMap(1) = CreateObject("MimeMap")
MimeMap(1).Extension = ".wml"
MimeMap(1).MimeType = "image/vnd.wap.wbmp"
RootDir.MIMEMap = MimeMap
RootDir.SetInfo

Wscript.Echo "站点创建成功，站点名=" & WebName & "，根目录=" & WebRoot & "\html，域名=" & WebHost & ""

'建立cgi-bin虚拟目录
Dim CGIDir: Set CGIDir = RootDir.Create("IISWebVirtualDir", "cgi-bin")
If (Err.Number <> 0) Then
	Wscript.Echo "创建虚拟目录cgi-bin失败"
	Wscript.Quit
End If

CGIDir.Path = WebRoot & "\cgi-bin"
CGIDir.DefaultDoc = "index.cgi"
CGIDir.AccessRead = False
CGIDir.AccessWrite = False
CGIDir.AccessExecute = True
CGIDir.EnableDirBrowsing = False
CGIDir.AppFriendlyName = "cgi-bin"
CGIDir.AppCreate True
CGIDir.SetInfo

Wscript.Echo "创建虚拟目录cgi-bin成功"

'建立images虚拟目录
Dim ImageDir: Set ImageDir = RootDir.Create("IISWebVirtualDir", "images")
If (Err.Number <> 0) Then
	Wscript.Echo "创建虚拟目录images失败"
	Wscript.Quit
End If

ImageDir.Path = WebRoot & "\images"
ImageDir.DefaultDoc = ""
ImageDir.AccessRead = True
ImageDir.AccessWrite = False
ImageDir.EnableDirBrowsing = False
ImageDir.SetInfo

Wscript.Echo "创建虚拟目录images成功"

'启动站点
ServerObj.Start
If (Err.Number <> 0) Then
	Wscript.Echo "启动站点失败"
	Wscript.Quit
End If

Wscript.Echo "站点" & WebName & "启动成功"
Wscript.Quit(0)