admin_payment.asp

来自「本程序系统完全实现了医院网站程序的全部功能的前台和后台程序」· ASP 代码 · 共 375 行 · 第 1/2 页

            Response.Write "    <td width='70' align='right'>" & FormatNumber(rsPaymentList("MoneyPay"), 2, vbTrue, vbFalse, vbTrue) & "</td>"
            Response.Write "    <td width='70' align='right'>" & FormatNumber(rsPaymentList("MoneyTrue"), 2, vbTrue, vbFalse, vbTrue) & "</td>"
            Response.Write "    <td width='60' align='center'>"
            If rsPaymentList("eBankID") <> 8 Then
                Select Case rsPaymentList("Status")
                Case 1
                    Response.Write "未提交"
                Case 2
                    Response.Write "已经提交，但未成功"
                Case 3
                    Response.Write "支付成功"
                End Select
            Else
                Select Case rsPaymentList("Status")
                Case 1
                    Response.Write "等待买家付款"
                Case 2
                    Response.Write "买家已付款"
                Case 3
                    Response.Write "交易成功"
                Case 4
                    Response.Write "卖家已发货，等待买家确认收货"
                End Select
            End If
            Response.Write "    </td>"
            Response.Write "    <td width='70' align='center'>" & rsPaymentList("eBankInfo") & "</td>"
            Response.Write "    <td>" & rsPaymentList("Remark") & "</td>"
            Response.Write "    <td align='center'>"
            If rsPaymentList("Status") = 1 Then
                Response.Write "<a href='Admin_Payment.asp?Action=Cancel&PaymentID=" & rsPaymentList("PaymentID") & "' onclick=""return confirm('确定要删除这条在线支付记录吗？');"">取消</a> "
                Response.Write "<a href='Admin_Payment.asp?Action=Success&PaymentID=" & rsPaymentList("PaymentID") & "' onclick=""return confirm('确定这条在线支付记录已经支付成功了吗？');"">成功</a>"
            End If
            Response.Write "</td>"
            Response.Write "  </tr>"
            TotalMoneyPay = TotalMoneyPay + rsPaymentList("MoneyPay")
            TotalMoneyTrue = TotalMoneyTrue + rsPaymentList("MoneyTrue")
            i = i + 1
            If i >= MaxPerPage Then Exit Do
            rsPaymentList.MoveNext
        Loop
    End If
    rsPaymentList.Close
    Set rsPaymentList = Nothing
        
    Response.Write "  <tr class='tdbg' onmouseout=""this.className='tdbg'"" onmouseover=""this.className='tdbgmouseover'"">"
    Response.Write "    <td colspan='5' align='right'>合计金额：</td>"
    Response.Write "    <td width='70' align='right'>" & FormatNumber(TotalMoneyPay, 2, vbTrue, vbFalse, vbTrue) & "</td>"
    Response.Write "    <td width='70' align='right'>" & FormatNumber(TotalMoneyTrue, 2, vbTrue, vbFalse, vbTrue) & "</td>"
    Response.Write "    <td colspan='4' align='center'> </td>"
    Response.Write "  </tr>"
    Response.Write "</table>"
    Response.Write "<table width='100%' border='0' cellpadding='0' cellspacing='0'>"
    Response.Write "  <tr>"
    Response.Write "    <td width='220' height='30'><input name='chkAll' type='checkbox' id='chkAll' onclick='CheckAll(this.form)' value='checkbox'> 选中本页显示的所有在线支付记录</td>"
    Response.Write "    <td width='560'> <input name='Action' type='hidden' id='Action' value='Cancel'> <input type='submit' name='Submit' value='删除选定的在线支付记录'> </td>"
    Response.Write "  </tr>"
    Response.Write "</table>"
    Response.Write "</td>"
    Response.Write "</form></tr></table>"
    Response.Write ShowPage(strFileName, totalPut, MaxPerPage, CurrentPage, True, True, "条在线支付记录", True)
End Sub


Sub DelPayment()
    Dim PaymentID
    Dim rsPayment, sqlPayment
    PaymentID = Trim(Request("PaymentID"))
    If PaymentID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定支付单ID！</li>"
        Exit Sub
    Else
        If IsValidID(PaymentID) = False Then
            FoundErr = True
            ErrMsg = ErrMsg & "<li>请指定正确的支付单ID！</li>"
            Exit Sub
        End If
    End If
    
    sqlPayment = "select * from PE_Payment where PaymentID in (" & PaymentID & ")"
    Set rsPayment = Server.CreateObject("Adodb.RecordSet")
    rsPayment.Open sqlPayment, Conn, 1, 3
    Do While Not rsPayment.EOF
        If rsPayment("Status") = 1 Then
            rsPayment.Delete
            rsPayment.Update
        End If
        rsPayment.MoveNext
    Loop
    rsPayment.Close
    Set rsPayment = Nothing
    Call CloseConn
    Call WriteSuccessMsg("成功删除选定的在线支付记录", "Admin_Payment.asp")
End Sub

Sub PaySuccess()
    Dim PaymentID, PaymentNum, UserName, OrderFormID, MoneyReceipt, eBankID, MoneyPayout, ClientID
    Dim rsPayment, sqlPayment, trs, rsUser
    PaymentID = Trim(Request("PaymentID"))
    ClientID = 0
    If PaymentID = "" Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>请指定支付单ID！</li>"
        Exit Sub
    Else
        PaymentID = PE_CLng(PaymentID)
    End If
    
    sqlPayment = "select * from PE_Payment where PaymentID=" & PaymentID & ""
    Set rsPayment = Server.CreateObject("Adodb.RecordSet")
    rsPayment.Open sqlPayment, Conn, 1, 3
    If rsPayment.BOF And rsPayment.EOF Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>找不到指定的订单！</li>"
        rsPayment.Close
        Set rsPayment = Nothing
        Exit Sub
    End If
    If rsPayment("Status") > 1 Then
        FoundErr = True
        ErrMsg = ErrMsg & "<li>此支付单已经提交给银行！</li>"
    Else
        PaymentNum = rsPayment("PaymentNum")
        UserName = rsPayment("UserName")
        OrderFormID = rsPayment("OrderFormID")
        MoneyReceipt = rsPayment("MoneyPay")
        eBankID = rsPayment("eBankID")
        rsPayment("Status") = 3
        rsPayment("eBankInfo") = "支付完成"
        rsPayment("Remark") = "未知"
        rsPayment.Update
    End If
    rsPayment.Close
    Set rsPayment = Nothing

    Set rsUser = Conn.Execute("select ClientID from PE_User where UserName='" & UserName & "'")
    If Not (rsUser.EOF And rsUser.BOF) Then ClientID = rsUser(0)
      
    If FoundErr = True Then Exit Sub
    
    '检查是否已经有记录，若已经有，跳过写入数据库的操作
    Set trs = Conn.Execute("select * from PE_BankrollItem where PaymentID=" & PaymentID & "")
    If Not (trs.BOF And trs.EOF) Then
        ErrMsg = ErrMsg & "<li>资金明细中已经有相关记录！</li>"
        FoundErr = True
    End If
    Set trs = Nothing
    If FoundErr = True Then Exit Sub
    
    '向资金余额中添加金额
    Conn.Execute ("update PE_User set Balance=Balance+" & MoneyReceipt & " where UserName='" & UserName & "'")
    
    ' 向资金明细表中添加收入记录
    Call AddBankrollItem("", UserName, ClientID, MoneyReceipt, 3, "", eBankID, 1, 0, PaymentID, "在线支付单号：" & PaymentNum, Now())
        
    If OrderFormID > 0 Then
        Dim rsOrder
        Set rsOrder = Server.CreateObject("adodb.recordset")
        rsOrder.Open "select * from PE_OrderForm where OrderFormID=" & OrderFormID & "", Conn, 1, 3
        If Not (rsOrder.BOF And rsOrder.EOF) Then
            If rsOrder("MoneyReceipt") < rsOrder("MoneyTotal") Then
                If rsOrder("MoneyTotal") - rsOrder("MoneyReceipt") > MoneyReceipt Then
                    MoneyPayout = MoneyReceipt
                    rsOrder("MoneyReceipt") = rsOrder("MoneyReceipt") + MoneyReceipt
                Else
                    MoneyPayout = rsOrder("MoneyTotal") - rsOrder("MoneyReceipt")
                    rsOrder("MoneyReceipt") = rsOrder("MoneyTotal")
                End If
                rsOrder.Update
                '向资金明细表中添加支付记录
                Call AddBankrollItem("", UserName, ClientID, MoneyPayout, 4, "", 0, 2, OrderFormID, 0, "支付订单费用，订单号：" & rsOrder("OrderFormNum"), Now())
                
                '从资金余额中扣除支付费用
                Conn.Execute ("update PE_User set Balance=Balance-" & MoneyPayout & " where UserName='" & UserName & "'")
            End If
        End If
        rsOrder.Close
        Set rsOrder = Nothing
    End If
    Call CloseConn
    Call WriteSuccessMsg("在线支付成功", "Admin_Payment.asp")
    If ErrMsg <> "" Then
        FoundErr = True
    End If
End Sub
%>