clsgoodstype.cls

<Visual Basic 数据库开发实例精粹（第二版）>一书首先介绍了Visual Basic(简称VB)开发的技巧和重点技术

VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
  Persistable = 0  'NotPersistable
  DataBindingBehavior = 0  'vbNone
  DataSourceBehavior  = 0  'vbNone
  MTSTransactionMode  = 0  'NotAnMTSObject
END
Attribute VB_Name = "clsGoodsType"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = True
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = True
Attribute VB_Ext_KEY = "SavedWithClassBuilder6" ,"Yes"
Attribute VB_Ext_KEY = "Top_Level" ,"Yes"
Option Explicit

'保持属性值的局部变量
Private mvarID As Long           '类型编号
Private mvarTypeName As String   '类型名称
Private mvarRemark As String     '备注

Public Property Let Remark(ByVal vData As String)
'向属性指派值时使用，位于赋值语句的左边。
'Syntax: X.Remark = 5
    mvarRemark = vData
End Property

Public Property Get Remark() As String
'检索属性值时使用，位于赋值语句的右边。
'Syntax: Debug.Print X.Remark
    Remark = mvarRemark
End Property

Public Property Let TypeName(ByVal vData As String)
'向属性指派值时使用，位于赋值语句的左边。
'Syntax: X.TypeName = 5
    mvarTypeName = vData
End Property

Public Property Get TypeName() As String
'检索属性值时使用，位于赋值语句的右边。
'Syntax: Debug.Print X.TypeName
    TypeName = mvarTypeName
End Property

Public Property Let ID(ByVal vData As Long)
'向属性指派值时使用，位于赋值语句的左边。
'Syntax: X.ID = 5
    mvarID = vData
End Property

Public Property Get ID() As Long
'检索属性值时使用，位于赋值语句的右边。
'Syntax: Debug.Print X.ID
    ID = mvarID
End Property

'添加商品类型
Public Function AddNew() As gxcAddNew
  On Error Resume Next

  '使用ADO的内置Command类来调用存储过程
  Dim cmd As New ADODB.Command
  
  '指定命令对象当前的活动连接
  cmd.ActiveConnection = g_Conn
  '指定命令类型为调用存储过程
  cmd.CommandType = adCmdStoredProc
  '指定命令文本，即要调用的存储过程名
  cmd.CommandText = "GoodsTypeAddNew"
  
  '指定命令对象的参数
  cmd.Parameters("@TypeName") = RealString(Me.TypeName)
  cmd.Parameters("@Remark") = RealString(Me.Remark)
  cmd.Parameters("@ID") = Null
  cmd.Parameters("@ReturnValue") = Null
  
  '执行命令
  cmd.Execute

  '由存储过程输出参数决定函数返回值 (自定义枚举)
  AddNew = cmd.Parameters("@ReturnValue").Value
  
  '获取添加成功后商品类型的ID值
  If AddNew = AddNewOK Then Me.ID = cmd.Parameters("@ID").Value
    
  '释放命令对象
  Set cmd = Nothing
End Function

'更新商品类型
Public Function Update() As gxcUpdate
  On Error Resume Next
  
  '使用ADO的内置Command类来调用存储过程
  Dim cmd As New ADODB.Command
  '为创建Command的参数而使用
  Dim param As ADODB.Parameter

  '指定命令对象当前的活动连接
  cmd.ActiveConnection = g_Conn
  '指定命令类型为调用存储过程
  cmd.CommandType = adCmdStoredProc
  '指定命令文本，即要调用的存储过程名
  cmd.CommandText = "GoodsTypeUpdate"

  '创建参数并设置各参数的属性
  '以下是输入型参数
  Set param = cmd.CreateParameter("TypeID", adInteger, adParamInput, 4, Me.ID)
  cmd.Parameters.Append param
  Set param = cmd.CreateParameter("TypeName", adVarChar, adParamInput, 100, Me.TypeName)
  cmd.Parameters.Append param
  Set param = cmd.CreateParameter("Remark", adVarChar, adParamInput, 1000, Me.Remark)
  cmd.Parameters.Append param
  '以下是输出型参数
  Set param = cmd.CreateParameter("ReturnValue", adInteger, adParamOutput)
  cmd.Parameters.Append param

  '执行命令
  cmd.Execute
     
  '由存储过程输出参数决定函数返回值(自定义枚举)
  Update = cmd.Parameters("ReturnValue").Value

  '释放命令对象
  Set cmd = Nothing
End Function

'删除商品类型
Public Function Delete(lngID As Long) As gxcDelete
  On Error Resume Next
  
  '使用ADO的内置Command类来调用存储过程
  Dim cmd As New ADODB.Command
  '为创建Command的参数而使用
  Dim param As ADODB.Parameter

  '指定命令对象当前的活动连接
  cmd.ActiveConnection = g_Conn
  '指定命令类型为调用存储过程
  cmd.CommandType = adCmdStoredProc
  '指定命令文本，即要调用的存储过程名
  cmd.CommandText = "GoodsTypeDelete"

  '创建参数并设置各参数的属性
  '以下是输入型参数
  Set param = cmd.CreateParameter("TypeID", adInteger, adParamInput, 4, lngID)
  cmd.Parameters.Append param
  '以下是输出型参数
  Set param = cmd.CreateParameter("ReturnValue", adInteger, adParamOutput)
  cmd.Parameters.Append param

  '执行命令
  cmd.Execute

  '由存储过程输出参数决定函数返回值(自定义枚举)
  Delete = cmd.Parameters("ReturnValue").Value

  '释放命令对象
  Set cmd = Nothing
End Function