commond.asp

割自ro-blog v2.0

<%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
<%
Response.Buffer = True
Server.ScriptTimeOut = 90
Session.CodePage=65001
DIM MaxUrl,MaxHttp
MaxUrl=2 '最多可以在一个评论中加多少个[url ] 
MaxHttp=3 '最多可以在一个评论中加多少个 http://
'定义 Cookie,Application 域，可以修改，否则可能运行不正常
Const CookieName="17u0book"
Const CookieNameSet="17u0bookSet" '17u0设置保存用的Cookie，建议不要和CookieName相等
Dim StartTime,SQLQueryNums
StartTime=Timer()
SQLQueryNums=0
'定义数据库链接文件，根据自己的情况修改
Const AccessFile="data/17u0book.mdb" 
Const AccessPath="data" '路径要和上面一样否则后台备份数据库会失败
'定义数据库连接
Dim Conn
    on error resume next
	Set Conn= Server.CreateObject("ADODB.Connection")
	Conn.ConnectionString="Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath(AccessFile)
	Conn.Open
	If Err Then
    err.Clear
    Set Conn = Nothing
    Response.Write "数据库连接出错，请检查连接字串。"
    Response.End
    End If

Dim R17u0_Infos,SiteName,SiteUrl,R17u0BookPage
Set R17u0_Infos=Conn.ExeCute("SELECT * FROM 17u0_Info")
SQLQueryNums=SQLQueryNums+1
SiteName=R17u0_Infos("17u0_Name")
SiteURL=R17u0_Infos("17u0_URL")
R17u0BookPage=R17u0_Infos("17u0_BookPage")
Set R17u0_Infos=Nothing
Dim SQL,TempVar,siteTitle

Const Register_UserNames="游客,客人,Admin,SupAdmin,Fuck"'注册名字过滤
Dim Register_UserName
Register_UserName=Split(Register_UserNames,",")
Dim memName,memPassword,memStatus,Guest_IP
memName=CheckStr(Request.Cookies(CookieName)("memName"))
memPassword=CheckStr(Request.Cookies(CookieName)("memPassword"))
memStatus=CheckStr(Request.Cookies(CookieName)("memStatus"))
Guest_IP=Replace(Request.ServerVariables("REMOTE_ADDR"),"'","")
IF memName<>Empty Then
    Dim CheckCookie
    Set CheckCookie=Server.CreateObject("ADODB.RecordSet")
    SQL="SELECT mem_Name,mem_Password,mem_Status,mem_LastIP FROM 17u0_Member WHERE mem_Name='"&memName&"' AND mem_Password='"&memPassword&"' AND mem_Status='"&memStatus&"'"
    CheckCookie.Open SQL,Conn,1,1
    SQLQueryNums=SQLQueryNums+1
    If CheckCookie.EOF AND CheckCookie.BOF Then
        Response.Cookies(CookieName)("memName")=""
        memName=Empty
        Response.Cookies(CookieName)("memPassword")=""
        memPassword=Empty
        Response.Cookies(CookieName)("memStatus")=""
        memStatus=Empty
    Else
        If CheckCookie("mem_LastIP")<>Guest_IP Or isNull(CheckCookie("mem_LastIP")) Then
            Response.Cookies(CookieName)("memName")=""
            memName=Empty
            Response.Cookies(CookieName)("memPassword")=""
            memPassword=Empty
            Response.Cookies(CookieName)("memStatus")=""
            memStatus=Empty
        End If
    End IF
    CheckCookie.Close
    Set CheckCookie=Nothing
Else
    Response.Cookies(CookieName)("memName")=""
    memName=Empty
    Response.Cookies(CookieName)("memPassword")=""
    memPassword=Empty
    Response.Cookies(CookieName)("memStatus")=""
    memStatus=Empty
End IF


'写入表情符号
Dim Arr_Smilies
IF Not IsArray(Application(CookieName&"_17u0_Smilies")) Then
	Dim log_Smilies,log_SmiliesList
	Set log_Smilies=Conn.Execute("SELECT sm_ID,sm_Image,sm_Text FROM 17u0_Smilies ORDER BY sm_ID ASC")
	SQLQueryNums=SQLQueryNums+1
	TempVar=""
	Do While Not log_Smilies.EOF
		log_SmiliesList=log_SmiliesList&TempVar&log_Smilies("sm_ID")&"|"&log_Smilies("sm_Image")&"|"&log_Smilies("sm_Text")
		TempVar=","
		log_Smilies.MoveNext
	Loop
	Set log_Smilies=Nothing
	Arr_Smilies=Split(log_SmiliesList,",")
	Application.Lock
	Application(CookieName&"_17u0_Smilies")=Arr_Smilies
	Application.UnLock
Else
	Arr_Smilies=Application(CookieName&"_17u0_Smilies")
End IF


'脏字过滤列表
Dim Arr_WordFilter
IF Not IsArray(Application(CookieName&"_17u0_WordFilter")) Then
	Dim log_WordFilter,log_WordFilterList
	Set log_WordFilter=Conn.Execute("SELECT * FROM 17u0_WordFilter ORDER BY wf_Mode ASC")
	TempVar=""
	Do While Not log_WordFilter.EOF
		log_WordFilterList=log_WordFilterList&TempVar&log_WordFilter("wf_ID")&"|"&log_WordFilter("wf_Mode")&"|"&log_WordFilter("wf_Text")&"|"&log_WordFilter("wf_Replace")
		TempVar=","
		log_WordFilter.MoveNext
	Loop
	Set log_WordFilter=Nothing
	Arr_WordFilter=Split(log_WordFilterList,",")
	Application.Lock
	Application(CookieName&"_17u0_WordFilter")=Arr_WordFilter
	Application.UnLock
Else
	Arr_WordFilter=Application(CookieName&"_17u0_WordFilter")
End IF

%>