discriptive1.sas

本书详细讲解了sas的使用基础以及编程基础

DATA weight;
 INFILE 'd:\data\tomhs.txt' dlm='09'x firstobs=2;
 INPUT ptid $ clinic $ sex $ height weight; 
 bmi = (weight*703.0768)/(height*height);
* BMI is calculated in kg/m2;
RUN;
PROC PRINT DATA = weight (OBS=5) NOOBS;
TITLE
 'Proc Print: TOMHS 数据的５条观测';
RUN;

PROC MEANS DATA = weight;
 VAR  height weight bmi;
 TITLE 'Proc Means Example 1';
RUN;

PROC MEANS DATA = weight MEAN MEDIAN STD MAXDEC=2;
 VAR  height weight bmi;
 TITLE 'Proc Means Example 2 (specifying options)';
RUN;
PROC MEANS DATA = weight N MEAN STD MAXDEC=2 FW=8;
 CLASS clinic;
 TITLE 'Proc Means Example 3 (使用 CLASS类别语句)';
RUN;
PROC UNIVARIATE DATA = weight PLOT  ;
 ID ptid;
 VAR bmi;
 TITLE 'Proc Univariate Example 1';
RUN;
*  High resolution graphs can also be produced. 
   The following makes a histogram ;
  

PROC UNIVARIATE DATA = weight;
 VAR bmi;
 
 HISTOGRAM bmi / normal MIDPOINTS=20 to 40 by 2;
 INSET N    = 'N' (5.0)
       MEAN = 'Mean' (5.1)
       STD  = 'Sdev' (5.1)
       MIN  = 'Min'  (5.1)
       MAX  = 'Max'  (5.1)/ POS=nw HEADER='Summary Statistics';
 LABEL bmi = 'Body Mass Index (kg/m2)';
 TITLE 'Histogram of BMI';
RUN;