serial.s

IR Decoding source code

#
# Simple serial I/O routine for hc11
#
        .include         "../include/symbols.f1w.h"
        .include        "serial.h"
        .section        .text

;
; Initialise serial port with baud rate constant in A
;
serial_init:
        psha
        pshx
        ldx     #REGBS
        staa    BAUD,x
        clra
        staa    SCCR1,x
        bset    SCCR2,x #0b00001100
        pulx
        pula
        rts

;
; Flush serial port
;
serial_flush:
        pshx
        ldx     #REGBS
        brclr   SCSR,x #0b10000000 .
        pulx
        rts

;
; Send character in A to serial port
;
serial_send:
        pshx
        ldx     #REGBS
        bsr     serial_flush
        staa    SCDR,x
        pulx
        rts

;
; Print the string pointed to by X to the serial port 
;  terminate with a null
;
serial_send_string:
        psha
        pshx
sss_next:        
        ldaa    0,x
        tsta
        beq     .sss_done
        bsr     serial_send
        inx
        bra     sss_next
.sss_done:
        pulx
        pula
        rts

;
; Print the carriage return and line feed to the serial port
;
serial_send_crlf:
        psha
        ldaa    #0xd
        bsr     serial_send
        ldaa    #0xa
        bsr     serial_send
        pula
        rts

;
; Print the hex value of A to the serial port
;
serial_send_hex_byte:
        psha
        pshb
        tab
        lsra
        lsra
        lsra
        lsra
        cmpa    #10
        bge     .upper1
        adda    #'0
        bra     .out1
.upper1:
        adda    #'A - 10
.out1:
        jsr     serial_send
        tba
        anda    #0b00001111
        cmpa    #10
        bge     .upper2
        adda    #'0
        bra     .out2
.upper2:
        adda    #'A - 10
.out2:
        jsr     serial_send
        pulb
        pula
        rts