storeitemview.as

This is a Flex UIComponent that can be used 谋n a FLEX 3 mxml application as component written in act

package mx.item.view
{
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.geom.Point;
	import flash.net.URLRequest;
	import flash.text.TextField;
	import flash.text.TextFormat;
	
	import mx.item.data.StoreItem;
	
	public class StoreItemView extends Sprite
	{
		
		private var _data:StoreItem;
		private var _loader:Loader;
		private var _textField:TextField;
		private var _mask:Sprite;
		private var _background:Sprite;
		
		public function get data():StoreItem {
			return _data;
		}
		public function StoreItemView(data:StoreItem):void
		{
			_data = data;
			_background = new Sprite();
			_background.graphics.lineStyle(0, 0x000000, 1);
			_background.graphics.beginFill(0xFFFFFF, .5);
			_background.graphics.drawRect(0, 0, 320, 120);
			_background.graphics.endFill();
			this.addChild(_background);
			_loader = new Loader();
			var request:URLRequest = new URLRequest(_data.url);
			_loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoad);
			_loader.load(request);
			_loader.x = 10;
			_loader.y = 10;
			this.addChild(_loader);
			_textField = new TextField();
			_textField.width = 200;
			_textField.height = 100;
			_textField.x = 110;
			_textField.y = 10;
			_textField.multiline = true;
			_textField.wordWrap = true;
			_textField.htmlText = "<b>"+_data.name+"</b>\n"+ _data.description;
			this.addChild(_textField);
			var format:TextFormat = new TextFormat();
			format.size = 15;
			format.font = "_sans";
			_textField.setTextFormat(format);
			_mask = new Sprite();
			_mask.graphics.lineStyle();
			_mask.graphics.beginFill(0xFFFFFF);
			_mask.graphics.drawRoundRectComplex(0,0,75,100,10,10,10,10);//RoundRect(0, 0, 100, 100, 40, 40);
			_mask.graphics.endFill();
			_mask.x = 10;
			_mask.y = 10;
			this.addChild(_mask);
		}


     private function onLoad(event:Event):void {
     	var scaleFactor:Number = 100 / Math.max(_loader.width, _loader.height);
     	_loader.scaleX = scaleFactor;
     	_loader.scaleY = scaleFactor;
     	_loader.mask = _mask;
     	
     }
    
    public function clone():StoreItemView {
    	var itemView:StoreItemView = new StoreItemView(_data);
    	if(parent != null) {
    		var point:Point = new Point(x,y);
    		var coordinates:Point = parent.localToGlobal(point);
    		itemView.x = coordinates.x;
    		itemView.y = coordinates.y;
    	}
    	return itemView;
    }
	}
}